[gentoo-commits] gentoo-x86 commit in net-misc/wicd: wicd-1.7.1_pre20111210-r1.ebuild ChangeLog wicd-1.7.1_pre20111210.ebuild

[Thomas Kahle (tomka)]

tomka       11/12/30 09:42:08

  Modified:             ChangeLog wicd-1.7.1_pre20111210.ebuild
  Added:                wicd-1.7.1_pre20111210-r1.ebuild
  Log:
  Fix bug 394309 and download URI
  
  (Portage version: 2.1.10.44/cvs/Linux x86_64)

Revision  Changes    Path
1.103                net-misc/wicd/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/wicd/ChangeLog?rev=1.103&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/wicd/ChangeLog?rev=1.103&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/wicd/ChangeLog?r1=1.102&r2=1.103

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-misc/wicd/ChangeLog,v
retrieving revision 1.102
retrieving revision 1.103
diff -u -r1.102 -r1.103
--- ChangeLog	11 Dec 2011 10:21:18 -0000	1.102
+++ ChangeLog	30 Dec 2011 09:42:08 -0000	1.103
@@ -1,6 +1,13 @@
 # ChangeLog for net-misc/wicd
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/wicd/ChangeLog,v 1.102 2011/12/11 10:21:18 tomka Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-misc/wicd/ChangeLog,v 1.103 2011/12/30 09:42:08 tomka Exp $
+
+*wicd-1.7.1_pre20111210-r1 (30 Dec 2011)
+
+  30 Dec 2011; Thomas Kahle <tomka@g.o> wicd-1.7.1_pre20111210.ebuild,
+  +wicd-1.7.1_pre20111210-r1.ebuild,
+  +files/wicd-1.7.1_pre20111210-fix-config-reading.patch:
+  Fix bug 394309 and download URI
 
   11 Dec 2011; Thomas Kahle <tomka@g.o> wicd-1.7.1_pre20111210.ebuild:
   ewarn updated again. Thanks to Jeff Kowalczyk and Nikolaj Sjujskij for



1.4                  net-misc/wicd/wicd-1.7.1_pre20111210.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/wicd/wicd-1.7.1_pre20111210.ebuild?rev=1.4&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/wicd/wicd-1.7.1_pre20111210.ebuild?rev=1.4&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/wicd/wicd-1.7.1_pre20111210.ebuild?r1=1.3&r2=1.4

Index: wicd-1.7.1_pre20111210.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-misc/wicd/wicd-1.7.1_pre20111210.ebuild,v
retrieving revision 1.3
retrieving revision 1.4
diff -u -r1.3 -r1.4
--- wicd-1.7.1_pre20111210.ebuild	11 Dec 2011 10:21:18 -0000	1.3
+++ wicd-1.7.1_pre20111210.ebuild	30 Dec 2011 09:42:08 -0000	1.4
@@ -1,6 +1,6 @@
 # Copyright 1999-2011 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/wicd/wicd-1.7.1_pre20111210.ebuild,v 1.3 2011/12/11 10:21:18 tomka Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-misc/wicd/wicd-1.7.1_pre20111210.ebuild,v 1.4 2011/12/30 09:42:08 tomka Exp $
 
 EAPI=3
 
@@ -17,7 +17,7 @@
 
 DESCRIPTION="A lightweight wired and wireless network manager for Linux"
 HOMEPAGE="http://wicd.sourceforge.net/"
-SRC_URI="http://dev.gentoo.org/~tomka/files/${PF}.tar.gz"
+SRC_URI="http://dev.gentoo.org/~tomka/files/${P}.tar.gz"
 
 LICENSE="GPL-2"
 SLOT="0"



1.1                  net-misc/wicd/wicd-1.7.1_pre20111210-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/wicd/wicd-1.7.1_pre20111210-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/wicd/wicd-1.7.1_pre20111210-r1.ebuild?rev=1.1&content-type=text/plain

Index: wicd-1.7.1_pre20111210-r1.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-misc/wicd/wicd-1.7.1_pre20111210-r1.ebuild,v 1.1 2011/12/30 09:42:08 tomka Exp $

EAPI=3

PYTHON_DEPEND="2"
PYTHON_USE_WITH="ncurses? xml"
SUPPORT_PYTHON_ABIS="1"
RESTRICT_PYTHON_ABIS="3.* *-jython"
DISTUTILS_USE_SEPARATE_SOURCE_DIRECTORIES="1"

inherit eutils distutils systemd

MY_PV="${PN}-1.7.1"
S="${WORKDIR}/${MY_PV}"

DESCRIPTION="A lightweight wired and wireless network manager for Linux"
HOMEPAGE="http://wicd.sourceforge.net/"
SRC_URI="http://dev.gentoo.org/~tomka/files/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
IUSE="X +gtk ioctl libnotify ncurses nls +pm-utils"

DEPEND=""
# Maybe virtual/dhcp would work, but there are enough problems with
# net-misc/dhcp that I want net-misc/dhcpcd to be guarenteed to be considered
# first if none are installed.
RDEPEND="
	dev-python/dbus-python
	X? ( gtk? ( dev-python/pygtk
		|| (
			x11-libs/gksu
			kde-base/kdesu
			)
		)
	)
	|| (
		net-misc/dhcpcd
		net-misc/dhcp
		net-misc/pump
	)
	net-wireless/wireless-tools
	net-wireless/wpa_supplicant
	|| (
		sys-apps/net-tools
		sys-apps/ethtool
	)
	!gtk? ( dev-python/pygobject:2 )
	ioctl? ( dev-python/python-iwscan dev-python/python-wpactrl )
	libnotify? ( dev-python/notify-python )
	ncurses? (
		dev-python/urwid
		dev-python/pygobject:2
	)
	pm-utils? ( >=sys-power/pm-utils-1.1.1 )
	"
DOCS="CHANGES NEWS AUTHORS README"

src_prepare() {
	epatch "${FILESDIR}"/${PN}-1.7.1_beta2-init.patch
	epatch "${FILESDIR}"/${PN}-init-sve-start.patch
	# Fix bug 394309
	epatch "${FILESDIR}"/${P}-fix-config-reading.patch
	# Add a template for hex psk's and wpa (Bug 306423)
	epatch "${FILESDIR}"/${P}-wpa-psk-hex-template.patch
	# get rid of opts variable to fix bug 381885
	sed -i "/opts/d" "in/init=gentoo=wicd.in"
	# Need to ensure that generated scripts use Python 2 at run time.
	sed -e "s:self.python = '/usr/bin/python':self.python = '/usr/bin/python2':" \
	  -i setup.py || die "sed failed"
	python_copy_sources
}

src_configure() {
	local myconf
	use gtk || myconf="${myconf} --no-install-gtk"
	use libnotify || myconf="${myconf} --no-use-notifications"
	use ncurses || myconf="${myconf} --no-install-ncurses"
	use pm-utils || myconf="${myconf} --no-install-pmutils"
	configuration() {
		$(PYTHON) ./setup.py configure --no-install-docs --resume=/usr/share/wicd/scripts/ --suspend=/usr/share/wicd/scripts/ --verbose ${myconf}
	}
	python_execute_function -s configuration
}

src_install() {
	distutils_src_install
	keepdir /var/lib/wicd/configurations \
		|| die "keepdir failed, critical for this app"
	keepdir /etc/wicd/scripts/{postconnect,disconnect,preconnect} \
		|| die "keepdir failed, critical for this app"
	keepdir /var/log/wicd \
		|| die "keepdir failed, critical for this app"
	use nls || rm -rf "${D}"/usr/share/locale
	systemd_dounit "${S}/other/wicd.service"
}

pkg_postinst() {
	distutils_pkg_postinst

	elog "You may need to restart the dbus service after upgrading wicd."
	echo
	elog "To start wicd at boot, add /etc/init.d/wicd to a runlevel and:"
	elog "- Remove all net.* initscripts (except for net.lo) from all runlevels"
	elog "- Add these scripts to the RC_PLUG_SERVICES line in /etc/rc.conf"
	elog "(For example, rc_hotplug=\"!net.eth* !net.wlan*\")"
	# Maintainer's note: the consolekit use flag short circuits a dbus rule and
	# allows the connection. Else, you need to be in the group.
	if ! has_version sys-auth/pambase[consolekit]; then
			ewarn "Wicd-1.6 and newer requires your user to be in the 'users' group. If"
			ewarn "you are not in that group, then modify /etc/dbus-1/system.d/wicd.conf"
	fi
	ewarn "If you upgrade from earlier versions, then be sure to check"
	ewarn "your connection settings.  New versions parse old settings"
	ewarn "differently, so your DHCP hostname and passphrase could appear"
	ewarn "enclosed in ['square brackets in quotes']. In this case just"
	ewarn "remove the offending brackets and quotes."
}