[gentoo-commits] repo/gentoo:master commit in: dev-python/pytest-trio/

[Michał Górny]

commit:     2833368b7dc517c1ad4b518389c99be96ca3457b
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Thu Apr  7 08:53:15 2022 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Thu Apr  7 09:12:51 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=2833368b

dev-python/pytest-trio: EAPI 8, PEP517

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/pytest-trio/pytest-trio-0.7.0-r1.ebuild | 52 ++++++++++++++++++++++
 1 file changed, 52 insertions(+)

diff --git a/dev-python/pytest-trio/pytest-trio-0.7.0-r1.ebuild b/dev-python/pytest-trio/pytest-trio-0.7.0-r1.ebuild
new file mode 100644
index 000000000000..ac9b1f5bd507
--- /dev/null
+++ b/dev-python/pytest-trio/pytest-trio-0.7.0-r1.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( pypy3 python3_{8..10} )
+
+inherit distutils-r1
+
+DESCRIPTION="This is a pytest plugin to help you test projects that use Trio"
+HOMEPAGE="
+	https://github.com/python-trio/pytest-trio
+	https://pypi.org/project/pytest-trio/
+"
+SRC_URI="mirror://pypi/${P:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="|| ( MIT Apache-2.0 )"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~sparc ~x86"
+
+RDEPEND="
+	>=dev-python/async_generator-1.9[${PYTHON_USEDEP}]
+	dev-python/outcome[${PYTHON_USEDEP}]
+	>=dev-python/pytest-6.0.0[${PYTHON_USEDEP}]
+	>=dev-python/trio-0.15[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		>=dev-python/hypothesis-3.64[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+distutils_enable_sphinx docs/source \
+	dev-python/attrs \
+	dev-python/sphinx_rtd_theme \
+	dev-python/sphinxcontrib-trio
+
+python_prepare_all() {
+	# Defining 'pytest_plugins' in a non-top-level conftest is no longer supported:
+	mv pytest_trio/_tests/conftest.py conftest.py || die
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	# disable autoloading pytest-asyncio in nested pytest calls
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	# since we disabled autoloading, force loading pytest-trio
+	local -x PYTEST_PLUGINS=pytest_trio.plugin
+	epytest
+}