[gentoo-commits] gentoo-x86 commit in app-admin/sagan: sagan-0.2.0.ebuild ChangeLog metadata.xml

[Maxim Koltsov (maksbotan)]

maksbotan    11/08/31 08:36:54

  Added:                sagan-0.2.0.ebuild ChangeLog metadata.xml
  Log:
  Add app-admin/sagan, bug #341461
  
  (Portage version: 2.1.10.11/cvs/Linux x86_64)

Revision  Changes    Path
1.1                  app-admin/sagan/sagan-0.2.0.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/sagan/sagan-0.2.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/sagan/sagan-0.2.0.ebuild?rev=1.1&content-type=text/plain

Index: sagan-0.2.0.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-admin/sagan/sagan-0.2.0.ebuild,v 1.1 2011/08/31 08:36:54 maksbotan Exp $

EAPI=4

inherit eutils autotools-utils

DESCRIPTION="Sagan is a multi-threaded, real time system and event log monitoring system"
HOMEPAGE="http://sagan.softwink.com/"
SRC_URI="http://sagan.softwink.com/download/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="smtp mysql postgres prelude +lognorm +libdnet +pcap"

DEPEND="dev-util/pkgconfig
	${RDEPEND}"

RDEPEND="dev-libs/libpcre
	app-admin/sagan-rules
	smtp? ( net-libs/libesmtp )
	pcap? ( net-libs/libpcap )
	mysql? ( virtual/mysql )
	postgres? ( dev-db/postgresql-base )
	prelude? ( dev-libs/libprelude )
	lognorm? ( dev-libs/liblognorm )
	libdnet? ( dev-libs/libdnet )"

AUTOTOOLS_IN_SOURCE_BUILD=1
DOCS=(AUTHORS ChangeLog FAQ INSTALL README NEWS TODO)

pkg_setup() {
	enewgroup sagan
	enewuser sagan -1 -1 /dev/null sagan
}

src_configure() {
	 local myeconfargs=(
		$(use_enable mysql)
		$(use_enable postgres postgresql)
		$(use_enable smtp esmtp)
		$(use_enable prelude )
		$(use_enable lognorm)
		$(use_enable libdnet)
		$(use_enable pcap libpcap) )

	autotools-utils_src_configure
}

src_install() {
	autotools-utils_src_install

	diropts -g sagan -o sagan -m 775

	dodir /var/log/sagan
	dodir /var/run/sagan

	keepdir /var/log/sagan
	keepdir /var/run/sagan

	mkfifo -m 0640 "${ED}"/var/run/sagan.fifo
	chown sagan.root "${ED}"/var/run/sagan.fifo

	touch "${ED}"/var/log/sagan/sagan.log
	chown sagan.sagan "${ED}"/var/log/sagan/sagan.log

	newinitd "${FILESDIR}"/sagan.init sagan
	newconfd "${FILESDIR}"/sagan.confd sagan

	insinto /usr/share/doc/${EP}/examples
	doins -r extra/*
}

pkg_postinst() {
	if use smtp; then
		ewarn "You have enabled smtp use flag. If you plan on using Sagan with"
		ewarn "email, create valid writable home directory for user 'sagan'"
		ewarn "For security reasons it was created with /dev/null home directory"
	fi

	einfo "For configuration assistance see"
	einfo "http://wiki.quadrantsec.com/bin/view/Main/SaganHOWTO"
}



1.1                  app-admin/sagan/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/sagan/ChangeLog?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/sagan/ChangeLog?rev=1.1&content-type=text/plain

Index: ChangeLog
===================================================================
# ChangeLog for app-admin/sagan
# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
# $Header: /var/cvsroot/gentoo-x86/app-admin/sagan/ChangeLog,v 1.1 2011/08/31 08:36:54 maksbotan Exp $

*sagan-0.2.0 (31 Aug 2011)

  31 Aug 2011; Maxim Koltsov <maksbotan@g.o> +sagan-0.2.0.ebuild,
  +files/sagan.confd, +files/sagan.init, +metadata.xml:
  Copy app-admin/sagan from rion-overlay, thanks to slepnoga. Bug 341461




1.1                  app-admin/sagan/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/sagan/metadata.xml?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/sagan/metadata.xml?rev=1.1&content-type=text/plain

Index: metadata.xml
===================================================================
<?xml version="1.0" encoding="UTF-8"?>
<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
<pkgmetadata>
<herd>no-herd</herd>
<maintainer>
  <email>spamslepnoga@×××××.ru</email>
</maintainer>
<maintainer>
  <email>maksbotan@g.o</email>
</maintainer>
<use>
  <flag name='smtp'>Build witch SMTP (E-Mail) support</flag>
  <flag name='lognorm'>Add support for log/rules normalizations via <pkg>dev-libs/liblognorm</pkg></flag>
  <flag name='pcap'>Add support for network packet capture via <pkg>net-libs/libpcap</pkg></flag>
  <flag name='libdnet'>Add support for <pkg>dev-libs/libdnet</pkg></flag>
</use>
</pkgmetadata>