[gentoo-commits] gentoo-x86 commit in sys-fs/loop-aes: loop-aes-3.6d.ebuild ChangeLog

[Robin H. Johnson (robbat2)]

robbat2     12/01/07 01:05:10

  Modified:             ChangeLog
  Added:                loop-aes-3.6d.ebuild
  Log:
  Version bump, bug #388759 to compile against kernel 3.2.
  
  (Portage version: 2.2.0_alpha84/cvs/Linux x86_64)

Revision  Changes    Path
1.80                 sys-fs/loop-aes/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-fs/loop-aes/ChangeLog?rev=1.80&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-fs/loop-aes/ChangeLog?rev=1.80&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-fs/loop-aes/ChangeLog?r1=1.79&r2=1.80

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-fs/loop-aes/ChangeLog,v
retrieving revision 1.79
retrieving revision 1.80
diff -p -w -b -B -u -u -r1.79 -r1.80
--- ChangeLog	13 Jun 2011 16:56:43 -0000	1.79
+++ ChangeLog	7 Jan 2012 01:05:10 -0000	1.80
@@ -1,6 +1,11 @@
 # ChangeLog for sys-fs/loop-aes
-# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-fs/loop-aes/ChangeLog,v 1.79 2011/06/13 16:56:43 c1pher Exp $
+# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/sys-fs/loop-aes/ChangeLog,v 1.80 2012/01/07 01:05:10 robbat2 Exp $
+
+*loop-aes-3.6d (07 Jan 2012)
+
+  07 Jan 2012; Robin H. Johnson <robbat2@g.o> +loop-aes-3.6d.ebuild:
+  Version bump, bug #388759 to compile against kernel 3.2.
 
 *loop-aes-3.6c (13 Jun 2011)
 



1.1                  sys-fs/loop-aes/loop-aes-3.6d.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-fs/loop-aes/loop-aes-3.6d.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-fs/loop-aes/loop-aes-3.6d.ebuild?rev=1.1&content-type=text/plain

Index: loop-aes-3.6d.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-fs/loop-aes/loop-aes-3.6d.ebuild,v 1.1 2012/01/07 01:05:10 robbat2 Exp $

EAPI="3"

inherit linux-mod

MY_P="${PN/aes/AES}-v${PV}"

DESCRIPTION="Linux kernel module to encrypt local file systems and disk partitions with AES cipher."
HOMEPAGE="http://loop-aes.sourceforge.net/loop-AES.README"
SRC_URI="mirror://sourceforge/${PN}/${MY_P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~arm ~hppa ~ppc ~sparc ~x86"
IUSE="aes-ni extra-ciphers keyscrub padlock"

DEPEND=">=sys-apps/util-linux-2.12r[crypt,loop-aes]"
RDEPEND="${DEPEND}"

S="${WORKDIR}/${MY_P}"

pkg_setup() {
	linux-mod_pkg_setup

	CONFIG_CHECK="!BLK_DEV_LOOP"
	MODULE_NAMES="loop(block::tmp-d-kbuild)"
	BUILD_TARGETS="all"

	BUILD_PARAMS=" \
		LINUX_SOURCE=\"${KERNEL_DIR}\" \
		KBUILD_OUTPUT=\"${KBUILD_OUTPUT}\" \
		USE_KBUILD=y MODINST=n RUNDM=n"
	use aes-ni && BUILD_PARAMS="${BUILD_PARAMS} INTELAES=y"
	use keyscrub && BUILD_PARAMS="${BUILD_PARAMS} KEYSCRUB=y"
	use padlock && BUILD_PARAMS="${BUILD_PARAMS} PADLOCK=y"

	if use extra-ciphers; then
		MODULE_NAMES="${MODULE_NAMES}
			loop_blowfish(block::tmp-d-kbuild)
			loop_serpent(block::tmp-d-kbuild)
			loop_twofish(block::tmp-d-kbuild)"
		BUILD_PARAMS="${BUILD_PARAMS} EXTRA_CIPHERS=y"
	fi
}

src_prepare() {
	sed -e 's/make/$(MAKE)/g' -i Makefile || die "sed failed"
}

src_install() {
	linux-mod_src_install

	dodoc README || die "dodoc failed"
	dobin loop-aes-keygen || die "dobin failed"
	doman loop-aes-keygen.1 || die "doman failed"
}

pkg_postinst() {
	linux-mod_pkg_postinst

	einfo
	einfo "For more instructions take a look at examples in README at:"
	einfo "'${EPREFIX}/usr/share/doc/${PF}'"
	einfo
	einfo "If you have a newer Intel processor (i5, i7), and you use AES"
	einfo "you may want to consider using the aes-ni use flag. It will"
	einfo "use your processors native AES instructions giving quite a speed"
	einfo "increase."
	einfo
}