[gentoo-commits] gentoo-x86 commit in sys-libs/e2fsprogs-libs: ChangeLog e2fsprogs-libs-1.42_pre0702.ebuild

[Mike Frysinger (vapier)]

vapier      11/09/01 19:32:02

  Modified:             ChangeLog
  Added:                e2fsprogs-libs-1.42_pre0702.ebuild
  Log:
  Add WIP from upstream #379573 by Sebastian Pipping.
  
  (Portage version: 2.2.0_alpha51/cvs/Linux x86_64)

Revision  Changes    Path
1.68                 sys-libs/e2fsprogs-libs/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-libs/e2fsprogs-libs/ChangeLog?rev=1.68&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-libs/e2fsprogs-libs/ChangeLog?rev=1.68&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-libs/e2fsprogs-libs/ChangeLog?r1=1.67&r2=1.68

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-libs/e2fsprogs-libs/ChangeLog,v
retrieving revision 1.67
retrieving revision 1.68
diff -u -r1.67 -r1.68
--- ChangeLog	29 Aug 2011 06:12:49 -0000	1.67
+++ ChangeLog	1 Sep 2011 19:32:02 -0000	1.68
@@ -1,6 +1,12 @@
 # ChangeLog for sys-libs/e2fsprogs-libs
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-libs/e2fsprogs-libs/ChangeLog,v 1.67 2011/08/29 06:12:49 jer Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-libs/e2fsprogs-libs/ChangeLog,v 1.68 2011/09/01 19:32:02 vapier Exp $
+
+*e2fsprogs-libs-1.42_pre0702 (01 Sep 2011)
+
+  01 Sep 2011; Mike Frysinger <vapier@g.o>
+  +e2fsprogs-libs-1.42_pre0702.ebuild:
+  Add WIP from upstream #379573 by Sebastian Pipping.
 
   29 Aug 2011; Jeroen Roovers <jer@g.o> e2fsprogs-libs-1.41.14.ebuild:
   Stable for HPPA (bug #378039).



1.1                  sys-libs/e2fsprogs-libs/e2fsprogs-libs-1.42_pre0702.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-libs/e2fsprogs-libs/e2fsprogs-libs-1.42_pre0702.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-libs/e2fsprogs-libs/e2fsprogs-libs-1.42_pre0702.ebuild?rev=1.1&content-type=text/plain

Index: e2fsprogs-libs-1.42_pre0702.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-libs/e2fsprogs-libs/e2fsprogs-libs-1.42_pre0702.ebuild,v 1.1 2011/09/01 19:32:02 vapier Exp $

case ${PV} in
*_pre*) UP_PV="${PV%_pre*}-WIP-${PV#*_pre}" ;;
*)      UP_PV=${PV} ;;
esac

EAPI="2"

inherit toolchain-funcs

DESCRIPTION="e2fsprogs libraries (common error and subsystem)"
HOMEPAGE="http://e2fsprogs.sourceforge.net/"
SRC_URI="mirror://sourceforge/e2fsprogs/${PN}-${UP_PV}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd"
IUSE="nls elibc_glibc"

RDEPEND="elibc_glibc? ( >=sys-libs/glibc-2.6 )
	!sys-libs/com_err
	!sys-libs/ss
	!<sys-fs/e2fsprogs-1.41.8"
DEPEND="nls? ( sys-devel/gettext )
	dev-util/pkgconfig"

S=${WORKDIR}/${P%_pre*}

src_prepare() {
	printf 'all:\n%%:;@:\n' > doc/Makefile.in # don't bother with docs #305613
}

src_configure() {
	# We want to use the "bsd" libraries while building on Darwin, but while
	# building on other Gentoo/*BSD we prefer elf-naming scheme.
	local libtype
	case ${CHOST} in
		*-darwin*) libtype=bsd;;
		*)         libtype=elf;;
	esac

	# we use blkid/uuid from util-linux now
	ac_cv_lib_uuid_uuid_generate=yes \
	ac_cv_lib_blkid_blkid_get_cache=yes \
	ac_cv_path_LDCONFIG=: \
	econf \
		--disable-libblkid \
		--disable-libuuid \
		--enable-${libtype}-shlibs \
		$(tc-has-tls || echo --disable-tls) \
		$(use_enable nls)
}

src_install() {
	emake STRIP=: DESTDIR="${D}" install || die
	gen_usr_ldscript -a com_err ss
}