[gentoo-commits] gentoo-x86 commit in app-office/magicpoint: ChangeLog magicpoint-1.12a-r1.ebuild magicpoint-1.12a.ebuild

[Christian Faulhammer (opfer)]

opfer       07/09/25 11:50:19

  Modified:             ChangeLog
  Added:                magicpoint-1.12a-r1.ebuild
  Removed:              magicpoint-1.12a.ebuild
  Log:
  remove old ebuild; introduce doc and examples USE flags; don't install COPYRIGHT files; make intallation succesful even without USE=emacs
  (Portage version: 2.1.3.9)

Revision  Changes    Path
1.29                 app-office/magicpoint/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-office/magicpoint/ChangeLog?rev=1.29&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-office/magicpoint/ChangeLog?rev=1.29&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-office/magicpoint/ChangeLog?r1=1.28&r2=1.29

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-office/magicpoint/ChangeLog,v
retrieving revision 1.28
retrieving revision 1.29
diff -u -r1.28 -r1.29
--- ChangeLog	25 Sep 2007 06:13:52 -0000	1.28
+++ ChangeLog	25 Sep 2007 11:50:19 -0000	1.29
@@ -1,6 +1,13 @@
 # ChangeLog for app-office/magicpoint
 # Copyright 2002-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-office/magicpoint/ChangeLog,v 1.28 2007/09/25 06:13:52 opfer Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-office/magicpoint/ChangeLog,v 1.29 2007/09/25 11:50:19 opfer Exp $
+
+*magicpoint-1.12a-r1 (25 Sep 2007)
+
+  25 Sep 2007; Christian Faulhammer <opfer@g.o>
+  -magicpoint-1.12a.ebuild, +magicpoint-1.12a-r1.ebuild:
+  remove old ebuild; introduce doc and examples USE flags; don't install
+  COPYRIGHT files; make intallation succesful even without USE=emacs
 
   25 Sep 2007; Christian Faulhammer <opfer@g.o>
   magicpoint-1.12a.ebuild:



1.1                  app-office/magicpoint/magicpoint-1.12a-r1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-office/magicpoint/magicpoint-1.12a-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-office/magicpoint/magicpoint-1.12a-r1.ebuild?rev=1.1&content-type=text/plain

Index: magicpoint-1.12a-r1.ebuild
===================================================================
# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-office/magicpoint/magicpoint-1.12a-r1.ebuild,v 1.1 2007/09/25 11:50:19 opfer Exp $

inherit autotools elisp-common eutils fixheadtails

DESCRIPTION="An X11 based presentation tool"
SRC_URI="ftp://sh.wide.ad.jp/WIDE/free-ware/mgp/${P}.tar.gz
	ftp://ftp.mew.org/pub/MagicPoint/${P}.tar.gz"
HOMEPAGE="http://member.wide.ad.jp/wg/mgp/"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~alpha ~ppc ~sparc ~x86"
IUSE="cjk doc emacs examples gif imlib m17n-lib nls truetype"

MY_DEPEND="x11-libs/libICE
	x11-libs/libSM
	x11-libs/libXrender
	x11-libs/libXmu
	gif? ( >=media-libs/giflib-4.0.1 )
	imlib? ( media-libs/imlib )
	truetype? ( virtual/xft )
	emacs? ( virtual/emacs )
	m17n-lib? ( dev-libs/m17n-lib )
	mng? ( media-libs/libmng )"
DEPEND="${MY_DEPEND}
	sys-devel/autoconf
	x11-proto/xextproto
	x11-libs/libxkbfile
	app-text/rman
	x11-misc/imake"
RDEPEND="${MY_DEPEND}
	nls? ( sys-devel/gettext )
	truetype? ( cjk? ( media-fonts/sazanami ) )"

SITEFILE=50${PN}-gentoo.el

src_unpack() {
	unpack ${A}
	cd "${S}"
	epatch "${FILESDIR}/${PN}-1.11b-gentoo.diff"

	# bug #85720
	sed -i -e "s/ungif/gif/g" configure.in || die "sed failed"
	ht_fix_file configure.in
	eautoreconf
}

src_compile() {
	econf \
		$(use_enable gif) \
		$(use_enable imlib) \
		$(use_enable nls locale) \
		$(use_enable truetype xft2) \
		$(use_with m17n-lib) \
		--disable-vflib \
		--disable-freetype \
		--x-libraries=/usr/X11R6/lib \
		--x-includes=/usr/X11R6/include || die "econf failed"

	xmkmf || die "xmkmf failed"
	# no parallel build possibly, anywhere
	emake -j1 Makefiles || die "emake Makefiles failed"
	emake -j1 clean || die "emake clean failed"
	emake -j1 BINDIR=/usr/bin LIBDIR=/etc/X11 || die "emake failed"
	if use emacs; then
	   cd contrib/
	   elisp-compile *.el || die "elisp-compile failed"
	fi
}

src_install() {
	emake -j1 \
		DESTDIR="${D}" \
		BINDIR=/usr/bin \
		LIBDIR=/etc/X11 \
		install || die "emake install failed"

	emake -j1 \
		DESTDIR="${D}" \
		DOCHTMLDIR=/usr/share/doc/${PF} \
		MANPATH=/usr/share/man \
		MANSUFFIX=1 \
		install.man || die "emake install.man failed"

	dobin contrib/{mgp2html.pl,mgp2latex.pl}

	if use emacs ; then
		elisp-install ${PN} *.el *.elc || die "elisp-install failed"
		elisp-site-file-install "${FILESDIR}/${SITEFILE}"
	fi

	use doc && dodoc FAQ README* RELNOTES SYNTAX TODO* USAGE*

	if use examples; then
		cd sample
		insinto /usr/share/${PF}/sample
		doins README* cloud.jpg dad.* embed*.mgp gradation*.mgp \
			mgp-old*.jpg mgp.mng mgp3.xbm mgprc-sample \
			multilingual.mgp sample*.mgp sendmail6*.mgp \
			tutorial*.mgp v6*.mgp v6header.* || \
			die "example installation failed"
	fi
}

pkg_postinst() {
	elog
	elog "If you enabled xft2 support (default) you may specify xfont directive by"
	elog "font name and font registry."
	elog "e.g.)"
	elog '%deffont "standard" xfont "sazanami mincho" "jisx0208.1983"'
	elog
	use emacs && elisp-site-regen
}

pkg_postrm() {
	use emacs && elisp-site-regen
}



-- 
gentoo-commits@g.o mailing list