[gentoo-commits] gentoo-x86 commit in app-misc/gtypist: ChangeLog gtypist-2.9.1.ebuild

[Jeremy Olexa (darkside)]

darkside    11/12/01 17:59:12

  Modified:             ChangeLog
  Added:                gtypist-2.9.1.ebuild
  Log:
  very, very minor upstream version bump including UTF-8 fixes, bug 392555
  
  (Portage version: 2.1.10.36/cvs/Linux i686)

Revision  Changes    Path
1.31                 app-misc/gtypist/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/gtypist/ChangeLog?rev=1.31&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/gtypist/ChangeLog?rev=1.31&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/gtypist/ChangeLog?r1=1.30&r2=1.31

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-misc/gtypist/ChangeLog,v
retrieving revision 1.30
retrieving revision 1.31
diff -u -r1.30 -r1.31
--- ChangeLog	30 Sep 2011 15:48:11 -0000	1.30
+++ ChangeLog	1 Dec 2011 17:59:12 -0000	1.31
@@ -1,6 +1,11 @@
 # ChangeLog for app-misc/gtypist
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-misc/gtypist/ChangeLog,v 1.30 2011/09/30 15:48:11 darkside Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-misc/gtypist/ChangeLog,v 1.31 2011/12/01 17:59:12 darkside Exp $
+
+*gtypist-2.9.1 (01 Dec 2011)
+
+  01 Dec 2011; Jeremy Olexa <darkside@g.o> +gtypist-2.9.1.ebuild:
+  very, very minor upstream version bump including UTF-8 fixes, bug 392555
 
   30 Sep 2011; Jeremy Olexa <darkside@g.o> -gtypist-2.8.5.ebuild,
   gtypist-2.8.5-r1.ebuild:



1.1                  app-misc/gtypist/gtypist-2.9.1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/gtypist/gtypist-2.9.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/gtypist/gtypist-2.9.1.ebuild?rev=1.1&content-type=text/plain

Index: gtypist-2.9.1.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-misc/gtypist/gtypist-2.9.1.ebuild,v 1.1 2011/12/01 17:59:12 darkside Exp $

EAPI=4

inherit eutils elisp-common

DESCRIPTION="Universal typing tutor"
HOMEPAGE="http://www.gnu.org/software/gtypist/"
SRC_URI="mirror://gnu/gtypist/${P}.tar.xz
	http://colemak.com/pub/learn/colemak.typ"

LICENSE="GPL-2 public-domain"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86 ~amd64-linux"
IUSE="nls emacs xemacs"

DEPEND=">=sys-libs/ncurses-5.2
	emacs? ( virtual/emacs )
	xemacs? ( !emacs? ( app-editors/xemacs app-xemacs/fsf-compat ) )"

RDEPEND="${DEPEND}"

SITEFILE=50${PN}-gentoo.el

src_unpack() {
	unpack ${P}.tar.xz
}

src_prepare() {
	epatch "${FILESDIR}"/${PN}-2.8.3-xemacs-compat.patch
}

src_configure() {
	local lispdir=""
	if use emacs; then
		lispdir="${SITELISP}/${PN}"
		einfo "Configuring to build with GNU Emacs support"
	elif use xemacs; then
		lispdir="${EPREFIX}/usr/lib/xemacs/site-packages/lisp/${PN}"
		einfo "Configuring to build with XEmacs support"
	fi

	econf $(use_enable nls) \
		EMACS=$(usev emacs || usev xemacs || echo no) \
		--with-lispdir="${lispdir}"
}

src_install() {
	emake DESTDIR="${D}" install
	dodoc AUTHORS ChangeLog NEWS README THANKS TODO

	insinto /usr/share/gtypist
	doins "${DISTDIR}"/colemak.typ

	if use emacs; then
		elisp-site-file-install "${FILESDIR}/${SITEFILE}" || die
	fi
}

pkg_postinst() {
	use emacs && elisp-site-regen
}

pkg_postrm() {
	use emacs && elisp-site-regen
}