[gentoo-commits] repo/gentoo:master commit in: dev-cpp/libjson-rpc-cpp/

[Michał Górny]

commit:     86a87e5fc856d6ccfcdb27788499dc4ad9fa0212
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Sat Oct 23 19:52:18 2021 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Sat Oct 23 20:19:42 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=86a87e5f

dev-cpp/libjson-rpc-cpp: Bump to 1.4.0

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-cpp/libjson-rpc-cpp/Manifest                   |  1 +
 .../libjson-rpc-cpp/libjson-rpc-cpp-1.4.0.ebuild   | 69 ++++++++++++++++++++++
 2 files changed, 70 insertions(+)

diff --git a/dev-cpp/libjson-rpc-cpp/Manifest b/dev-cpp/libjson-rpc-cpp/Manifest
index 6c0de9f1f33..9296ea8ddd5 100644
--- a/dev-cpp/libjson-rpc-cpp/Manifest
+++ b/dev-cpp/libjson-rpc-cpp/Manifest
@@ -1 +1,2 @@
 DIST libjson-rpc-cpp-1.3.0.tar.gz 182354 BLAKE2B 512392c37e61833a98c1f682bdbb3ed0e3c72ff56f17407d49e5a0f134795daf5ff4c2702dd5222bfc8962b2c9a56c0c7856cc8fe1b923ea68c369a24d334b5c SHA512 4eb53c7b77845a0e845e42413c491dcfa1d6f72411276e8614dae6612edde8905013588465437ea39c5cc5700c2d48df07d15c83222924fc24e015fb9f7a02ea
+DIST libjson-rpc-cpp-1.4.0.tar.gz 179478 BLAKE2B 1b5807665a5e055790a6ca3e977845ab6b8dc7fbcaf6baece170567cc4c5b16202b74cb72f47136a075352ee408dac26de85cf02e41873cbbb55aeac1145e1a6 SHA512 28774604fe91f0893fb36017f648556dced71cb731f0f76c95084af5dd35e167b69a0f5fdb64557ff273f7dc971bc6c469e4f32ada35d7cac18add18baf2f5ae

diff --git a/dev-cpp/libjson-rpc-cpp/libjson-rpc-cpp-1.4.0.ebuild b/dev-cpp/libjson-rpc-cpp/libjson-rpc-cpp-1.4.0.ebuild
new file mode 100644
index 00000000000..02579592624
--- /dev/null
+++ b/dev-cpp/libjson-rpc-cpp/libjson-rpc-cpp-1.4.0.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake
+
+DESCRIPTION="JSON-RPC (1.0 & 2.0) framework for C++"
+HOMEPAGE="https://github.com/cinemast/libjson-rpc-cpp"
+SRC_URI="https://github.com/cinemast/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0/1"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc +http-client +http-server redis-client redis-server +stubgen test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-libs/jsoncpp:=
+	http-client? ( net-misc/curl:= )
+	http-server? ( net-libs/libmicrohttpd:= )
+	redis-client? ( dev-libs/hiredis:= )
+	redis-server? ( dev-libs/hiredis:= )
+	stubgen? ( dev-libs/argtable:= )"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	doc? ( app-doc/doxygen )
+	test? ( dev-cpp/catch:0 )"
+
+src_configure() {
+	local mycmakeargs=(
+		-DHTTP_CLIENT=$(usex http-client)
+		-DHTTP_SERVER=$(usex http-server)
+		-DREDIS_CLIENT=$(usex redis-client)
+		-DREDIS_SERVER=$(usex redis-server)
+		# they have no deps
+		-DTCP_SOCKET_CLIENT=ON
+		-DTCP_SOCKET_SERVER=ON
+		-DSERIAL_PORT_CLIENT=ON
+		-DSERIAL_PORT_SERVER=ON
+		-DUNIX_DOMAIN_SOCKET_CLIENT=ON
+		-DUNIX_DOMAIN_SOCKET_SERVER=ON
+		# they are not installed
+		-DCOMPILE_EXAMPLES=OFF
+		-DCOMPILE_STUBGEN=$(usex stubgen)
+		-DCOMPILE_TESTS=$(usex test)
+		-DCATCH_INCLUDE_DIR="${EPREFIX}/usr/include/catch2"
+	)
+
+	cmake_src_configure
+}
+
+src_compile() {
+	cmake_src_compile
+
+	use doc && emake -C "${BUILD_DIR}" doc
+}
+
+src_test() {
+	# Tests fail randomly when run in parallel
+	local MAKEOPTS=-j1
+	cmake_src_test
+}
+
+src_install() {
+	cmake_src_install
+
+	use doc && dodoc -r "${BUILD_DIR}"/doc/html
+}