[gentoo-commits] gentoo-x86 commit in app-editors/bluefish: ChangeLog bluefish-1.3.6.ebuild bluefish-1.1.6.ebuild bluefish-1.3.2.ebuild bluefish-1.0.ebuild

[Tomas Chvatal (scarabeus)]

scarabeus    09/08/28 08:53:46

  Modified:             ChangeLog
  Added:                bluefish-1.3.6.ebuild
  Removed:              bluefish-1.1.6.ebuild bluefish-1.3.2.ebuild
                        bluefish-1.0.ebuild
  Log:
  Version bump. Remove old. Per bug #262212 and #282893.
  (Portage version: 2.2_rc38/cvs/Linux i686)

Revision  Changes    Path
1.63                 app-editors/bluefish/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-editors/bluefish/ChangeLog?rev=1.63&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-editors/bluefish/ChangeLog?rev=1.63&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-editors/bluefish/ChangeLog?r1=1.62&r2=1.63

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-editors/bluefish/ChangeLog,v
retrieving revision 1.62
retrieving revision 1.63
diff -u -r1.62 -r1.63
--- ChangeLog	22 Feb 2009 11:42:01 -0000	1.62
+++ ChangeLog	28 Aug 2009 08:53:46 -0000	1.63
@@ -1,6 +1,12 @@
 # ChangeLog for app-editors/bluefish
-# Copyright 2002-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-editors/bluefish/ChangeLog,v 1.62 2009/02/22 11:42:01 hanno Exp $
+# Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/app-editors/bluefish/ChangeLog,v 1.63 2009/08/28 08:53:46 scarabeus Exp $
+
+*bluefish-1.3.6 (28 Aug 2009)
+
+  28 Aug 2009; Tomáš Chvátal <scarabeus@g.o> -bluefish-1.0.ebuild,
+  -bluefish-1.1.6.ebuild, -bluefish-1.3.2.ebuild, +bluefish-1.3.6.ebuild:
+  Version bump. Remove old. Per bug #262212 and #282893.
 
 *bluefish-1.3.2 (22 Feb 2009)
 



1.1                  app-editors/bluefish/bluefish-1.3.6.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-editors/bluefish/bluefish-1.3.6.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-editors/bluefish/bluefish-1.3.6.ebuild?rev=1.1&content-type=text/plain

Index: bluefish-1.3.6.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-editors/bluefish/bluefish-1.3.6.ebuild,v 1.1 2009/08/28 08:53:46 scarabeus Exp $

EAPI="2"

inherit eutils fdo-mime

IUSE="nls spell gnome python"

MY_P="${PN}-unstable-${PV}"

DESCRIPTION="A GTK HTML editor for the experienced web designer or programmer."
SRC_URI="http://www.bennewitz.com/bluefish/devel/source/${MY_P}.tar.bz2"
HOMEPAGE="http://bluefish.openoffice.nl/"

LICENSE="GPL-2"
KEYWORDS="~alpha ~amd64 ~ia64 ~ppc ~ppc64 ~sparc ~x86"
SLOT="0"

RDEPEND="
	dev-libs/libpcre
	x11-libs/gtk+:2
	spell? ( app-text/enchant[aspell] )"

DEPEND="${RDEPEND}
	app-text/enchant[aspell]
	dev-libs/glib:2
	dev-libs/libxml2
	dev-util/pkgconfig
	x11-libs/pango
	gnome? ( gnome-extra/gucharmap )
	nls? ( sys-devel/gettext dev-util/intltool )
	python? ( dev-lang/python )"

S="${WORKDIR}/${MY_P}"

src_configure() {
	econf \
		--disable-dependency-tracking \
		--disable-update-databases \
		--disable-xml-catalog-update \
		$(use_enable nls) \
		$(use_enable spell spell-check) \
		$(use_enable python)
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"
}

pkg_postinst() {
	fdo-mime_desktop_database_update
	fdo-mime_mime_database_update

	einfo "Adding XML catalog entries..."
	/usr/bin/xmlcatalog  --noout \
		--add 'public' 'Bluefish/DTD/Bflang' 'bflang.dtd' \
		--add 'system' 'http://bluefish.openoffice.nl/DTD/bflang.dtd' 'bflang.dtd' \
		--add 'rewriteURI' 'http://bluefish.openoffice.nl/DTD' '/usr/share/xml/bluefish-unstable' \
		/etc/xml/catalog \
		|| ewarn "Failed to add XML catalog entries."
}

pkg_postrm() {
	einfo "Removing XML catalog entries..."
	/usr/bin/xmlcatalog  --noout \
		--del 'Bluefish/DTD/Bflang' \
		--del 'http://bluefish.openoffice.nl/DTD/bflang.dtd' \
		--del 'http://bluefish.openoffice.nl/DTD' \
		/etc/xml/catalog \
		|| ewarn "Failed to remove XML catalog entries."
}