[gentoo-commits] gentoo-x86 commit in dev-python/cssutils: cssutils-0.9.9.ebuild ChangeLog

[Dirkjan Ochtman (djc)]

djc         12/03/02 08:31:05

  Modified:             ChangeLog
  Added:                cssutils-0.9.9.ebuild
  Log:
  Version bump cssutils to 0.9.9 for bug 381983 (thanks to Johan Bergstroem).
  
  (Portage version: 2.1.10.49/cvs/Linux x86_64)

Revision  Changes    Path
1.23                 dev-python/cssutils/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/cssutils/ChangeLog?rev=1.23&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/cssutils/ChangeLog?rev=1.23&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/cssutils/ChangeLog?r1=1.22&r2=1.23

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-python/cssutils/ChangeLog,v
retrieving revision 1.22
retrieving revision 1.23
diff -u -r1.22 -r1.23
--- ChangeLog	5 Feb 2012 13:43:31 -0000	1.22
+++ ChangeLog	2 Mar 2012 08:31:05 -0000	1.23
@@ -1,6 +1,11 @@
 # ChangeLog for dev-python/cssutils
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/cssutils/ChangeLog,v 1.22 2012/02/05 13:43:31 ranger Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/cssutils/ChangeLog,v 1.23 2012/03/02 08:31:05 djc Exp $
+
+*cssutils-0.9.9 (02 Mar 2012)
+
+  02 Mar 2012; Dirkjan Ochtman <djc@g.o> +cssutils-0.9.9.ebuild:
+  Version bump to 0.9.9 for bug 381983 (thanks to Johan Bergstroem).
 
   05 Feb 2012; Brent Baude <ranger@g.o> cssutils-0.9.7.ebuild:
   Marking cssutils-0.9.7 ppc for bug 386729



1.1                  dev-python/cssutils/cssutils-0.9.9.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/cssutils/cssutils-0.9.9.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/cssutils/cssutils-0.9.9.ebuild?rev=1.1&content-type=text/plain

Index: cssutils-0.9.9.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-python/cssutils/cssutils-0.9.9.ebuild,v 1.1 2012/03/02 08:31:05 djc Exp $

EAPI="3"
PYTHON_DEPEND="2"
SUPPORT_PYTHON_ABIS="1"
RESTRICT_PYTHON_ABIS=""
DISTUTILS_SRC_TEST="nosetests"
PYTHON_TESTS_RESTRICTED_ABIS="3.*"

inherit distutils

DESCRIPTION="A CSS Cascading Style Sheets library"
HOMEPAGE="http://pypi.python.org/pypi/cssutils/ https://bitbucket.org/cthedot/cssutils"
SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.zip"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE="examples test"

RDEPEND="dev-python/setuptools"
DEPEND="${RDEPEND}
	app-arch/unzip
	test? ( dev-python/mock )"

PYTHON_MODNAME="cssutils encutils"

src_prepare() {
	distutils_src_prepare

	# Disable test failing with dev-python/pyxml installed.
	if has_version dev-python/pyxml; then
		sed -e "s/test_linecol/_&/" -i src/tests/test_errorhandler.py
	fi

	# https://bitbucket.org/cthedot/cssutils/issue/8/test-failure
	sed -e "s/test_cssText2/_&/" -i src/tests/test_cssvariablesdeclaration.py
}

src_install() {
	distutils_src_install

	# Don't install tests.
	delete_tests() {
		rm -fr "${ED}$(python_get_sitedir)/tests"
	}
	python_execute_function -q delete_tests

	# Don't install py3 stuff on py2. Breaks py25
	deletion_of_unneeded_files() {
		[[ "${PYTHON_ABI}" == 3.* ]] && return
		rm -f "${ED}$(python_get_sitedir)/cssutils/_codec3.py"
	}
	python_execute_function -q deletion_of_unneeded_files

	if use examples; then
		insinto /usr/share/doc/${PF}
		doins -r examples
	fi
}