[gentoo-commits] repo/gentoo:master commit in: media-sound/cantata/, media-sound/cantata/files/

[Andreas Sturmlechner]

commit:     564cb54b235260ec1550e33bc2e4750cafc2226f
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Sun Feb 17 16:11:25 2019 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Sun Feb 17 16:12:59 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=564cb54b

media-sound/cantata: Fix bundled solid-lite static linking

Thanks-to: Bigos <wielkiegie <AT> gmail.com>
Closes: https://bugs.gentoo.org/678228
Package-Manager: Portage-2.3.60, Repoman-2.3.12
Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 media-sound/cantata/cantata-2.3.3-r1.ebuild        | 122 +++++++++++++++++++++
 .../files/cantata-2.3.3-solidlite-static.patch     |  29 +++++
 2 files changed, 151 insertions(+)

diff --git a/media-sound/cantata/cantata-2.3.3-r1.ebuild b/media-sound/cantata/cantata-2.3.3-r1.ebuild
new file mode 100644
index 00000000000..0e490d59668
--- /dev/null
+++ b/media-sound/cantata/cantata-2.3.3-r1.ebuild
@@ -0,0 +1,122 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PLOCALES="cs da de en_GB es fr hu it ja ko pl pt_BR ru zh_CN"
+inherit cmake-utils l10n qmake-utils xdg
+
+DESCRIPTION="Featureful and configurable Qt client for the music player daemon (MPD)"
+HOMEPAGE="https://github.com/CDrummond/cantata"
+SRC_URI="https://github.com/CDrummond/${PN}/releases/download/v${PV}/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 x86"
+IUSE="cdda cddb cdio http-server libav mtp musicbrainz replaygain streaming taglib udisks zeroconf"
+REQUIRED_USE="
+	?? ( cdda cdio )
+	cdda? ( udisks || ( cddb musicbrainz ) )
+	cddb? ( || ( cdio cdda ) taglib )
+	cdio? ( udisks || ( cddb musicbrainz ) )
+	mtp? ( taglib udisks )
+	musicbrainz? ( || ( cdio cdda ) taglib )
+	replaygain? ( taglib )
+"
+
+BDEPEND="
+	dev-qt/linguist-tools:5
+"
+COMMON_DEPEND="
+	dev-qt/qtcore:5
+	dev-qt/qtdbus:5
+	dev-qt/qtgui:5
+	dev-qt/qtnetwork:5
+	dev-qt/qtsql:5[sqlite]
+	dev-qt/qtsvg:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtxml:5
+	sys-libs/zlib
+	virtual/libudev:=
+	cdda? ( media-sound/cdparanoia )
+	cddb? ( media-libs/libcddb )
+	cdio? ( dev-libs/libcdio-paranoia )
+	mtp? ( media-libs/libmtp )
+	musicbrainz? ( media-libs/musicbrainz:5= )
+	replaygain? (
+		media-libs/libebur128
+		media-sound/mpg123
+		libav? ( media-video/libav:= )
+		!libav? ( media-video/ffmpeg:0= )
+	)
+	streaming? ( dev-qt/qtmultimedia:5 )
+	taglib? (
+		media-libs/taglib[asf(+),mp4(+)]
+		udisks? ( sys-fs/udisks:2 )
+	)
+	zeroconf? ( net-dns/avahi )
+"
+RDEPEND="${COMMON_DEPEND}
+	dev-lang/perl[ithreads]
+	|| ( kde-frameworks/breeze-icons:5 kde-frameworks/oxygen-icons:* )
+"
+DEPEND="${COMMON_DEPEND}
+	dev-qt/qtconcurrent:5
+"
+
+# cantata has no tests
+RESTRICT="test"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-2.2.0-headers.patch"
+	"${FILESDIR}/${P}-solidlite-static.patch" # bug 678228
+)
+
+src_prepare() {
+	remove_locale() {
+		rm "translations/${PN}_${1}".ts || die
+	}
+
+	cmake-utils_src_prepare
+
+	# Unbundle 3rd party libs
+	rm -r 3rdparty/{ebur128,qtsingleapplication} || die
+
+	l10n_find_plocales_changes "translations" "${PN}_" ".ts"
+	l10n_for_each_disabled_locale_do remove_locale
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DCANTATA_HELPERS_LIB_DIR="$(get_libdir)"
+		-DENABLE_CDPARANOIA=$(usex cdda)
+		-DENABLE_CDDB=$(usex cddb)
+		-DENABLE_CDIOPARANOIA=$(usex cdio)
+		-DENABLE_HTTP_SERVER=$(usex http-server)
+		-DENABLE_MTP=$(usex mtp)
+		-DENABLE_MUSICBRAINZ=$(usex musicbrainz)
+		-DLRELEASE_EXECUTABLE="$(qt5_get_bindir)/lrelease"
+		-DENABLE_FFMPEG=$(usex replaygain)
+		-DENABLE_MPG123=$(usex replaygain)
+		-DENABLE_HTTP_STREAM_PLAYBACK=$(usex streaming)
+		-DENABLE_TAGLIB=$(usex taglib)
+		-DENABLE_DEVICES_SUPPORT=$(usex udisks)
+		-DENABLE_AVAHI=$(usex zeroconf)
+		-DENABLE_REMOTE_DEVICES=OFF
+		-DENABLE_UDISKS2=ON
+	)
+
+	cmake-utils_src_configure
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+
+	has_version media-sound/mpd || \
+		elog "An instance of media-sound/mpd, local or remote, is required to set up Cantata."
+
+	if ! has_version app-misc/media-player-info; then
+		elog "Install app-misc/media-player-info to enable identification"
+		elog "and querying of portable media players"
+	fi
+}

diff --git a/media-sound/cantata/files/cantata-2.3.3-solidlite-static.patch b/media-sound/cantata/files/cantata-2.3.3-solidlite-static.patch
new file mode 100644
index 00000000000..891917eebcb
--- /dev/null
+++ b/media-sound/cantata/files/cantata-2.3.3-solidlite-static.patch
@@ -0,0 +1,29 @@
+From aa35362aa2835e9e2903f5f785f10402a6abd3a1 Mon Sep 17 00:00:00 2001
+From: Andreas Sturmlechner <andreas.sturmlechner@×××××.com>
+Date: Sun, 17 Feb 2019 16:58:48 +0100
+Subject: [PATCH] Fix solid-lite static linking
+
+If BUILD_SHARED_LIBS is part of standard system cmake args:
+
+  cantata: error while loading shared libraries: libsolidlite.so:
+  cannot open shared object file: No such file or directory
+---
+ 3rdparty/solid-lite/CMakeLists.txt | 2 +-
+ 1 file changed, 1 insertion(+), 1 deletion(-)
+
+diff --git a/3rdparty/solid-lite/CMakeLists.txt b/3rdparty/solid-lite/CMakeLists.txt
+index 4ae51aab..86e37189 100644
+--- a/3rdparty/solid-lite/CMakeLists.txt
++++ b/3rdparty/solid-lite/CMakeLists.txt
+@@ -202,7 +202,7 @@ if(APPLE)
+    set(solidlite_OPTIONAL_LIBS ${IOKIT_LIBRARY})
+ endif()
+ 
+-add_library(solidlite ${solidlite_LIB_SRCS})
++add_library(solidlite STATIC ${solidlite_LIB_SRCS})
+ 
+ if ( UDEV_FOUND )
+    set(solidlite_OPTIONAL_LIBS ${solidlite_OPTIONAL_LIBS} ${UDEV_LIBS})
+-- 
+2.20.1
+