[gentoo-commits] gentoo-x86 commit in games-engines/scummvm-tools: scummvm-tools-1.6.0.ebuild ChangeLog

[Michael Sterrett (mr_bones_)]

mr_bones_    13/06/02 04:33:51

  Modified:             ChangeLog
  Added:                scummvm-tools-1.6.0.ebuild
  Log:
  version bump
  
  (Portage version: 2.1.11.62/cvs/Linux x86_64, unsigned Manifest commit)

Revision  Changes    Path
1.58                 games-engines/scummvm-tools/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-engines/scummvm-tools/ChangeLog?rev=1.58&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-engines/scummvm-tools/ChangeLog?rev=1.58&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-engines/scummvm-tools/ChangeLog?r1=1.57&r2=1.58

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/games-engines/scummvm-tools/ChangeLog,v
retrieving revision 1.57
retrieving revision 1.58
diff -u -r1.57 -r1.58
--- ChangeLog	4 Nov 2012 04:31:47 -0000	1.57
+++ ChangeLog	2 Jun 2013 04:33:51 -0000	1.58
@@ -1,6 +1,12 @@
 # ChangeLog for games-engines/scummvm-tools
-# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/games-engines/scummvm-tools/ChangeLog,v 1.57 2012/11/04 04:31:47 mr_bones_ Exp $
+# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/games-engines/scummvm-tools/ChangeLog,v 1.58 2013/06/02 04:33:51 mr_bones_ Exp $
+
+*scummvm-tools-1.6.0 (02 Jun 2013)
+
+  02 Jun 2013; Michael Sterrett <mr_bones_@g.o>
+  +scummvm-tools-1.6.0.ebuild:
+  version bump
 
   04 Nov 2012; Michael Sterrett <mr_bones_@g.o>
   +files/scummvm-tools-1.4.0-boost.patch, scummvm-tools-1.4.0.ebuild:



1.1                  games-engines/scummvm-tools/scummvm-tools-1.6.0.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-engines/scummvm-tools/scummvm-tools-1.6.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-engines/scummvm-tools/scummvm-tools-1.6.0.ebuild?rev=1.1&content-type=text/plain

Index: scummvm-tools-1.6.0.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/games-engines/scummvm-tools/scummvm-tools-1.6.0.ebuild,v 1.1 2013/06/02 04:33:51 mr_bones_ Exp $

EAPI=5
WX_GTK_VER=2.8
inherit wxwidgets eutils flag-o-matic games

DESCRIPTION="utilities for the SCUMM game engine"
HOMEPAGE="http://scummvm.sourceforge.net/"
SRC_URI="mirror://sourceforge/scummvm/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~ppc64 ~x86 ~x86-fbsd"
IUSE="flac iconv mad png vorbis"
RESTRICT="test" # some tests require external files

RDEPEND="png? ( media-libs/libpng )
	mad? ( media-libs/libmad )
	flac? ( media-libs/flac )
	vorbis? ( media-libs/libvorbis )
	iconv? ( virtual/libiconv media-libs/freetype:2 )
	sys-libs/zlib
	>=dev-libs/boost-1.32
	x11-libs/wxGTK:2.8"
DEPEND="${RDEPEND}
	virtual/pkgconfig"

src_prepare() {
	rm -rf *.bat dists/win32
	# use $T instead of /tmp - bug #402459
	sed -i \
		-e 's:/tmp:"${T}":' \
		configure || die
	sed -ri \
		-e '/^(CC|CXX)\b/d' \
		Makefile || die

	local boost_ver=$(best_version ">=dev-libs/boost-1.32")

	boost_ver=${boost_ver/*boost-/}
	boost_ver=${boost_ver%.*}
	boost_ver=${boost_ver/./_}

	einfo "Using boost version ${boost_ver}"
	append-cxxflags \
        -I/usr/include/boost-${boost_ver}
	append-ldflags \
        -L/usr/$(get_libdir)/boost-${boost_ver}
	export BOOST_INCLUDEDIR="/usr/include/boost-${boost_ver}"
	export BOOST_LIBRARYDIR="/usr/$(get_libdir)/boost-${boost_ver}"
}

src_configure() {
	# Not an autoconf script
	./configure \
		--enable-verbose-build \
		--mandir=/usr/share/man \
		--prefix=/usr/games \
		--libdir=/usr/games/lib \
		$(use_enable flac) \
		$(use_enable iconv) \
		$(use_enable iconv freetype) \
		$(use_enable mad) \
		$(use_enable png) \
		$(use_enable vorbis) \
		|| die
}

src_install() {
	local f
	for f in $(find . -type f -perm +1 -print); do
		newgamesbin $f ${PN}-${f##*/} || die
	done
	dodoc README TODO
	prepgamesdirs
}