[gentoo-commits] repo/gentoo:master commit in: app-portage/pfl/

[Daniel Pielmeier]

commit:     9303a3c491fa724daf3f4f1618f0f7b4245757e5
Author:     Daniel Pielmeier <billie <AT> gentoo <DOT> org>
AuthorDate: Wed Feb  2 17:11:25 2022 +0000
Commit:     Daniel Pielmeier <billie <AT> gentoo <DOT> org>
CommitDate: Wed Feb  2 17:11:25 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=9303a3c4

app-portage/pfl: Migrate to PEP517 build.

Package-Manager: Portage-3.0.30, Repoman-3.0.3
Signed-off-by: Daniel Pielmeier <billie <AT> gentoo.org>

 app-portage/pfl/pfl-3.2-r2.ebuild | 50 +++++++++++++++++++++++++++++++++++++++
 1 file changed, 50 insertions(+)

diff --git a/app-portage/pfl/pfl-3.2-r2.ebuild b/app-portage/pfl/pfl-3.2-r2.ebuild
new file mode 100644
index 000000000000..a6828df22df9
--- /dev/null
+++ b/app-portage/pfl/pfl-3.2-r2.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8,9,10} )
+PYTHON_REQ_USE="xml"
+
+inherit distutils-r1 systemd
+
+DESCRIPTION="Searchable online file/package database for Gentoo"
+HOMEPAGE="http://www.portagefilelist.de https://github.com/portagefilelist/client"
+SRC_URI="https://github.com/portagefilelist/client/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux ~x64-macos"
+IUSE="+network-cron"
+
+DEPEND=""
+RDEPEND="
+	dev-python/requests[${PYTHON_USEDEP}]
+	dev-python/termcolor[${PYTHON_USEDEP}]
+	sys-apps/portage[${PYTHON_USEDEP}]
+	network-cron? ( sys-apps/util-linux[caps] )
+"
+
+S="${WORKDIR}/client-${PV}"
+
+python_install_all() {
+	if use network-cron ; then
+		exeinto /etc/cron.weekly
+		doexe cron/pfl
+	fi
+
+	systemd_dounit systemd/pfl.{service,timer}
+
+	keepdir /var/lib/${PN}
+
+	distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+	if [[ ! -e "${EROOT}/var/lib/${PN}/pfl.info" ]]; then
+		touch "${EROOT}/var/lib/${PN}/pfl.info" || die
+	fi
+	chown -R portage:portage "${EROOT}/var/lib/${PN}" || die
+	chmod 775 "${EROOT}/var/lib/${PN}" || die
+}