[gentoo-commits] repo/gentoo:master commit in: xfce-base/libxfce4ui/

[Michał Górny]

commit:     16ea19ef17e84ca75afe063d54679e06855c9576
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Sun Jun 27 06:06:52 2021 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Sun Jun 27 06:06:52 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=16ea19ef

xfce-base/libxfce4ui: Bump to 4.17.0

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 xfce-base/libxfce4ui/Manifest                 |  1 +
 xfce-base/libxfce4ui/libxfce4ui-4.17.0.ebuild | 73 +++++++++++++++++++++++++++
 2 files changed, 74 insertions(+)

diff --git a/xfce-base/libxfce4ui/Manifest b/xfce-base/libxfce4ui/Manifest
index 35ed3045de5..19c1c30458e 100644
--- a/xfce-base/libxfce4ui/Manifest
+++ b/xfce-base/libxfce4ui/Manifest
@@ -1 +1,2 @@
 DIST libxfce4ui-4.16.0.tar.bz2 837838 BLAKE2B a7e0612bb2a6e47fb9e03c69f1f014740b1ed0f363e198823b328980c106bf5566c880cdeac254291a44ff5a4fc6c8ae95c0396b37e6869e0ec3721897c75d43 SHA512 07ce8399ca860d5414f91b0795ba61eff21b6022a9e8c26de77a6c4e6c45371e10318b626a892b7e2998d95c7e92cf32c2cd48fdefc291bb5521fe8a6cf93aed
+DIST libxfce4ui-4.17.0.tar.bz2 879058 BLAKE2B 5dd8bc1b03aaa0fc9ead58f0d5eacf470712ec5c3dcf055513d40f3798f834d82e288b5ca448c25b7b917a1d815ebc082c779ecb5f607479e06247ce7cdf9efe SHA512 c95afd0568818886bc953dbac4fd5f9a583499c944aea6b5b1d61ee05bdf7afe733f78abd8575c84adde4f9e16f795ebefbab912e3a8ab7046d8c205601d0944

diff --git a/xfce-base/libxfce4ui/libxfce4ui-4.17.0.ebuild b/xfce-base/libxfce4ui/libxfce4ui-4.17.0.ebuild
new file mode 100644
index 00000000000..c8d8318a922
--- /dev/null
+++ b/xfce-base/libxfce4ui/libxfce4ui-4.17.0.ebuild
@@ -0,0 +1,73 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit xdg-utils vala
+
+DESCRIPTION="Unified widget and session management libs for Xfce"
+HOMEPAGE="https://wiki.gentoo.org/wiki/No_homepage"
+SRC_URI="https://archive.xfce.org/src/xfce/${PN}/${PV%.*}/${P}.tar.bz2"
+
+LICENSE="LGPL-2+ GPL-2+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux ~x86-solaris"
+IUSE="debug glade +introspection startup-notification system-info vala"
+REQUIRED_USE="vala? ( introspection )"
+
+RDEPEND="
+	>=dev-libs/glib-2.50:2
+	>=x11-libs/gtk+-3.22:3[introspection?]
+	x11-libs/libX11
+	x11-libs/libICE
+	x11-libs/libSM
+	>=xfce-base/libxfce4util-4.15.6:=[introspection?]
+	>=xfce-base/xfconf-4.12:=
+	glade? ( dev-util/glade:3.10 )
+	introspection? ( dev-libs/gobject-introspection:= )
+	startup-notification? ( x11-libs/startup-notification )
+	system-info? (
+		dev-libs/libgudev
+		gnome-base/libgtop
+		>=media-libs/libepoxy-1.2
+	)"
+DEPEND="${RDEPEND}"
+BDEPEND="dev-lang/perl
+	dev-util/intltool
+	sys-devel/gettext
+	virtual/pkgconfig
+	vala? ( $(vala_depend) )"
+
+src_prepare() {
+	# stupid vala.eclass...
+	default
+}
+
+src_configure() {
+	local myconf=(
+		$(use_enable introspection)
+		$(use_enable system-info glibtop)
+		$(use_enable system-info epoxy)
+		$(use_enable system-info gudev)
+		$(use_enable startup-notification)
+		$(use_enable vala)
+		$(use_enable glade gladeui2)
+		--with-vendor-info=Gentoo
+	)
+
+	use vala && vala_src_prepare
+	econf "${myconf[@]}"
+}
+
+src_install() {
+	emake -j1 DESTDIR="${D}" install
+	find "${D}" -name '*.la' -delete || die
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+}