[gentoo-commits] gentoo-x86 commit in net-news/liferea: ChangeLog liferea-1.4.2b.ebuild liferea-1.4.2.ebuild

[Daniel Gryniewicz (dang)]

dang        07/09/20 13:45:26

  Modified:             ChangeLog
  Added:                liferea-1.4.2b.ebuild
  Removed:              liferea-1.4.2.ebuild
  Log:
  Bump to 1.4.2b
  (Portage version: 2.1.3.9)

Revision  Changes    Path
1.123                net-news/liferea/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-news/liferea/ChangeLog?rev=1.123&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-news/liferea/ChangeLog?rev=1.123&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-news/liferea/ChangeLog?r1=1.122&r2=1.123

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-news/liferea/ChangeLog,v
retrieving revision 1.122
retrieving revision 1.123
diff -u -r1.122 -r1.123
--- ChangeLog	15 Sep 2007 13:36:42 -0000	1.122
+++ ChangeLog	20 Sep 2007 13:45:26 -0000	1.123
@@ -1,6 +1,23 @@
 # ChangeLog for net-news/liferea
 # Copyright 2000-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-news/liferea/ChangeLog,v 1.122 2007/09/15 13:36:42 dang Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-news/liferea/ChangeLog,v 1.123 2007/09/20 13:45:26 dang Exp $
+
+*liferea-1.4.2b (20 Sep 2007)
+
+  20 Sep 2007; Daniel Gryniewicz <dang@g.o> -liferea-1.4.2.ebuild,
+  +liferea-1.4.2b.ebuild:
+  Bump to 1.4.2b
+  	* Fixes compilation problems of GtkHTML2 rendering.
+  	* Fixes SF #1798158: problem with 'mark as read' 
+  	  option in popup window (reported by zodmaner)
+  	* Now removes leading/trailing white spaces from
+  	  feed list node titles. (patch from Christian Dywan)
+  	* Fixes broken HTTP authentication. Auth info was
+  	  just not passed with HTTP requests. (reported
+  	  by Jim Henderson)
+  	* Fixes Debian #442798: update interval values
+  	  isn't correctly updated. Interval unit is lost.
+  	  (reported by Yannick Palanque)
 
   15 Sep 2007; Daniel Gryniewicz <dang@g.o> liferea-1.4.2.ebuild:
   Disable webkit.  bug #192566



1.1                  net-news/liferea/liferea-1.4.2b.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-news/liferea/liferea-1.4.2b.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-news/liferea/liferea-1.4.2b.ebuild?rev=1.1&content-type=text/plain

Index: liferea-1.4.2b.ebuild
===================================================================
# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-news/liferea/liferea-1.4.2b.ebuild,v 1.1 2007/09/20 13:45:26 dang Exp $

WANT_AUTOMAKE=1.7
WANT_AUTOCONF=latest
inherit gnome2

DESCRIPTION="News Aggregator for RDF/RSS/CDF/Atom/Echo/etc feeds"
HOMEPAGE="http://liferea.sourceforge.net/"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
LICENSE="GPL-2"

SLOT="0"
KEYWORDS="~amd64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
IUSE="dbus firefox gtkhtml gnutls libnotify lua networkmanager seamonkey xulrunner"

RDEPEND="
	libnotify? ( >=x11-libs/libnotify-0.3.2 )
	lua? ( >=dev-lang/lua-5.1 )
	xulrunner? ( net-libs/xulrunner )
	!xulrunner? ( firefox? ( www-client/mozilla-firefox ) )
	!xulrunner? ( !firefox? ( seamonkey? ( www-client/seamonkey ) ) )
	!amd64? ( !xulrunner? ( !firefox? ( !seamonkey? ( =gnome-extra/gtkhtml-2* ) ) ) )
	!amd64? ( gtkhtml? ( =gnome-extra/gtkhtml-2* ) )
	>=x11-libs/gtk+-2.8
	x11-libs/pango
	>=gnome-base/gconf-2
	>=dev-libs/libxml2-2.6.27
	>=dev-libs/libxslt-1.1.19
	>=dev-db/sqlite-3.3
	>=dev-libs/glib-2
	>=gnome-base/libglade-2
	dbus? ( >=dev-libs/dbus-glib-0.71 )
	networkmanager? ( net-misc/networkmanager )
	gnutls? ( net-libs/gnutls )"

DEPEND="${RDEPEND}
	dev-util/pkgconfig
	>=dev-util/intltool-0.35"

DOCS="AUTHORS ChangeLog NEWS README"

pkg_setup() {
	# On amd64, gtkhtml isn't supported.  You need one of the gecko use flags
	if use amd64 && ! use firefox && ! use seamonkey && ! use xulrunner; then
		elog "gtkhtml is no longer supported on amd64; you will need to select"
		elog "one of the gecko backends to use liferea"
		die "You must enable on of the gecko backends on amd64"
	fi

	# if you don't choose a gecko to use, we will automatically
	# use gtkhtml2 as the backend except on amd64 (where we failed above)
	if ! use seamonkey && ! use firefox && ! use xulrunner && ! use amd64 ; then
		G2CONF="${G2CONF} --enable-gtkhtml2"
	elif ! use amd64 && use gtkhtml ; then
		G2CONF="${G2CONF} --enable-gtkhtml2"
	else
		G2CONF="${G2CONF} --disable-gtkhtml2"
	fi

	# we prefer xulrunner over firefox over seamonkey
	if use xulrunner ; then
		G2CONF="${G2CONF} --enable-xulrunner"
	elif use firefox ; then
		G2CONF="${G2CONF} --enable-gecko=firefox"
	elif use seamonkey ; then
		G2CONF="${G2CONF} --enable-gecko=seamonkey"
	else
		G2CONF="${G2CONF} --disable-gecko"
	fi

	G2CONF="${G2CONF} \
		--disable-webkit \
		$(use_enable dbus) \
		$(use_enable gnutls) \
		$(use_enable libnotify) \
		$(use_enable lua) \
		$(use_enable networkmanager nm)"
}

src_install() {
	gnome2_src_install
	rm -f ${D}/usr/bin/${PN}
	mv ${D}/usr/bin/${PN}-bin ${D}/usr/bin/${PN}
}



-- 
gentoo-commits@g.o mailing list