[gentoo-commits] gentoo-x86 commit in sys-apps/etckeeper: ChangeLog etckeeper-1.7.ebuild etckeeper-1.6.ebuild

[Julian Ospald (hasufell)]

hasufell    13/07/31 21:06:03

  Modified:             ChangeLog
  Added:                etckeeper-1.7.ebuild
  Removed:              etckeeper-1.6.ebuild
  Log:
  version bump
  
  (Portage version: 2.2.0_alpha191/cvs/Linux x86_64, signed Manifest commit with key E73C35B3)

Revision  Changes    Path
1.27                 sys-apps/etckeeper/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/etckeeper/ChangeLog?rev=1.27&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/etckeeper/ChangeLog?rev=1.27&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/etckeeper/ChangeLog?r1=1.26&r2=1.27

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-apps/etckeeper/ChangeLog,v
retrieving revision 1.26
retrieving revision 1.27
diff -u -r1.26 -r1.27
--- ChangeLog	29 Jul 2013 22:32:42 -0000	1.26
+++ ChangeLog	31 Jul 2013 21:06:03 -0000	1.27
@@ -1,6 +1,13 @@
 # ChangeLog for sys-apps/etckeeper
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-apps/etckeeper/ChangeLog,v 1.26 2013/07/29 22:32:42 mrueg Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/etckeeper/ChangeLog,v 1.27 2013/07/31 21:06:03 hasufell Exp $
+
+*etckeeper-1.7 (31 Jul 2013)
+
+  31 Jul 2013; Julian Ospald <hasufell@g.o>
+  -files/etckeeper-1.5-gentoo.patch, -etckeeper-1.6.ebuild,
+  +etckeeper-1.7.ebuild, +files/etckeeper-1.7-gentoo.patch:
+  version bump
 
 *etckeeper-1.6 (29 Jul 2013)
 



1.1                  sys-apps/etckeeper/etckeeper-1.7.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/etckeeper/etckeeper-1.7.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/etckeeper/etckeeper-1.7.ebuild?rev=1.1&content-type=text/plain

Index: etckeeper-1.7.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-apps/etckeeper/etckeeper-1.7.ebuild,v 1.1 2013/07/31 21:06:03 hasufell Exp $

EAPI=5

PYTHON_COMPAT=( python2_6 python2_7 )

inherit eutils bash-completion-r1 prefix python-r1

DESCRIPTION="A collection of tools to let /etc be stored in a repository"
HOMEPAGE="http://kitenet.net/~joey/code/etckeeper/"
SRC_URI="https://github.com/joeyh/etckeeper/archive/${PV}.tar.gz -> ${P}.tar.gz"

LICENSE="GPL-2"
KEYWORDS="~amd64 ~x86"
SLOT="0"
IUSE="bazaar cron"
REQUIRED_USE="bazaar? ( ${PYTHON_REQUIRED_USE} )"

VCS_DEPEND="dev-vcs/git
	dev-vcs/mercurial
	dev-vcs/darcs"
DEPEND="bazaar? ( dev-vcs/bzr )"
RDEPEND="${DEPEND}
	app-portage/portage-utils
	cron? ( virtual/cron )
	bazaar? ( ${PYTHON_DEPS} )
	!bazaar? ( || ( ${VCS_DEPEND} ) )"

src_prepare(){
	epatch "${FILESDIR}"/${PN}-1.5-gentoo.patch
}

src_compile() {
	:
}

src_install(){
	emake DESTDIR="${ED}" install

	bzr_install() {
		${PYTHON} ./${PN}-bzr/__init__.py install --root="${ED}" ||
			die "bzr support installation failed!"
	}
	use bazaar && python_foreach_impl bzr_install

	if use prefix; then
		doenvd "${FILESDIR}"/99${PN}
		eprefixify "${ED%/}"/etc/env.d/99${PN}
	fi

	newbashcomp bash_completion ${PN}
	dodoc README TODO
	docinto examples
	dodoc "${FILESDIR}"/bashrc

	if use cron ; then
		exeinto /etc/cron.daily
		newexe debian/cron.daily etckeeper
	fi
}

pkg_postinst(){
	elog "${PN} supports the following VCS: ${VCS_DEPEND}"
	elog "	dev-vcs/bzr"
	elog "This ebuild just ensures at least one is installed!"
	elog "For dev-vcs/bzr you need to enable 'bazaar' useflag."
	elog
	elog "You may want to adjust your /etc/portage/bashrc"
	elog "see the example file in /usr/share/doc/${P}/examples"
	elog
	elog "To initialise your etc-dir as a repository run:"
	elog "${PN} init -d /etc"
}