[gentoo-commits] gentoo-x86 commit in net-irc/inspircd: ChangeLog inspircd-2.0.7.ebuild

[JosA MarAa Alonso (nimiux)]

nimiux      12/07/07 12:35:20

  Modified:             ChangeLog
  Added:                inspircd-2.0.7.ebuild
  Log:
  [net-irc/inspircd] Revision bump to 2.0.7.
  
  (Portage version: 2.1.10.65/cvs/Linux x86_64)

Revision  Changes    Path
1.51                 net-irc/inspircd/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-irc/inspircd/ChangeLog?rev=1.51&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-irc/inspircd/ChangeLog?rev=1.51&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-irc/inspircd/ChangeLog?r1=1.50&r2=1.51

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-irc/inspircd/ChangeLog,v
retrieving revision 1.50
retrieving revision 1.51
diff -u -r1.50 -r1.51
--- ChangeLog	23 Jun 2012 17:16:04 -0000	1.50
+++ ChangeLog	7 Jul 2012 12:35:20 -0000	1.51
@@ -1,6 +1,12 @@
 # ChangeLog for net-irc/inspircd
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-irc/inspircd/ChangeLog,v 1.50 2012/06/23 17:16:04 nimiux Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-irc/inspircd/ChangeLog,v 1.51 2012/07/07 12:35:20 nimiux Exp $
+
+*inspircd-2.0.7 (07 Jul 2012)
+
+  07 Jul 2012; Chema Alonso <nimiux@g.o> +inspircd-2.0.7.ebuild,
+  +files/inspircd-2.0.7-fix-path-builds.patch, +files/inspircd-2.0.7-init:
+  Revision bump to 2.0.7
 
   23 Jun 2012; Chema Alonso <nimiux@g.o> inspircd-2.0.6_rc1.ebuild,
   +files/inspircd-2.0.6_rc1-gcc-4.7.patch, metadata.xml:



1.1                  net-irc/inspircd/inspircd-2.0.7.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-irc/inspircd/inspircd-2.0.7.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-irc/inspircd/inspircd-2.0.7.ebuild?rev=1.1&content-type=text/plain

Index: inspircd-2.0.7.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-irc/inspircd/inspircd-2.0.7.ebuild,v 1.1 2012/07/07 12:35:20 nimiux Exp $

EAPI=4

inherit eutils flag-o-matic multilib

DESCRIPTION="Inspire IRCd - The Stable, High-Performance Modular IRCd"
HOMEPAGE="http://inspircd.github.com/"
SRC_URI="http://github.com/inspircd/inspircd/downloads/InspIRCd-${PV}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="geoip gnutls ipv6 ldap mysql postgres sqlite ssl"

RDEPEND="
	dev-lang/perl
	ssl? ( dev-libs/openssl )
	geoip? ( dev-libs/geoip )
	gnutls? ( net-libs/gnutls dev-libs/libgcrypt )
	ldap? ( net-nds/openldap )
	mysql? ( virtual/mysql )
	postgres? ( dev-db/postgresql-server )
	sqlite? ( >=dev-db/sqlite-3.0 )"
DEPEND="${RDEPEND}"

S="${WORKDIR}/${PN}"

pkg_setup() {
	enewgroup ${PN}
	enewuser ${PN} -1 -1 -1 ${PN}
}

src_prepare() {
	# Patch the inspircd launcher with the inspircd user
	sed -i -e "s/@UID@/${PN}/" "${S}/make/template/${PN}" || die

	epatch "${FILESDIR}/${PF}-fix-path-builds.patch"
}

src_configure() {
	local extras=""
	local essl="--enable-openssl"
	local egnutls="--enable-gnutls"
	local dipv6="--disable-ipv6"

	use geoip && extras="${extras}m_geoip.cpp,"
	use gnutls && extras="${extras}m_ssl_gnutls.cpp,"
	use ldap && extras="${extras}m_ldapauth.cpp,"
	use mysql && extras="${extras}m_mysql.cpp,"
	use postgres && extras="${extras}m_pgsql.cpp,"
	use sqlite && extras="${extras}m_sqlite3.cpp,"
	use ssl && extras="${extras}m_ssl_openssl.cpp,"

	# allow inspircd to be built by root
	touch .force-root-ok || die

	if [ -n "${extras}" ]; then
		./configure --disable-interactive \
			--enable-extras=${extras} || die
	fi

	use !ssl && essl=""
	use !gnutls && egnutls=""
	use ipv6 && dipv6=""

	./configure \
		--disable-interactive \
		--prefix="/usr/$(get_libdir)/${PN}" \
		--config-dir="/etc/${PN}" \
		--binary-dir="/usr/bin" \
		--module-dir="/usr/$(get_libdir)/${PN}/modules" \
		${essl} ${egnutls} ${dipv6} || die
}

src_compile() {
	append-cxxflags -Iinclude -fPIC
	emake LDFLAGS="${LDFLAGS}" CXXFLAGS="${CXXFLAGS}"
}

src_install() {
	emake INSTUID=${PN} \
		BINPATH="${D}/usr/bin" \
		BASE="${D}/usr/$(get_libdir)/${PN}/inspircd.launcher" \
		MODPATH="${D}/usr/$(get_libdir)/${PN}/modules/" \
		CONPATH="${D}/etc/${PN}" install

	insinto /usr/include/"${PN}"
	doins include/*

	diropts -o"${PN}" -g"${PN}"
	dodir "/var/run/${PN}" "/var/lib/${PN}/data"

	newinitd "${FILESDIR}/${PF}-init" "${PN}"
	keepdir "/var/log/${PN}"/
}

pkg_postinst() {
	elog "Before starting ${PN} the first time you should create"
	elog "the /etc/${PN}/${PN}.conf file."
	elog "You can find example configuration files under /etc/${PN}"
	elog "Read the ${PN}.conf.example file carefully before starting "
	elog "the service."
	elog
}