[gentoo-commits] repo/gentoo:master commit in: dev-ruby/gpgme/

[Hans de Graaff]

commit:     72c4ad16d07830b0e6c3a2fef4386e3fe3af1b16
Author:     Hans de Graaff <graaff <AT> gentoo <DOT> org>
AuthorDate: Sun Oct 31 05:56:36 2021 +0000
Commit:     Hans de Graaff <graaff <AT> gentoo <DOT> org>
CommitDate: Sun Oct 31 05:57:10 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=72c4ad16

dev-ruby/gpgme: EAPI 8; add ruby30; fix extension install

Package-Manager: Portage-3.0.28, Repoman-3.0.3
Signed-off-by: Hans de Graaff <graaff <AT> gentoo.org>

 dev-ruby/gpgme/gpgme-2.0.20-r1.ebuild | 51 +++++++++++++++++++++++++++++++++++
 1 file changed, 51 insertions(+)

diff --git a/dev-ruby/gpgme/gpgme-2.0.20-r1.ebuild b/dev-ruby/gpgme/gpgme-2.0.20-r1.ebuild
new file mode 100644
index 00000000000..a5f8cb60ba6
--- /dev/null
+++ b/dev-ruby/gpgme/gpgme-2.0.20-r1.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+USE_RUBY="ruby26 ruby27 ruby30"
+
+RUBY_FAKEGEM_EXTRADOC="NEWS README.rdoc"
+
+RUBY_FAKEGEM_GEMSPEC="${PN}.gemspec"
+
+RUBY_FAKEGEM_EXTENSIONS=(ext/gpgme/extconf.rb)
+
+inherit ruby-fakegem flag-o-matic
+
+DESCRIPTION="Ruby language binding for GnuPG Made Easy"
+HOMEPAGE="https://github.com/ueno/ruby-gpgme"
+SRC_URI="https://github.com/ueno/ruby-gpgme/archive/v${PV}.tar.gz -> ruby-${P}.tar.gz"
+RUBY_S="ruby-${P}"
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+
+DEPEND+=">=app-crypt/gpgme-1.1.3 test? ( >=app-crypt/gpgme-1.13.0 )"
+RDEPEND+=">=app-crypt/gpgme-1.1.3"
+
+ruby_add_bdepend "test? ( dev-ruby/mocha:0.14 )"
+
+all_ruby_prepare() {
+	sed -i -e '/\(coverall\|bundler\|ruby-debug\|byebug\)/I s:^:#:' \
+		-e '3igem "mocha", "~> 0.14"' \
+		test/test_helper.rb || die
+
+	# Remove failing tests for now. This package was added without
+	# running any tests :-(
+	rm -f test/{ctx,crypto}_test.rb || die
+
+	sed -i -e '/portile/d ; /rubyforge/d' ${RUBY_FAKEGEM_GEMSPEC} || die
+}
+
+each_ruby_configure() {
+	append-flags -fPIC
+	export RUBY_GPGME_USE_SYSTEM_LIBRARIES=1
+	each_fakegem_configure
+}
+
+each_ruby_test() {
+	unset DISPLAY GPG_AGENT_INFO GPG_TTY
+	MT_NO_PLUGINS=true ${RUBY} -Ilib:test:. -e 'Dir["test/*_test.rb"].each{|f| require f}' || die
+}