[gentoo-commits] gentoo-x86 commit in app-misc/mc: ChangeLog mc-4.7.5.ebuild

[Alex Alexander (wired)]

wired       11/02/01 07:50:29

  Modified:             ChangeLog
  Added:                mc-4.7.5.ebuild
  Log:
  version bump
  
  (Portage version: 2.2.0_alpha19/cvs/Linux x86_64)

Revision  Changes    Path
1.213                app-misc/mc/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/mc/ChangeLog?rev=1.213&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/mc/ChangeLog?rev=1.213&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/mc/ChangeLog?r1=1.212&r2=1.213

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-misc/mc/ChangeLog,v
retrieving revision 1.212
retrieving revision 1.213
diff -u -r1.212 -r1.213
--- ChangeLog	8 Nov 2010 23:31:36 -0000	1.212
+++ ChangeLog	1 Feb 2011 07:50:29 -0000	1.213
@@ -1,6 +1,11 @@
 # ChangeLog for app-misc/mc
-# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-misc/mc/ChangeLog,v 1.212 2010/11/08 23:31:36 wired Exp $
+# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/app-misc/mc/ChangeLog,v 1.213 2011/02/01 07:50:29 wired Exp $
+
+*mc-4.7.5 (01 Feb 2011)
+
+  01 Feb 2011; Alex Alexander <wired@g.o> +mc-4.7.5.ebuild:
+  version bump
 
 *mc-4.7.0.10 (08 Nov 2010)
 



1.1                  app-misc/mc/mc-4.7.5.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/mc/mc-4.7.5.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/mc/mc-4.7.5.ebuild?rev=1.1&content-type=text/plain

Index: mc-4.7.5.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-misc/mc/mc-4.7.5.ebuild,v 1.1 2011/02/01 07:50:29 wired Exp $

EAPI=4

inherit base

MY_P=${P/_/-}

DESCRIPTION="GNU Midnight Commander is a text based file manager"
HOMEPAGE="http://www.midnight-commander.org"
SRC_URI="http://www.midnight-commander.org/downloads/${MY_P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd ~x86-interix ~amd64-linux ~ppc-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x86-solaris"
IUSE="+edit gpm +ncurses nls samba slang X"

REQUIRED_USE="^^ ( ncurses slang )"

RDEPEND=">=dev-libs/glib-2.8:2
	gpm? ( sys-libs/gpm )
	kernel_linux? ( sys-fs/e2fsprogs )
	ncurses? ( sys-libs/ncurses )
	samba? ( net-fs/samba )
	slang? ( >=sys-libs/slang-2 )
	X? ( x11-libs/libX11
		x11-libs/libICE
		x11-libs/libXau
		x11-libs/libXdmcp
		x11-libs/libSM )"
DEPEND="${RDEPEND}
	dev-util/pkgconfig
	nls? ( sys-devel/gettext )"

S=${WORKDIR}/${MY_P}

src_configure() {
	local myscreen=ncurses
	use slang && myscreen=slang

	econf \
		--disable-dependency-tracking \
		$(use_enable nls) \
		--enable-vfs \
		$(use_enable kernel_linux vfs-undelfs) \
		--enable-charset \
		$(use_with X x) \
		$(use_enable samba vfs-smb) \
		$(use_with gpm gpm-mouse) \
		--with-screen=${myscreen} \
		$(use_with edit)
}

src_install() {
	emake DESTDIR="${D}" install || die
	dodoc AUTHORS README

	# fix bug #334383
	if [[ ${EUID} == 0 ]] ; then
		fowners root:tty /usr/libexec/mc/cons.saver ||
			die "setting cons.saver's owner failed"
		fperms g+s /usr/libexec/mc/cons.saver ||
			die "setting cons.saver's permissions failed"
	fi
}

pkg_postinst() {
	elog "To enable exiting to latest working directory,"
	elog "put this into your ~/.bashrc:"
	elog ". ${EPREFIX}/usr/libexec/mc/mc.sh"
}