[gentoo-commits] repo/gentoo:master commit in: app-admin/rasdaemon/

[Matthew Thode]

commit:     78cae72a3eef162d5ff2af6af7a10a61aadbf406
Author:     Georgy Yakovlev <gyakovlev <AT> gentoo <DOT> org>
AuthorDate: Wed Dec 12 06:26:23 2018 +0000
Commit:     Matthew Thode <prometheanfire <AT> gentoo <DOT> org>
CommitDate: Wed Dec 12 07:04:19 2018 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=78cae72a

app-admin/rasdaemon: fix multiple issues

Package-Manager: Portage-2.3.52, Repoman-2.3.12
Signed-off-by: Georgy Yakovlev <gyakovlev <AT> gentoo.org>
Signed-off-by: Matthew Thode <prometheanfire <AT> gentoo.org>

 app-admin/rasdaemon/rasdaemon-0.6.2-r2.ebuild | 57 +++++++++++++++++++++++++++
 1 file changed, 57 insertions(+)

diff --git a/app-admin/rasdaemon/rasdaemon-0.6.2-r2.ebuild b/app-admin/rasdaemon/rasdaemon-0.6.2-r2.ebuild
new file mode 100644
index 00000000000..0e27e9fe31e
--- /dev/null
+++ b/app-admin/rasdaemon/rasdaemon-0.6.2-r2.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit linux-info systemd
+
+DESCRIPTION="Reliability, Availability and Serviceability logging tool"
+HOMEPAGE="http://www.infradead.org/~mchehab/rasdaemon/"
+SRC_URI="http://www.infradead.org/~mchehab/${PN}/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+
+DEPEND=""
+RDEPEND="
+	${DEPEND}
+	sys-devel/gettext
+	dev-db/sqlite
+	sys-apps/dmidecode
+	dev-perl/DBD-SQLite
+"
+
+pkg_setup() {
+	linux-info_pkg_setup
+	local CONFIG_CHECK="~ACPI_EXTLOG ~DYNAMIC_FTRACE ~FUNCTION_GRAPH_TRACER  ~FUNCTION_TRACER ~STACK_TRACER"
+	check_extra_config
+}
+
+src_configure() {
+	local myconf=(
+		--enable-abrt-report
+		--enable-aer
+		--enable-arm
+		--enable-extlog
+		--enable-hisi-ns-decode
+		--enable-mce
+		--enable-non-standard
+		--enable-sqlite3
+		--includedir="/usr/include/${PN}"
+		--localstatedir=/var
+	)
+	econf "${myconf[@]}"
+}
+
+src_install() {
+	default
+
+	keepdir "/var/lib/${PN}"
+
+	systemd_dounit misc/*.service
+
+	newinitd "${FILESDIR}/rasdaemon.openrc" rasdaemon
+	newinitd "${FILESDIR}/ras-mc-ctl.openrc" ras-mc-ctl
+}