[gentoo-commits] gentoo-x86 commit in dev-python/jinja: jinja-2.6-r100.ebuild ChangeLog

[Mike Gilbert (floppym)]

floppym     13/05/23 00:38:36

  Modified:             ChangeLog
  Added:                jinja-2.6-r100.ebuild
  Log:
  Create 'compat' slot for packages requiring python 2.5, 3.1, or 3.2, which >=jinja-2.7 does not support.
  
  (Portage version: 2.2.0_alpha176/cvs/Linux x86_64, signed Manifest commit with key 0BBEEA1FEA4843A4)

Revision  Changes    Path
1.66                 dev-python/jinja/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/jinja/ChangeLog?rev=1.66&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/jinja/ChangeLog?rev=1.66&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/jinja/ChangeLog?r1=1.65&r2=1.66

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-python/jinja/ChangeLog,v
retrieving revision 1.65
retrieving revision 1.66
diff -u -r1.65 -r1.66
--- ChangeLog	20 May 2013 14:51:15 -0000	1.65
+++ ChangeLog	23 May 2013 00:38:36 -0000	1.66
@@ -1,6 +1,12 @@
 # ChangeLog for dev-python/jinja
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/jinja/ChangeLog,v 1.65 2013/05/20 14:51:15 djc Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/jinja/ChangeLog,v 1.66 2013/05/23 00:38:36 floppym Exp $
+
+*jinja-2.6-r100 (23 May 2013)
+
+  23 May 2013; Mike Gilbert <floppym@g.o> +jinja-2.6-r100.ebuild:
+  Create 'compat' slot for packages requiring python 2.5, 3.1, or 3.2, which
+  >=jinja-2.7 does not support.
 
 *jinja-2.7 (20 May 2013)
 



1.1                  dev-python/jinja/jinja-2.6-r100.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/jinja/jinja-2.6-r100.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/jinja/jinja-2.6-r100.ebuild?rev=1.1&content-type=text/plain

Index: jinja-2.6-r100.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-python/jinja/jinja-2.6-r100.ebuild,v 1.1 2013/05/23 00:38:36 floppym Exp $

EAPI=5

PYTHON_COMPAT=( python{2_5,3_1,3_2} )

inherit eutils distutils-r1

MY_PN=Jinja2
MY_P=${MY_PN}-${PV}

DESCRIPTION="A small but fast and easy to use stand-alone template engine written in pure Python"
HOMEPAGE="http://jinja.pocoo.org/ http://pypi.python.org/pypi/Jinja2"
SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz"

LICENSE="BSD"
SLOT="compat"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~x86-interix ~amd64-linux ~x86-linux ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris"
IUSE="doc examples"

RDEPEND="dev-python/markupsafe[${PYTHON_USEDEP}]
	dev-python/setuptools[${PYTHON_USEDEP}]
	!<dev-python/jinja-2.7:0"
DEPEND="${RDEPEND}
	doc? ( >=dev-python/sphinx-0.6 )"

# XXX: handle Babel better?

S=${WORKDIR}/${MY_P}

wrap_opts() {
	local mydistutilsargs=()

	if [[ ${EPYTHON} == python* ]]; then
		mydistutilargs+=( --with-debugsupport )
	fi

	"${@}"
}

python_prepare() {
	epatch "${FILESDIR}"/${P}-python3.3.patch
}

python_compile() {
	wrap_opts distutils-r1_python_compile
}

python_compile_all() {
	if use doc; then
		cd docs || die

		if [[ ${EPYTHON} == python3* ]]; then
			# https://github.com/mitsuhiko/jinja2/issues/115
			2to3 -n -w --no-diffs jinjaext.py || die
		fi

		emake html
	fi
}

python_test() {
	esetup.py test
}

python_install_all() {
	use doc && local HTML_DOCS=( docs/_build/html/. )

	distutils-r1_python_install_all

	if use examples; then
		insinto /usr/share/doc/${PF}
		doins -r examples
	fi

	insinto /usr/share/vim/vimfiles/syntax
	doins ext/Vim/*
}

pkg_postinst() {
	if ! has_version dev-python/Babel; then
		elog "For i18n support, please emerge dev-python/Babel."
	fi
}