[gentoo-commits] repo/gentoo:master commit in: media-gfx/cura/

[Amy Liffey]

commit:     b4bcea7b6bf920147435fbbf39a4d546f63866c3
Author:     Mathy Vanvoorden <mathy <AT> vanvoorden <DOT> be>
AuthorDate: Sat Dec  8 23:02:54 2018 +0000
Commit:     Amy Liffey <amynka <AT> gentoo <DOT> org>
CommitDate: Wed Jan  2 21:49:03 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=b4bcea7b

media-gfx/cura: version bump to 3.6.0

Closes: https://bugs.gentoo.org/show_bug.cgi?id=669264
Closes: https://bugs.gentoo.org/show_bug.cgi?id=671552

Signed-off-by: Mathy Vanvoorden <mathy <AT> vanvoorden.be>
Signed-off-by: Amy Liffey <amynka <AT> gentoo.org>
Closes: https://github.com/gentoo/gentoo/pull/10595
Package-Manager: Portage[mgorny]-2.3.51.1

 media-gfx/cura/Manifest          |  1 +
 media-gfx/cura/cura-3.6.0.ebuild | 73 ++++++++++++++++++++++++++++++++++++++++
 2 files changed, 74 insertions(+)

diff --git a/media-gfx/cura/Manifest b/media-gfx/cura/Manifest
index fc0e250b33e..e25b1427a32 100644
--- a/media-gfx/cura/Manifest
+++ b/media-gfx/cura/Manifest
@@ -1,2 +1,3 @@
 DIST cura-3.3.1.tar.gz 21045888 BLAKE2B 6298a291498fb7930970fdb15827e5698011e69c69326e07ecaf5440994b099aa3ce9ee2540b968ffaff1ad47a58ef76bc7c5c003e92b710d81fc649e4fc825a SHA512 7b05885213828f0c297c7798b4bf7ea5967902893b5743b424d65d3a0c88804ed208c3d0361b92cade8ad31a42d1aff3a07eb4d2effa15597f942603a2d2bf63
 DIST cura-3.4.1.tar.gz 21720836 BLAKE2B 228ad51d189f83d2a34c2af7a6edcbe468bc32ee6ac012141eac1b7332046790e2e85c4e643c1ebb13ceded6024cd52aeab2bcd0db555db8f355a7b568bed728 SHA512 5d1935c923173a5ea6d3a95181d61c8deffbb51f3ee4f3e4cb2c5a58f79581d3dd9adc6a9583e6ca0ab5da4c36b63695d7479e67d1237c132354616aa990e3c1
+DIST cura-3.6.0.tar.gz 23388945 BLAKE2B bd2f2e688306e7ef060141abae22c858e9fbb9385e49110079b48e69955c3f6630f8f69ad67fdf2d9e5c1ac0c969cd2d2f416642fc61a63867f79f88985c5c86 SHA512 b56e5575cb0eb15d759999dcd2f4c33873a0a57805a8ba0ec7860811a2137658a656216c969c6e3316d65fbd5e43f2def10a6385ccbf4fc306d15098569ef279

diff --git a/media-gfx/cura/cura-3.6.0.ebuild b/media-gfx/cura/cura-3.6.0.ebuild
new file mode 100644
index 00000000000..379309b70d6
--- /dev/null
+++ b/media-gfx/cura/cura-3.6.0.ebuild
@@ -0,0 +1,73 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python3_{5,6} )
+inherit cmake-utils fdo-mime gnome2-utils python-single-r1
+
+MY_PN=Cura
+
+DESCRIPTION="A 3D model slicing application for 3D printing"
+HOMEPAGE="https://github.com/Ultimaker/Cura"
+SRC_URI="https://github.com/Ultimaker/${MY_PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="LGPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="+usb zeroconf"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="${PYTHON_DEPS}
+	>=dev-python/uranium-${PV:0:3}[${PYTHON_USEDEP}]
+	>=media-gfx/curaengine-${PV:0:3}
+	>=media-gfx/fdm-materials-${PV:0:3}
+	>=dev-libs/libsavitar-${PV:0:3}:=[python,${PYTHON_USEDEP}]
+	>=dev-libs/libcharon-${PV:0:3}[${PYTHON_USEDEP}]
+	usb? ( dev-python/pyserial[${PYTHON_USEDEP}] )
+	zeroconf? ( dev-python/zeroconf[${PYTHON_USEDEP}] )"
+
+DEPEND="${RDEPEND}
+	sys-devel/gettext"
+
+S="${WORKDIR}/${MY_PN}-${PV}"
+PATCHES=( "${FILESDIR}/${PN}-3.3.0-fix-install-paths.patch" )
+DOCS=( README.md )
+
+src_prepare() {
+	default
+	sed -i "s/set(CURA_VERSION \"master\"/set(CURA_VERSION \"${PV}\"/" CMakeLists.txt || die
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DPYTHON_SITE_PACKAGES_DIR="$(python_get_sitedir)"
+	)
+	cmake-utils_src_configure
+}
+
+src_compile() {
+	cmake-utils_src_compile
+}
+
+src_install() {
+	cmake-utils_src_install
+	doicon icons/*.png
+	python_optimize "${D}${get_libdir}"
+}
+
+pkg_preinst() {
+	gnome2_icon_savelist
+}
+
+pkg_postinst() {
+	fdo-mime_desktop_database_update
+	fdo-mime_mime_database_update
+	gnome2_icon_cache_update
+}
+
+pkg_postrm() {
+	fdo-mime_desktop_database_update
+	fdo-mime_mime_database_update
+	gnome2_icon_cache_update
+}