[gentoo-commits] repo/gentoo:master commit in: sys-apps/fwupd/

[Lars Wendler]

commit:     b03cc6007009b9aa8fe6c7cb2534f86beb2ec2d0
Author:     Lars Wendler <polynomial-c <AT> gentoo <DOT> org>
AuthorDate: Fri Apr 29 14:32:58 2022 +0000
Commit:     Lars Wendler <polynomial-c <AT> gentoo <DOT> org>
CommitDate: Fri Apr 29 14:33:14 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=b03cc600

sys-apps/fwupd: Removed old

Signed-off-by: Lars Wendler <polynomial-c <AT> gentoo.org>

 sys-apps/fwupd/Manifest           |   1 -
 sys-apps/fwupd/fwupd-1.7.6.ebuild | 175 --------------------------------------
 2 files changed, 176 deletions(-)

diff --git a/sys-apps/fwupd/Manifest b/sys-apps/fwupd/Manifest
index 40c6998d67a2..59ab218ee758 100644
--- a/sys-apps/fwupd/Manifest
+++ b/sys-apps/fwupd/Manifest
@@ -1,4 +1,3 @@
 DIST fwupd-1.7.5.tar.gz 4014523 BLAKE2B b7297bbf3358209464691b928b928fa029c68ae6a3bc413d514409e4382bf8a3b0d57f4febc29a24d6351481474dd8111406ffdcb11125139fbc04a33ea00321 SHA512 1c2d99d905f76ebfce65db310ba0f6c1305ecf662b58bd9f6f6597ccc79cbabed126c97f2142207c99d8373ed42575363a58d9f053f390780b7c9a19c614fb31
-DIST fwupd-1.7.6.tar.gz 4054269 BLAKE2B dea4a37aea406e933f312fb809ee2ea972e3b017e5267d51bed835b6d440c15ca1d589f76a6c1906e616acc7cdd6c0f6dcec034e1460427057d8a1168583c4ce SHA512 f04ee78a6ec9e73ce0f3eb9c2dcbfc471ac88264451a378f1b0010fa528596052b4d3a63f5303074dd4fad55bf153fe5642d77adebd4ed805d74f57fbbff5b2b
 DIST fwupd-1.7.7.tar.gz 4057638 BLAKE2B 197d7b8a8de64094d267bb4e2de30101373bcc52fd54d12dc2590a50f2bcebbcfe00847d19c0088d2c778743d219ee73c0237db711ad27e36f7126f7c615ccf7 SHA512 a787ffdff93f483ad97547d335c50a4db7b61bce1bc27d737b077bbedfa4676c8d6d37db94ac24083c50e3bfde8aefd4d1adb3d0e473303f454a46dde136df0a
 DIST fwupd-1.8.0.tar.gz 4103239 BLAKE2B 15d06a261be1f529573a0f3b21a54066b1b286e1d1c68ac24f3862f7e3a8855661775b369016d67fbc9797fd13dea88000e78d1a6973e489ecaa6f7f6855b3cf SHA512 8977e0b0878e46480565a32935cc008d57d3978609c01877e3a90dc594b122bed0c94613a53f0f2d3f50d8a039b09cb93787aaf7e0b5d8cf1ec1a6247fe1610b

diff --git a/sys-apps/fwupd/fwupd-1.7.6.ebuild b/sys-apps/fwupd/fwupd-1.7.6.ebuild
deleted file mode 100644
index e020b391df93..000000000000
--- a/sys-apps/fwupd/fwupd-1.7.6.ebuild
+++ /dev/null
@@ -1,175 +0,0 @@
-# Copyright 1999-2022 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-
-PYTHON_COMPAT=( python3_{8..10} )
-
-inherit bash-completion-r1 linux-info meson python-single-r1 vala xdg
-
-DESCRIPTION="Aims to make updating firmware on Linux automatic, safe and reliable"
-HOMEPAGE="https://fwupd.org"
-SRC_URI="https://github.com/${PN}/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
-
-LICENSE="LGPL-2.1+"
-SLOT="0"
-KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv ~x86"
-IUSE="amt archive bash-completion bluetooth dell elogind fastboot flashrom gnutls gtk-doc gusb introspection logitech lzma +man minimal modemmanager nvme policykit spi +sqlite synaptics systemd test thunderbolt tpm uefi"
-REQUIRED_USE="${PYTHON_REQUIRED_USE}
-	^^ ( elogind minimal systemd )
-	dell? ( uefi )
-	fastboot? ( gusb )
-	logitech? ( gusb )
-	minimal? ( !introspection )
-	spi? ( lzma )
-	synaptics? ( gnutls )
-	uefi? ( gnutls )
-"
-RESTRICT="!test? ( test )"
-
-BDEPEND="$(vala_depend)
-	virtual/pkgconfig
-	gtk-doc? ( dev-util/gtk-doc )
-	bash-completion? ( >=app-shells/bash-completion-2.0 )
-	introspection? ( dev-libs/gobject-introspection )
-	man? (
-		app-text/docbook-sgml-utils
-		sys-apps/help2man
-	)
-	test? (
-		thunderbolt? ( dev-util/umockdev )
-		net-libs/gnutls[tools]
-	)
-"
-COMMON_DEPEND="${PYTHON_DEPS}
-	>=app-arch/gcab-1.0
-	app-arch/xz-utils
-	>=dev-libs/glib-2.58:2
-	dev-libs/json-glib
-	dev-libs/libgudev:=
-	>=dev-libs/libjcat-0.1.4[gpg,pkcs7]
-	>=dev-libs/libxmlb-0.1.13:=[introspection?]
-	$(python_gen_cond_dep '
-		dev-python/pygobject:3[cairo,${PYTHON_USEDEP}]
-	')
-	>=net-libs/libsoup-2.51.92:2.4[introspection?]
-	net-misc/curl
-	archive? ( app-arch/libarchive:= )
-	dell? ( >=sys-libs/libsmbios-2.4.0 )
-	elogind? ( >=sys-auth/elogind-211 )
-	flashrom? ( >=sys-apps/flashrom-1.2-r3 )
-	gnutls? ( net-libs/gnutls )
-	gusb? ( >=dev-libs/libgusb-0.3.5[introspection?] )
-	logitech? ( dev-libs/protobuf-c:= )
-	lzma? ( app-arch/xz-utils )
-	modemmanager? ( net-misc/modemmanager[qmi] )
-	policykit? ( >=sys-auth/polkit-0.103 )
-	sqlite? ( dev-db/sqlite )
-	systemd? ( >=sys-apps/systemd-211 )
-	tpm? ( app-crypt/tpm2-tss )
-	uefi? (
-		sys-apps/fwupd-efi
-		sys-boot/efibootmgr
-		sys-fs/udisks
-		sys-libs/efivar
-	)
-"
-# Block sci-chemistry/chemical-mime-data for bug #701900
-RDEPEND="
-	!<sci-chemistry/chemical-mime-data-0.1.94-r4
-	${COMMON_DEPEND}
-	sys-apps/dbus
-"
-
-DEPEND="
-	${COMMON_DEPEND}
-	x11-libs/pango[introspection]
-"
-
-pkg_setup() {
-	python-single-r1_pkg_setup
-	if use nvme ; then
-		kernel_is -ge 4 4 || die "NVMe support requires kernel >= 4.4"
-	fi
-}
-
-src_prepare() {
-	default
-	# c.f. https://github.com/fwupd/fwupd/issues/1414
-	sed -e "/test('thunderbolt-self-test', e, env: test_env, timeout : 120)/d" \
-		-i plugins/thunderbolt/meson.build || die
-
-	sed -e '/platform-integrity/d' \
-		-i plugins/meson.build || die #753521
-
-	sed -e "/install_dir.*'doc'/s/fwupd/${PF}/" \
-		-i data/builder/meson.build || die
-
-	vala_src_prepare
-}
-
-src_configure() {
-	local plugins=(
-		-Dplugin_gpio="true"
-		$(meson_use amt plugin_amt)
-		$(meson_use dell plugin_dell)
-		$(meson_use fastboot plugin_fastboot)
-		$(meson_use flashrom plugin_flashrom)
-		$(meson_use gusb plugin_uf2)
-		$(meson_use logitech plugin_logitech_bulkcontroller)
-		$(meson_use modemmanager plugin_modem_manager)
-		$(meson_use nvme plugin_nvme)
-		$(meson_use sqlite)
-		$(meson_use spi plugin_intel_spi)
-		$(meson_use synaptics plugin_synaptics_mst)
-		$(meson_use synaptics plugin_synaptics_rmi)
-		$(meson_use thunderbolt plugin_thunderbolt)
-		$(meson_use tpm plugin_tpm)
-		$(meson_use uefi plugin_uefi_capsule)
-		$(meson_use uefi plugin_uefi_capsule_splash)
-		$(meson_use uefi plugin_uefi_pk)
-	)
-	use ppc64 && plugins+=( -Dplugin_msr="false" )
-	use riscv && plugins+=( -Dplugin_msr="false" )
-
-	local emesonargs=(
-		--localstatedir "${EPREFIX}"/var
-		-Dbuild="$(usex minimal standalone all)"
-		-Dconsolekit="false"
-		-Dcurl="true"
-		-Ddocs="$(usex gtk-doc gtkdoc none)"
-		-Defi_binary="false"
-		-Dsupported_build="true"
-		$(meson_use archive libarchive)
-		$(meson_use bash-completion bash_completion)
-		$(meson_use bluetooth bluez)
-		$(meson_use elogind)
-		$(meson_use gnutls)
-		$(meson_use gusb)
-		$(meson_use lzma)
-		$(meson_use man)
-		$(meson_use introspection)
-		$(meson_use policykit polkit)
-		$(meson_use systemd)
-		$(meson_use test tests)
-
-		${plugins[@]}
-	)
-	use uefi && emesonargs+=( -Defi_os_dir="gentoo" )
-	export CACHE_DIRECTORY="${T}"
-	meson_src_configure
-}
-
-src_install() {
-	meson_src_install
-
-	if ! use minimal ; then
-		newinitd "${FILESDIR}"/${PN}-r2 ${PN}
-
-		if ! use systemd ; then
-			# Don't timeout when fwupd is running (#673140)
-			sed '/^IdleTimeout=/s@=[[:digit:]]\+@=0@' \
-				-i "${ED}"/etc/${PN}/daemon.conf || die
-		fi
-	fi
-}