[gentoo-commits] gentoo-x86 commit in media-video/kmplayer: ChangeLog kmplayer-0.11.1a.ebuild

[Tomas Chvatal (scarabeus)]

scarabeus    09/06/05 12:13:57

  Modified:             ChangeLog
  Added:                kmplayer-0.11.1a.ebuild
  Log:
  Version bump.
  (Portage version: 2.2_rc33/cvs/Linux x86_64)

Revision  Changes    Path
1.126                media-video/kmplayer/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-video/kmplayer/ChangeLog?rev=1.126&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-video/kmplayer/ChangeLog?rev=1.126&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-video/kmplayer/ChangeLog?r1=1.125&r2=1.126

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-video/kmplayer/ChangeLog,v
retrieving revision 1.125
retrieving revision 1.126
diff -u -r1.125 -r1.126
--- ChangeLog	28 May 2009 12:44:48 -0000	1.125
+++ ChangeLog	5 Jun 2009 12:13:56 -0000	1.126
@@ -1,6 +1,12 @@
 # ChangeLog for media-video/kmplayer
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-video/kmplayer/ChangeLog,v 1.125 2009/05/28 12:44:48 scarabeus Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-video/kmplayer/ChangeLog,v 1.126 2009/06/05 12:13:56 scarabeus Exp $
+
+*kmplayer-0.11.1a (05 Jun 2009)
+
+  05 Jun 2009; Tomas Chvatal <scarabeus@g.o>
+  +kmplayer-0.11.1a.ebuild:
+  Version bump.
 
 *kmplayer-0.11.1 (28 May 2009)
 *kmplayer-0.10.0c-r2 (28 May 2009)



1.1                  media-video/kmplayer/kmplayer-0.11.1a.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-video/kmplayer/kmplayer-0.11.1a.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-video/kmplayer/kmplayer-0.11.1a.ebuild?rev=1.1&content-type=text/plain

Index: kmplayer-0.11.1a.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-video/kmplayer/kmplayer-0.11.1a.ebuild,v 1.1 2009/06/05 12:13:56 scarabeus Exp $

EAPI="2"

KDE_LINGUAS="cs da de el en_GB es et fr ga gl it ja km ku lt lv mai nb nds nl
nn pl pt pt_BR ro ru sk sv tr uk"

KMNAME="extragear/multimedia"
inherit kde4-base

MY_P="${P/_/-}"
DESCRIPTION="KMPlayer is a Video player plugin for Konqueror and basic MPlayer/Xine/ffmpeg/ffserver/VDR frontend."
HOMEPAGE="http://kmplayer.kde.org/"
SRC_URI="http://${PN}.kde.org/pkgs/${MY_P}.tar.bz2"

LICENSE="GPL-2"
KEYWORDS="~amd64 ~x86"
SLOT="4"
IUSE="cairo debug doc expat npp"

DEPEND="
	expat? ( >=dev-libs/expat-2.0.1 )
	cairo? (
		x11-libs/cairo
		x11-libs/pango
	)
	npp? (
		dev-libs/dbus-glib
		>=x11-libs/gtk+-2.10.14
	)
"
RDEPEND="${DEPEND}
	!media-video/kmplayer:4.1
	|| (
		media-video/mplayer
		media-video/mplayer-bin
	)
"

S="${WORKDIR}/${MY_P}"

pkg_setup() {
	if has_version "media-video/mplayer-bin"; then
		echo
		elog 'NOTICE: You have mplayer-bin installed; you may need to configure'
		elog 'NOTICE: kmplayer to use it from within the application.'
		echo
	fi

	kde4-base_pkg_setup
}

src_prepare() {
	# do not install icons
	sed -i \
		-e "s:add_subdirectory(icons):#add_subdirectory(icons):g" \
		CMakeLists.txt || die "removing icons failed"

	# fix the install dir for docs
	sed -i \
		-e "s|\${HTML_INSTALL_DIR}/en|\${HTML_INSTALL_DIR}/en SUBDIR ${PN}|" \
		doc/CMakeLists.txt || die "fixing docs target dir failed"

	# make docs optional
	sed -i \
		-e "s:add_subdirectory(doc):macro_optional_add_subdirectory(doc):g" \
		CMakeLists.txt || die "failed to make docs optional"

	kde4-base_src_prepare
}

src_configure() {
	mycmakeargs="${mycmakeargs}
		$(cmake-utils_use_build doc)
		$(cmake-utils_use cairo KMPLAYER_BUILT_WITH_CAIRO)
		$(cmake-utils_use expat KMPLAYER_BUILT_WITH_EXPAT)
		$(cmake-utils_use npp KMPLAYER_BUILT_WITH_NPP)"

	kde4-base_src_configure
}