[gentoo-commits] gentoo-x86 commit in app-emulation/libvirt: libvirt-0.6.3-r2.ebuild ChangeLog metadata.xml

[Doug Goldstein (cardoe)]

cardoe      09/05/28 16:27:25

  Modified:             ChangeLog metadata.xml
  Added:                libvirt-0.6.3-r2.ebuild
  Log:
  Support NUMA segmentation. Fix VirtualBox depend. Require QEMU 0.10.0 and higher for additional QEMU feature support. Several fixes from upstream.
  (Portage version: 2.1.6.13/cvs/Linux x86_64)

Revision  Changes    Path
1.25                 app-emulation/libvirt/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-emulation/libvirt/ChangeLog?rev=1.25&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-emulation/libvirt/ChangeLog?rev=1.25&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-emulation/libvirt/ChangeLog?r1=1.24&r2=1.25

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-emulation/libvirt/ChangeLog,v
retrieving revision 1.24
retrieving revision 1.25
diff -u -r1.24 -r1.25
--- ChangeLog	27 May 2009 22:34:30 -0000	1.24
+++ ChangeLog	28 May 2009 16:27:25 -0000	1.25
@@ -1,6 +1,17 @@
 # ChangeLog for app-emulation/libvirt
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-emulation/libvirt/ChangeLog,v 1.24 2009/05/27 22:34:30 cardoe Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-emulation/libvirt/ChangeLog,v 1.25 2009/05/28 16:27:25 cardoe Exp $
+
+*libvirt-0.6.3-r2 (28 May 2009)
+
+  28 May 2009; Doug Goldstein <cardoe@g.o>
+  +files/libvirt-0.6.2-enable-qemu-0-10-migration.patch,
+  +files/libvirt-0.6.2-fix-nosource-label.patch,
+  +files/libvirt-0.6.2-shared-readonly-label.patch,
+  +libvirt-0.6.3-r2.ebuild, +files/libvirt-0.6.3-hostdev-managed.patch,
+  +files/libvirt-0.6.3-refresh-qemu-caps.patch, metadata.xml:
+  Support NUMA segmentation. Fix VirtualBox depend. Require QEMU 0.10.0 and
+  higher for additional QEMU feature support. Several fixes from upstream.
 
 *libvirt-0.6.3-r1 (27 May 2009)
 



1.13                 app-emulation/libvirt/metadata.xml

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-emulation/libvirt/metadata.xml?rev=1.13&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-emulation/libvirt/metadata.xml?rev=1.13&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-emulation/libvirt/metadata.xml?r1=1.12&r2=1.13

Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-emulation/libvirt/metadata.xml,v
retrieving revision 1.12
retrieving revision 1.13
diff -u -r1.12 -r1.13
--- metadata.xml	27 May 2009 22:34:30 -0000	1.12
+++ metadata.xml	28 May 2009 16:27:25 -0000	1.13
@@ -31,5 +31,7 @@
 		<flag name='network'>Enable networking support for guests</flag>
 		<flag name='virtualbox'>Adds support for VirtualBox based virtual
 			machines</flag>
+		<flag name='numa'>Use NUMA for memory segmenting via
+			<pkg>sys-process/numactl</pkg></flag>
 	</use>
 </pkgmetadata>



1.1                  app-emulation/libvirt/libvirt-0.6.3-r2.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-emulation/libvirt/libvirt-0.6.3-r2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-emulation/libvirt/libvirt-0.6.3-r2.ebuild?rev=1.1&content-type=text/plain

Index: libvirt-0.6.3-r2.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-emulation/libvirt/libvirt-0.6.3-r2.ebuild,v 1.1 2009/05/28 16:27:25 cardoe Exp $

EAPI="2"

inherit eutils autotools confutils

DESCRIPTION="C toolkit to manipulate virtual machines"
HOMEPAGE="http://www.libvirt.org/"
SRC_URI="http://libvirt.org/sources/${P}.tar.gz"
LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="avahi iscsi hal kvm lvm +lxc +network nls numa openvz policykit \
	parted qemu sasl selinux uml virtualbox xen"
# devicekit isn't in portage

RDEPEND="sys-libs/readline
	sys-libs/ncurses
	>=dev-libs/libxml2-2.5
	>=net-libs/gnutls-1.0.25
	dev-lang/python
	sys-fs/sysfsutils
	net-analyzer/netcat
	avahi? ( >=net-dns/avahi-0.6 )
	iscsi? ( sys-block/open-iscsi )
	kvm? ( app-emulation/kvm )
	lvm? ( sys-fs/lvm2 )
	network? ( net-misc/bridge-utils net-dns/dnsmasq net-firewall/iptables )
	numa? ( sys-process/numactl )
	openvz? ( sys-kernel/openvz-sources )
	parted? ( >=sys-apps/parted-1.8 )
	policykit? ( >=sys-auth/policykit-0.6 )
	qemu? ( >=app-emulation/qemu-0.10.0 )
	sasl? ( dev-libs/cyrus-sasl )
	selinux? ( sys-libs/libselinux )
	virtualbox? ( >=app-emulation/virtualbox-bin-2.2.0 )
	xen? ( app-emulation/xen-tools app-emulation/xen )"
DEPEND="${RDEPEND}
	dev-util/pkgconfig"

src_prepare() {
	# Fix argv handling for KVM 85 and newer
	epatch "${FILESDIR}/${P}-kvm-85-argv-detection.patch"
	# Patch sent upstream for working with kvm-img
	epatch "${FILESDIR}/${P}-kvm-img.patch"
	# upstream patch. fix shared/read-only disk labeling
	epatch "${FILESDIR}/${PN}-0.6.2-shared-readonly-label.patch"
	# upstream patch. fix <hostdev managed='yes'>
	epatch "${FILESDIR}/${P}-hostdev-managed.patch"
	# upstream patch. refresh qemu caps when getCapabilities is called
	epatch "${FILESDIR}/${P}-refresh-qemu-caps.patch"
	# upstream patch. enable migration support which appeared in QEMU 0.10.0
	epatch "${FILESDIR}/${PN}-0.6.2-enable-qemu-0-10-migration.patch"
	# upstream patch. don't try to label a disk with no path (empty cdrom)
	epatch "${FILESDIR}/${PN}-0.6.2-fix-nosource-label.patch"

	eautoreconf
}

pkg_setup() {
	confutils_require_any lxc kvm openvz qemu uml virtualbox xen
}

src_configure() {
	local my_conf=""
	if use qemu || use kvm ; then
		my_conf="--with-qemu"
	else
		my_conf="--without-qemu"
	fi

	econf \
		$(use_with iscsi storage-iscsi) \
		$(use_with lvm storage-lvm) \
		$(use_with parted storage-disk) \
		$(use_with lxc) \
		$(use_with openvz) \
		$(use_with uml) \
		$(use_with virtualbox vbox) \
		$(use_with xen) \
		$(use_with xen xen-inotify) \
		$(use_with avahi) \
		$(use_with hal) \
		$(use_with sasl) \
		$(use_with network) \
		$(use_with policykit polkit) \
		$(use_with selinux) \
		$(use_enable nls) \
		$(use_with numa numactl) \
		${my_conf} \
		--without-devkit \
		--with-remote \
		--disable-iptables-lokkit \
		--localstatedir=/var \
		--with-remote-pid-file=/var/run/libvirtd.pid
}

src_install() {
	emake DESTDIR="${D}" install || die "emake instal lfailed"
	mv "${D}"/usr/share/doc/{${PN}-python*,${P}/python}

	newinitd "${FILESDIR}/libvirtd.init" libvirtd
	newconfd "${FILESDIR}/libvirtd.confd" libvirtd

	keepdir /var/lib/libvirt/images
}

pkg_postinst() {
	elog "To allow normal users to connect to libvirtd you must change the"
	elog " unix sock group and/or perms in /etc/libvirt/libvirtd.conf"
	elog
	ewarn "If you have a DNS server setup on your machine, you will have"
	ewarn "to configure /etc/dnsmasq.conf to enable the following settings: "
	ewarn " bind-interfaces"
	ewarn " interface or except-interface"
	elog
	ewarn "Otherwise you might have issues with your existing DNS server."
}