[gentoo-commits] repo/gentoo:master commit in: sys-apps/fwupd/

[Lars Wendler]

commit:     346f5291b2823f831a1aa1c850b754cb3b489aad
Author:     Lars Wendler <polynomial-c <AT> gentoo <DOT> org>
AuthorDate: Mon Feb  3 21:13:19 2020 +0000
Commit:     Lars Wendler <polynomial-c <AT> gentoo <DOT> org>
CommitDate: Mon Feb  3 21:13:32 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=346f5291

sys-apps/fwupd: Removed old

Package-Manager: Portage-2.3.87, Repoman-2.3.20
Signed-off-by: Lars Wendler <polynomial-c <AT> gentoo.org>

 sys-apps/fwupd/Manifest           |   1 -
 sys-apps/fwupd/fwupd-1.3.5.ebuild | 159 --------------------------------------
 2 files changed, 160 deletions(-)

diff --git a/sys-apps/fwupd/Manifest b/sys-apps/fwupd/Manifest
index a7c82340ed6..f37c760c4c2 100644
--- a/sys-apps/fwupd/Manifest
+++ b/sys-apps/fwupd/Manifest
@@ -1,4 +1,3 @@
 DIST fwupd-1.2.11.tar.gz 1945646 BLAKE2B 4eb6d5008d0e515880147a94b2632ed70b5f7ab1891775ac121347653c06bf4403ab7f4a1fe160000a6195d360fe06d64c8971dd53c1538aeac40d155f59979a SHA512 a8d6a76ac59937547c6866d414e95a67779574901b0a15ecfde763f49b434b284be2ade1194179225785006e5f93836667469d08f32d4c87fc85927aa0bfe9de
-DIST fwupd-1.3.5.tar.gz 2164874 BLAKE2B aa268f3d94b3c7104cad5e80de81a724ba978e3da468cd2d44833656c5b0a95b1f720f5c7a0dd9812b8afce4c58e8f777e13ea2e1f4ce0b8b582ee3c731b744a SHA512 b1944b06bed9cb10ec90219235b168a76fcf6ff7b8938dfba36259f07efed71a755d7b91fcbe8f6fda00ac971bd5d4734a49e045005e2e1c32b49fc5b86c48dd
 DIST fwupd-1.3.6.tar.gz 2207849 BLAKE2B 465055d90576d4c0a7812f2554d2bc3298a12030816a2469ce653d28f9ea81e363c401355191d41b200975a615cfc64b954e0cced6b6f6bbfbbf26f63163a25e SHA512 20a5f346563b1cb8296f31ea448f336d8b54df2e5296524e2fa040a31001838b0de4a88f0d4aad9f5eeaeb4acc46919c0effb254ce681556db00cec5a4a1bc78
 DIST fwupd-1.3.7.tar.gz 2223704 BLAKE2B e86603542dc76ec355912fae86721b8e60cea8bef34224cf5f157d3a91058deafc2804761ece472f0264ef42d7fa2b77d935a1638c9db3a6c0722c0659ce6a59 SHA512 6734533193be40051a565609905097c76d9f53c53075e37f560408be698774be0867383877b2acbcd2e5a92c817afdd30532f3d94465b27311b31c825a38481e

diff --git a/sys-apps/fwupd/fwupd-1.3.5.ebuild b/sys-apps/fwupd/fwupd-1.3.5.ebuild
deleted file mode 100644
index 9b799a5b2c1..00000000000
--- a/sys-apps/fwupd/fwupd-1.3.5.ebuild
+++ /dev/null
@@ -1,159 +0,0 @@
-# Copyright 1999-2020 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-
-PYTHON_COMPAT=( python3_{6,7,8} )
-
-inherit linux-info meson python-single-r1 vala xdg toolchain-funcs
-
-DESCRIPTION="Aims to make updating firmware on Linux automatic, safe and reliable"
-HOMEPAGE="https://fwupd.org"
-SRC_URI="https://github.com/hughsie/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
-
-LICENSE="LGPL-2.1+"
-SLOT="0"
-KEYWORDS="~amd64 ~arm ~x86"
-IUSE="agent amt consolekit dell gtk-doc elogind minimal +gpg introspection +man nvme pkcs7 redfish synaptics systemd test thunderbolt uefi"
-REQUIRED_USE="${PYTHON_REQUIRED_USE}
-	^^ ( consolekit elogind minimal systemd )
-	dell? ( uefi )
-	minimal? ( !introspection )
-"
-RESTRICT="!test? ( test )"
-
-BDEPEND="$(vala_depend)
-	virtual/pkgconfig
-	gtk-doc? ( dev-util/gtk-doc )
-	introspection? ( dev-libs/gobject-introspection )
-	man? (
-		app-text/docbook-sgml-utils
-		sys-apps/help2man
-	)
-	test? (
-		thunderbolt? ( dev-util/umockdev )
-		net-libs/gnutls[tools]
-	)
-"
-DEPEND="${PYTHON_DEPS}
-	>=app-arch/gcab-1.0
-	app-arch/libarchive:=
-	dev-db/sqlite
-	>=dev-libs/glib-2.45.8:2
-	dev-libs/json-glib
-	dev-libs/libgpg-error
-	dev-libs/libgudev:=
-	>=dev-libs/libgusb-0.2.9[introspection?]
-	>=dev-libs/libxmlb-0.1.13
-	dev-python/pillow[${PYTHON_USEDEP}]
-	dev-python/pycairo[${PYTHON_USEDEP}]
-	dev-python/pygobject:3[cairo,${PYTHON_USEDEP}]
-	>=net-libs/libsoup-2.51.92:2.4[introspection?]
-	virtual/libelf:0=
-	virtual/udev
-	consolekit? ( >=sys-auth/consolekit-1.0.0 )
-	dell? (
-		sys-libs/efivar
-		>=sys-libs/libsmbios-2.4.0
-	)
-	elogind? ( sys-auth/elogind )
-	gpg? (
-		app-crypt/gpgme
-		dev-libs/libgpg-error
-	)
-	!minimal? (
-		>=sys-auth/polkit-0.103
-	)
-	nvme? ( sys-libs/efivar )
-	pkcs7? ( >=net-libs/gnutls-3.4.4.1:= )
-	redfish? ( sys-libs/efivar )
-	systemd? ( >=sys-apps/systemd-211 )
-	thunderbolt? (
-		sys-apps/thunderbolt-software-user-space
-	)
-	uefi? (
-		app-crypt/tpm2-tss
-		media-libs/fontconfig
-		media-libs/freetype
-		sys-boot/gnu-efi
-		sys-boot/efibootmgr
-		>=sys-libs/efivar-33
-		x11-libs/cairo
-	)
-"
-RDEPEND="
-	${DEPEND}
-	sys-apps/dbus
-"
-
-pkg_setup() {
-	tc-ld-disable-gold # bug https://github.com/fwupd/fwupd/issues/1530
-
-	python-single-r1_pkg_setup
-	if use nvme; then
-		kernel_is -ge 4 4 || die "NVMe support requires kernel >= 4.4"
-	fi
-}
-
-src_prepare() {
-	default
-	# c.f. https://github.com/fwupd/fwupd/issues/1414
-	sed -e "/test('thunderbolt-self-test', e, env: test_env, timeout : 120)/d" \
-		-i plugins/thunderbolt/meson.build || die
-	vala_src_prepare
-}
-
-src_configure() {
-	local emesonargs=(
-		--localstatedir "${EPREFIX}"/var
-		-Dbuild="$(usex minimal standalone all)"
-		$(meson_use agent)
-		$(meson_use amt plugin_amt)
-		$(meson_use consolekit)
-		$(meson_use dell plugin_dell)
-		$(meson_use elogind)
-		$(meson_use gpg)
-		$(meson_use gtk-doc gtkdoc)
-		$(meson_use man)
-		$(meson_use nvme plugin_nvme)
-		$(meson_use pkcs7)
-		$(meson_use redfish plugin_redfish)
-		$(meson_use synaptics plugin_synaptics)
-		$(meson_use systemd)
-		$(meson_use test tests)
-		$(meson_use thunderbolt plugin_thunderbolt)
-		$(meson_use uefi plugin_uefi)
-		# Requires libflashrom which our sys-apps/flashrom
-		# package does not provide
-		-Dplugin_flashrom="false"
-		# Dependencies are not available (yet?)
-		-Dplugin_modem_manager="false"
-	)
-	export CACHE_DIRECTORY="${T}"
-	meson_src_configure
-}
-
-src_install() {
-	meson_src_install
-
-	if ! use minimal ; then
-		sed "s@%SEAT_MANAGER%@$(usex elogind elogind consolekit)@" \
-			"${FILESDIR}"/${PN}-r1 \
-			> "${T}"/${PN} || die
-		doinitd "${T}"/${PN}
-
-		if ! use systemd ; then
-			# Don't timeout when fwupd is running (#673140)
-			sed '/^IdleTimeout=/s@=[[:digit:]]\+@=0@' \
-				-i "${ED}"/etc/${PN}/daemon.conf || die
-		fi
-	fi
-}
-
-pkg_postinst() {
-	xdg_pkg_postinst
-	elog "In case you are using openrc as init system"
-	elog "and you're upgrading from <fwupd-1.1.0, you"
-	elog "need to start the fwupd daemon via the openrc"
-	elog "init script that comes with this package."
-}