Get Gentoo!
gentoo.org sites
gentoo.org Wiki Bugs Forums Packages
Planet Archives Sources
Infra Status

Gentoo Archives: gentoo-commits

From: "Ian Stakenvicius (axs)" <axs@g.o>
To: gentoo-commits@l.g.o
Subject: [gentoo-commits] gentoo-x86 commit in media-gfx/freewrl: freewrl-1.22.13-r1.ebuild freewrl-1.22.13-r2.ebuild ChangeLog
Date: Sun, 04 Nov 2012 01:21:46
Message-Id: 20121104012128.86ADD215F3@flycatcher.gentoo.org
1 axs 12/11/04 01:21:28
2
3 Modified: freewrl-1.22.13-r1.ebuild ChangeLog
4 Added: freewrl-1.22.13-r2.ebuild
5 Log:
6 reduce elog spam, add EAPI=5 ebuild with slot-operator dep on spidermonkey
7
8 (Portage version: 2.1.11.30/cvs/Linux x86_64, signed Manifest commit with key 2B6559ED)
9
10 Revision Changes Path
11 1.3 media-gfx/freewrl/freewrl-1.22.13-r1.ebuild
12
13 file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/freewrl/freewrl-1.22.13-r1.ebuild?rev=1.3&view=markup
14 plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/freewrl/freewrl-1.22.13-r1.ebuild?rev=1.3&content-type=text/plain
15 diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/freewrl/freewrl-1.22.13-r1.ebuild?r1=1.2&r2=1.3
16
17 Index: freewrl-1.22.13-r1.ebuild
18 ===================================================================
19 RCS file: /var/cvsroot/gentoo-x86/media-gfx/freewrl/freewrl-1.22.13-r1.ebuild,v
20 retrieving revision 1.2
21 retrieving revision 1.3
22 diff -u -r1.2 -r1.3
23 --- freewrl-1.22.13-r1.ebuild 24 Oct 2012 19:12:13 -0000 1.2
24 +++ freewrl-1.22.13-r1.ebuild 4 Nov 2012 01:21:28 -0000 1.3
25 @@ -1,6 +1,6 @@
26 # Copyright 1999-2012 Gentoo Foundation
27 # Distributed under the terms of the GNU General Public License v2
28 -# $Header: /var/cvsroot/gentoo-x86/media-gfx/freewrl/freewrl-1.22.13-r1.ebuild,v 1.2 2012/10/24 19:12:13 ulm Exp $
29 +# $Header: /var/cvsroot/gentoo-x86/media-gfx/freewrl/freewrl-1.22.13-r1.ebuild,v 1.3 2012/11/04 01:21:28 axs Exp $
30
31 EAPI=4
32
33 @@ -117,10 +117,12 @@
34 # install vrml.jar as a JRE extension
35 dodir /usr/java/packages/lib/ext
36 dosym /usr/share/${PN}/lib/vrml.jar /usr/java/packages/lib/ext/vrml.jar
37 + if ! has_version "media-gfx/freewrl[java]" ; then
38 elog "Because vrml.jar requires access to sockets, you will need to incorporate the"
39 elog "contents of /usr/share/${PN}/lib/java.policy into your system or user's default"
40 elog "java policy:"
41 elog " cat /usr/share/${PN}/lib/java.policy >>~/.java.policy"
42 + fi
43 fi
44
45 # remove unneeded .la files (as per Flameeyes' rant)
46 @@ -129,8 +131,10 @@
47 }
48
49 pkg_postinst() {
50 + if [[ -z ${REPLACING_VERSIONS} ]]; then
51 elog "By default, FreeWRL expects to find the 'firefox' binary in your include"
52 elog "path. If you do not have firefox installed or you wish to use a different"
53 elog "web browser to open links that are within VRML / X3D files, please be sure to"
54 elog "specify the command via your BROWSER environment variable."
55 + fi
56 }
57
58
59
60 1.50 media-gfx/freewrl/ChangeLog
61
62 file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/freewrl/ChangeLog?rev=1.50&view=markup
63 plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/freewrl/ChangeLog?rev=1.50&content-type=text/plain
64 diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/freewrl/ChangeLog?r1=1.49&r2=1.50
65
66 Index: ChangeLog
67 ===================================================================
68 RCS file: /var/cvsroot/gentoo-x86/media-gfx/freewrl/ChangeLog,v
69 retrieving revision 1.49
70 retrieving revision 1.50
71 diff -u -r1.49 -r1.50
72 --- ChangeLog 24 Oct 2012 19:12:13 -0000 1.49
73 +++ ChangeLog 4 Nov 2012 01:21:28 -0000 1.50
74 @@ -1,6 +1,12 @@
75 # ChangeLog for media-gfx/freewrl
76 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
77 -# $Header: /var/cvsroot/gentoo-x86/media-gfx/freewrl/ChangeLog,v 1.49 2012/10/24 19:12:13 ulm Exp $
78 +# $Header: /var/cvsroot/gentoo-x86/media-gfx/freewrl/ChangeLog,v 1.50 2012/11/04 01:21:28 axs Exp $
79 +
80 +*freewrl-1.22.13-r2 (04 Nov 2012)
81 +
82 + 04 Nov 2012; Ian Stakenvicius <axs@g.o> freewrl-1.22.13-r1.ebuild,
83 + +freewrl-1.22.13-r2.ebuild:
84 + reduce elog spam, add EAPI=5 ebuild with slot-operator dep on spidermonkey
85
86 24 Oct 2012; Ulrich Müller <ulm@g.o> freewrl-1.22.13-r1.ebuild:
87 Update dependency after package move from x11-libs/openmotif to
88
89
90
91 1.1 media-gfx/freewrl/freewrl-1.22.13-r2.ebuild
92
93 file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/freewrl/freewrl-1.22.13-r2.ebuild?rev=1.1&view=markup
94 plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/freewrl/freewrl-1.22.13-r2.ebuild?rev=1.1&content-type=text/plain
95
96 Index: freewrl-1.22.13-r2.ebuild
97 ===================================================================
98 # Copyright 1999-2012 Gentoo Foundation
99 # Distributed under the terms of the GNU General Public License v2
100 # $Header: /var/cvsroot/gentoo-x86/media-gfx/freewrl/freewrl-1.22.13-r2.ebuild,v 1.1 2012/11/04 01:21:28 axs Exp $
101
102 EAPI=5
103
104 inherit autotools nsplugins eutils flag-o-matic java-pkg-opt-2 multilib
105
106 DESCRIPTION="VRML97 and X3D compliant browser, library, and web-browser plugin"
107 HOMEPAGE="http://freewrl.sourceforge.net/"
108 SRC_URI="mirror://sourceforge/freewrl/${P}.1.tar.bz2"
109
110 LICENSE="GPL-3"
111 SLOT="0"
112 KEYWORDS="~amd64 ~x86"
113 IUSE="curl debug +glew java libeai motif +nsplugin osc +sox static-libs"
114
115 COMMONDEPEND="x11-libs/libXau
116 x11-libs/libXdmcp
117 x11-libs/libXext
118 x11-libs/libX11
119 motif? ( x11-libs/motif )
120 !motif? ( x11-libs/libXaw )
121 media-libs/mesa
122 glew? ( media-libs/glew )
123 virtual/opengl
124 media-libs/libpng
125 virtual/jpeg
126 media-libs/imlib2
127 >=media-libs/freetype-2
128 media-libs/fontconfig
129 curl? ( net-misc/curl )
130 osc? ( media-libs/liblo )
131 dev-lang/spidermonkey:="
132 DEPEND="${COMMONDEPEND}
133 virtual/pkgconfig
134 java? ( >=virtual/jdk-1.4 )
135 nsplugin? ( net-misc/npapi-sdk )"
136 RDEPEND="${COMMONDEPEND}
137 media-fonts/dejavu
138 || ( media-gfx/imagemagick
139 media-gfx/graphicsmagick[imagemagick] )
140 app-arch/unzip
141 java? ( >=virtual/jre-1.4 )
142 sox? ( media-sound/sox )"
143
144 src_prepare() {
145 epatch "${FILESDIR}"/${P}-fontconfig-match.patch
146 if has_version ">=dev-lang/spidermonkey-1.8.7" ; then
147 epatch "${FILESDIR}"/${P}-mozjs187-config.patch
148 eautoreconf
149 fi
150 }
151
152 src_configure() {
153 local myconf="--enable-fontconfig
154 --without-expat
155 --with-x
156 --with-imageconvert=/usr/bin/convert
157 --with-unzip=/usr/bin/unzip"
158 if use motif; then
159 myconf+=" --with-target=motif --with-statusbar=standard"
160 else
161 myconf+=" --with-target=x11 --with-statusbar=hud"
162 fi
163 if use nsplugin; then
164 myconf+=" --with-plugindir=/usr/$(get_libdir)/${PLUGINS_DIR}"
165 myconf+=" --disable-mozilla-plugin --disable-xulrunner-plugin"
166 fi
167 if use sox; then
168 myconf+=" --with-soundconv=/usr/bin/sox"
169 fi
170 # disable the checks for other js libs, in case they are installed
171 if has_version ">=dev-lang/spidermonkey-1.8.5" ; then
172 # spidermonkey-1.8.5 provides a .pc to pkg-config, it should be findable via mozjs185
173 for x in mozilla-js xulrunner-js firefox-js firefox2-js seamonkey-js; do
174 myconf+=" --disable-${x}"
175 done
176 else
177 for x in mozjs187 mozjs185 mozilla-js xulrunner-js firefox-js seamonkey-js; do
178 myconf+=" --disable-${x}"
179 done
180 # spidermonkey pre-1.8.5 has no pkg-config, so override ./configure
181 JAVASCRIPT_ENGINE_CFLAGS="-I/usr/include/js -DXP_UNIX"
182 if has_version ">=dev-lang/spidermonkey-1.8" ; then
183 # spidermonkey-1.8 changed the name of the lib
184 JAVASCRIPT_ENGINE_LIBS="-lmozjs"
185 else
186 JAVASCRIPT_ENGINE_LIBS="-ljs"
187 fi
188 if has_version dev-lang/spidermonkey[threadsafe] ; then
189 JAVASCRIPT_ENGINE_CFLAGS+=" -DJS_THREADSAFE $(pkg-config --cflags nspr)"
190 JAVASCRIPT_ENGINE_LIBS="$(pkg-config --libs nspr) ${JAVASCRIPT_ENGINE_LIBS}"
191 fi
192 export JAVASCRIPT_ENGINE_CFLAGS
193 export JAVASCRIPT_ENGINE_LIBS
194 fi
195 econf ${myconf} \
196 $(use_enable curl libcurl) \
197 $(use_with glew) \
198 $(use_enable debug) $(use_enable debug thread_colorized) \
199 $(use_enable libeai) \
200 $(use_enable java) \
201 $(use_enable nsplugin plugin) \
202 $(use_enable osc) \
203 $(use_enable static-libs static) \
204 $(use_enable sox sound)
205 }
206
207 src_install() {
208 emake DESTDIR="${D}" install
209
210 if use java; then
211 insinto /usr/share/${PN}/lib
212 doins src/java/java.policy
213 java-pkg_regjar src/java/vrml.jar
214 # install vrml.jar as a JRE extension
215 dodir /usr/java/packages/lib/ext
216 dosym /usr/share/${PN}/lib/vrml.jar /usr/java/packages/lib/ext/vrml.jar
217 if ! has_version "media-gfx/freewrl[java]" ; then
218 elog "Because vrml.jar requires access to sockets, you will need to incorporate the"
219 elog "contents of /usr/share/${PN}/lib/java.policy into your system or user's default"
220 elog "java policy:"
221 elog " cat /usr/share/${PN}/lib/java.policy >>~/.java.policy"
222 fi
223 fi
224
225 # remove unneeded .la files (as per Flameeyes' rant)
226 cd "${D}"
227 rm "usr/$(get_libdir)"/*.la "usr/$(get_libdir)/${PLUGINS_DIR}"/*.la
228 }
229
230 pkg_postinst() {
231 if [[ -z ${REPLACING_VERSIONS} ]]; then
232 elog "By default, FreeWRL expects to find the 'firefox' binary in your include"
233 elog "path. If you do not have firefox installed or you wish to use a different"
234 elog "web browser to open links that are within VRML / X3D files, please be sure to"
235 elog "specify the command via your BROWSER environment variable."
236 fi
237 }
Report Message
Find on MARC Find on Google Groups