[gentoo-commits] gentoo-x86 commit in net-libs/libtirpc: libtirpc-0.2.4-r2.ebuild ChangeLog

[Michal Gorny (mgorny)]

mgorny      14/05/30 14:22:20

  Modified:             ChangeLog
  Added:                libtirpc-0.2.4-r2.ebuild
  Log:
  Enable multilib support.
  
  (Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key EFB4464E!)

Revision  Changes    Path
1.34                 net-libs/libtirpc/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/libtirpc/ChangeLog?rev=1.34&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/libtirpc/ChangeLog?rev=1.34&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/libtirpc/ChangeLog?r1=1.33&r2=1.34

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-libs/libtirpc/ChangeLog,v
retrieving revision 1.33
retrieving revision 1.34
diff -u -r1.33 -r1.34
--- ChangeLog	2 Feb 2014 07:59:58 -0000	1.33
+++ ChangeLog	30 May 2014 14:22:20 -0000	1.34
@@ -1,6 +1,11 @@
 # ChangeLog for net-libs/libtirpc
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-libs/libtirpc/ChangeLog,v 1.33 2014/02/02 07:59:58 vapier Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-libs/libtirpc/ChangeLog,v 1.34 2014/05/30 14:22:20 mgorny Exp $
+
+*libtirpc-0.2.4-r2 (30 May 2014)
+
+  30 May 2014; Michał Górny <mgorny@g.o> +libtirpc-0.2.4-r2.ebuild:
+  Enable multilib support.
 
 *libtirpc-0.2.4-r1 (02 Feb 2014)
 



1.1                  net-libs/libtirpc/libtirpc-0.2.4-r2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/libtirpc/libtirpc-0.2.4-r2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/libtirpc/libtirpc-0.2.4-r2.ebuild?rev=1.1&content-type=text/plain

Index: libtirpc-0.2.4-r2.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-libs/libtirpc/libtirpc-0.2.4-r2.ebuild,v 1.1 2014/05/30 14:22:20 mgorny Exp $

EAPI="4"

inherit multilib-minimal toolchain-funcs

DESCRIPTION="Transport Independent RPC library (SunRPC replacement)"
HOMEPAGE="http://libtirpc.sourceforge.net/"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.bz2
	mirror://gentoo/${PN}-glibc-nfs.tar.xz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86"
IUSE="ipv6 kerberos static-libs"

RDEPEND="kerberos? ( virtual/krb5[${MULTILIB_USEDEP}] )"
DEPEND="${RDEPEND}
	app-arch/xz-utils
	virtual/pkgconfig[${MULTILIB_USEDEP}]"
RDEPEND="${RDEPEND}
	abi_x86_32? (
		!<=app-emulation/emul-linux-x86-baselibs-20140508-r7
		!app-emulation/emul-linux-x86-baselibs[-abi_x86_32(-)]
	)"

src_unpack() {
	unpack ${A}
	cp -r tirpc "${S}"/ || die
}

multilib_src_configure() {
	ECONF_SOURCE=${S} \
	econf \
		$(use_enable ipv6) \
		$(use_enable kerberos gssapi) \
		$(use_enable static-libs static)
}

multilib_src_install() {
	default

	# libtirpc replaces rpc support in glibc, so we need it in /
	multilib_is_native_abi && gen_usr_ldscript -a tirpc
}

multilib_src_install_all() {
	einstalldocs

	insinto /etc
	doins doc/netconfig

	insinto /usr/include/tirpc
	doins -r "${WORKDIR}"/tirpc/*

	# makes sure that the linking order for nfs-utils is proper, as
	# libtool would inject a libgssglue dependency in the list.
	use static-libs || prune_libtool_files
}