[gentoo-commits] gentoo-x86 commit in net-misc/grive: grive-0.3.0_pre20130503.ebuild ChangeLog

[Christoph Junghans (ottxor)]

ottxor      14/04/29 16:58:43

  Modified:             ChangeLog
  Added:                grive-0.3.0_pre20130503.ebuild
  Log:
  version bump to build with latest json-c (bug #508980)
  
  (Portage version: 2.2.8-r1/cvs/Linux x86_64, signed Manifest commit with key C2000586)

Revision  Changes    Path
1.14                 net-misc/grive/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/grive/ChangeLog?rev=1.14&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/grive/ChangeLog?rev=1.14&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/grive/ChangeLog?r1=1.13&r2=1.14

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-misc/grive/ChangeLog,v
retrieving revision 1.13
retrieving revision 1.14
diff -u -r1.13 -r1.14
--- ChangeLog	1 Mar 2014 22:09:38 -0000	1.13
+++ ChangeLog	29 Apr 2014 16:58:43 -0000	1.14
@@ -1,6 +1,12 @@
 # ChangeLog for net-misc/grive
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/grive/ChangeLog,v 1.13 2014/03/01 22:09:38 mgorny Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-misc/grive/ChangeLog,v 1.14 2014/04/29 16:58:43 ottxor Exp $
+
+*grive-0.3.0_pre20130503 (29 Apr 2014)
+
+  29 Apr 2014; Christoph Junghans <ottxor@g.o>
+  +grive-0.3.0_pre20130503.ebuild:
+  version bump to build with latest json-c (bug #508980)
 
   01 Mar 2014; Michał Górny <mgorny@g.o> grive-0.2.0-r1.ebuild:
   Update libgcrypt dep to use slot :0.



1.1                  net-misc/grive/grive-0.3.0_pre20130503.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/grive/grive-0.3.0_pre20130503.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/grive/grive-0.3.0_pre20130503.ebuild?rev=1.1&content-type=text/plain

Index: grive-0.3.0_pre20130503.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-misc/grive/grive-0.3.0_pre20130503.ebuild,v 1.1 2014/04/29 16:58:43 ottxor Exp $

EAPI=5

inherit cmake-utils eutils multilib

if [[ ${PV} = *9999 ]]; then
	inherit git-2
	EGIT_REPO_URI="git://github.com/Grive/${PN}.git"
else
	inherit eutils vcs-snapshot
	COMMIT="27817e835fe115ebbda5410ec904aa49a2ad01f1"
	SRC_URI="https://github.com/${PN}/${PN}/archive/${COMMIT}.tar.gz -> ${P}.tar.gz"
fi

DESCRIPTION="an open source Linux client for Google Drive"
HOMEPAGE="http://www.lbreda.com/grive/"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE=""

RDEPEND="
	dev-libs/boost:=
	dev-libs/expat
	dev-libs/json-c:=
	dev-libs/libgcrypt:0=
	dev-libs/yajl
	dev-qt/qtcore
	dev-qt/qtgui
	net-misc/curl
	sys-devel/binutils
	sys-libs/glibc
	sys-libs/zlib
	"

DEPEND="${RDEPEND}"

DOCS=( "README" )

src_prepare() {
	epatch "${FILESDIR}/${PN}"-0.2.0-check-bfd.h.patch

	#include dir change in json-c-0.10 #462632 and #452234
	if has_version ">=dev-libs/json-c-0.10" ; then
		sed -i -e '/\(include\|INCLUDE\)/s@json/@json-c/@' \
			libgrive/src/protocol/Json.cc \
			cmake/Modules/FindJSONC.cmake || die
	fi
	#json-c library changed in 0.11, bug #467432
	if has_version ">=dev-libs/json-c-0.11" ; then
		sed -i -e '/LIBRARY/s@json)@json-c)@' \
			cmake/Modules/FindJSONC.cmake || die
	fi

	sed -i '/grive.1/s/^/#/' bgrive/CMakeLists.txt || die
}

src_install(){
	cmake-utils_src_install

	local icon size
	for icon in icon/*/*.png; do
		size=${icon##*/}
		size=${size%.png}
		newicon -s "${size}" "${icon}" ${PN}.png
	done
	make_desktop_entry bgrive
}