[gentoo-commits] gentoo-x86 commit in media-video/mjpg-streamer: mjpg-streamer-0_pre20120621.ebuild ChangeLog

[Amadeusz Zolnowski (aidecoe)]

aidecoe     14/07/03 07:49:41

  Modified:             ChangeLog
  Added:                mjpg-streamer-0_pre20120621.ebuild
  Log:
  Version bump. Fixed bug #515406 on behalf of
  ChaosEngine <andrzej.pauli@×××××.com>.
  
  (Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key F0134531E1DBFAB5)

Revision  Changes    Path
1.8                  media-video/mjpg-streamer/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/mjpg-streamer/ChangeLog?rev=1.8&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/mjpg-streamer/ChangeLog?rev=1.8&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/mjpg-streamer/ChangeLog?r1=1.7&r2=1.8

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-video/mjpg-streamer/ChangeLog,v
retrieving revision 1.7
retrieving revision 1.8
diff -u -r1.7 -r1.8
--- ChangeLog	17 Mar 2013 16:05:48 -0000	1.7
+++ ChangeLog	3 Jul 2014 07:49:40 -0000	1.8
@@ -1,6 +1,14 @@
 # ChangeLog for media-video/mjpg-streamer
-# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-video/mjpg-streamer/ChangeLog,v 1.7 2013/03/17 16:05:48 hwoarang Exp $
+# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/media-video/mjpg-streamer/ChangeLog,v 1.8 2014/07/03 07:49:40 aidecoe Exp $
+
+*mjpg-streamer-0_pre20120621 (03 Jul 2014)
+
+  03 Jul 2014; Amadeusz Żołnowski <aidecoe@g.o>
+  +mjpg-streamer-0_pre20120621.ebuild,
+  +files/0_pre20120621-make-var-instead-of-cmd.patch:
+  Version bump. Fixed bug #515406 on behalf of
+  ChaosEngine <andrzej.pauli@×××××.com>.
 
   17 Mar 2013; Markos Chandras <hwoarang@g.o> metadata.xml:
   Add proxy-maintainers to metadata.xml



1.1                  media-video/mjpg-streamer/mjpg-streamer-0_pre20120621.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/mjpg-streamer/mjpg-streamer-0_pre20120621.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/mjpg-streamer/mjpg-streamer-0_pre20120621.ebuild?rev=1.1&content-type=text/plain

Index: mjpg-streamer-0_pre20120621.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-video/mjpg-streamer/mjpg-streamer-0_pre20120621.ebuild,v 1.1 2014/07/03 07:49:40 aidecoe Exp $

EAPI=4

inherit eutils

DESCRIPTION="MJPG-streamer takes JPGs from Linux-UVC compatible webcams"
HOMEPAGE="http://sourceforge.net/projects/mjpg-streamer"
SRC_URI="http://dev.gentoo.org/~aidecoe/distfiles/${CATEGORY}/${PN}/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86 ~amd64"

INPUT_PLUGINS="input_testpicture input_control input_file input_uvc"
OUTPUT_PLUGINS="output_file output_udp output_http output_autofocus output_rtsp"
IUSE_PLUGINS="${INPUT_PLUGINS} ${OUTPUT_PLUGINS}"
IUSE="input_testpicture input_control +input_file input_uvc output_file
	output_udp +output_http output_autofocus output_rtsp
	www v4l"
REQUIRED_USE="|| ( ${INPUT_PLUGINS} )
	|| ( ${OUTPUT_PLUGINS} )
	v4l? ( input_uvc )"

RDEPEND="virtual/jpeg
	v4l? ( input_uvc? ( media-libs/libv4l ) )"
DEPEND="${RDEPEND}
	input_testpicture? ( media-gfx/imagemagick )"

src_prepare() {
	epatch "${FILESDIR}/${PV}-make-var-instead-of-cmd.patch"

	local flag switch

	for flag in ${IUSE_PLUGINS}; do
		use ${flag} && switch='' || switch='#'
		sed -i \
			-e "s|^#*PLUGINS +\?= ${flag}.so|${switch}PLUGINS += ${flag}.so|" \
			Makefile
	done
}

src_compile() {
	local v4l=$(use v4l && use input_uvc && echo 'USE_LIBV4L2=true')
	emake ${v4l}
}

src_install() {
	into /usr
	dobin ${PN//-/_}
	dolib.so *.so

	if use www ; then
		insinto /usr/share/${PN}
		doins -r www
	fi

	dodoc README TODO

	newinitd "${FILESDIR}"/${PN}.initd ${PN}
	newconfd "${FILESDIR}"/${PN}.confd ${PN}
}

pkg_postinst() {
	elog "Remember to set an input and output plugin for mjpg-streamer."

	if use www ; then
		echo
		elog "An example webinterface has been installed into"
		elog "/usr/share/mjpg-streamer/www for your usage."
	fi
}