[gentoo-commits] repo/gentoo:master commit in: sys-kernel/gentoo-kernel-bin/

[Sam James]

commit:     6d894f114999229c71425b03d2d2d4713af51233
Author:     Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Thu May 13 16:50:53 2021 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Thu May 13 16:52:50 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=6d894f11

sys-kernel/gentoo-kernel-bin: bump to 5.10.36 for arm64

Signed-off-by: Sam James <sam <AT> gentoo.org>

 sys-kernel/gentoo-kernel-bin/Manifest              |   1 +
 .../gentoo-kernel-bin-5.10.36-r1.ebuild            | 114 +++++++++++++++++++++
 2 files changed, 115 insertions(+)

diff --git a/sys-kernel/gentoo-kernel-bin/Manifest b/sys-kernel/gentoo-kernel-bin/Manifest
index 0d561b4dd97..3040e1e65a7 100644
--- a/sys-kernel/gentoo-kernel-bin/Manifest
+++ b/sys-kernel/gentoo-kernel-bin/Manifest
@@ -21,6 +21,7 @@ DIST gentoo-kernel-5.10.35-1.amd64.xpak 65506651 BLAKE2B 0a5ee4e6b2791365f7de77f
 DIST gentoo-kernel-5.10.35-1.arm64.xpak 59347012 BLAKE2B 9d934f8d834eaea55f24bca126f3b281baf6f2c0af07f6183ae2803559c9dc9c5784f8b399302ea30e81b5fb8bd0a02e2b1c1ad6ab50f0e3b319bd9a89e110f9 SHA512 acbbc3d730d5ee755070f669de7e9a6ce0889b024393c06f0c67c31cf4ad40b67ea0d4ea170ed7ca46498a5ccac80b433784a6533eaf4fd9caa57cf8f445ff75
 DIST gentoo-kernel-5.10.35-1.x86.xpak 57305784 BLAKE2B 2ec3a3bf99684986bea53260012faa2defeeab5850953881c3438d44843bf8739d46d4e56eb07e206bdb161868283ab77b54f1a9c2247dd47e6aeaeae7326f0c SHA512 a8637130f5cb64f959a88ee5bf3263f862a226197c58301c936efd503f550fa84405c978d5939835f9553039d792c13457aff58af99f5482b131291f54384f20
 DIST gentoo-kernel-5.10.36-1.amd64.xpak 65513919 BLAKE2B bf171d4535cb040bb8fc9ac6918836b56ea3ce39950a875ddc0b07748f1da7bb902a00691caa0a16725863e8a901b535077cf536c30c88e977763d1ba9c2d12e SHA512 fb2836557ac54fe77b343da97b00c4feb67770526185b13e7dbe5a61bc1b1504497707d5a6745bb034a71dfbde7ae0828c9584f0556bc878758dcd78dbf8a287
+DIST gentoo-kernel-5.10.36-1.arm64.xpak 59285325 BLAKE2B a0e202bb94e60632c9330152c61cad8ecca619f75ae1503b9cc04aa579995c8380143a4b9a9a53a35c06bf0321b32d0328d903210fff5d91d9796cccddc8d6bb SHA512 6a642e21f87f9be6e414375c0606fedd09ee18826e17105de41bba9c4b845e1f7ad4b8f3e28e490b3912a12e916771d124b6670e305bcb3d524985d380c165d9
 DIST gentoo-kernel-5.10.36-1.x86.xpak 57246018 BLAKE2B 990349168a8ee58f30392afbd7798196ccc245741c2ff2b59c976c0efd7b26d98b0b9339d59b67d2eb5d60ceb91bab1e3eaddd1e5162ec9e572e6c669665e461 SHA512 7e83c274e54a7646efcbcf1ad6074c1d21d969b020d9713d07bb861c21fb3c5d878511bafee9d62ad359f204464a9537d72f2029d7484319256a5d29cfbeecbf
 DIST gentoo-kernel-5.11.19-1.amd64.xpak 65896925 BLAKE2B 7bad7ad368668bf79b5ac630b4e9bedfee4c81d7a27459fac002d5d4cb40496922f134bf41a2c479a184b64fbda0da6eb45e37724b1c6e29ebb56e3838b81052 SHA512 56c49da22f0a7c8870e7a57e2bdced8eba2b0295ffe7e3a5977b22e39fa43000077cccdad893643a0abb9a82aa9f57a32a8a47873839d549627cbba435b3010b
 DIST gentoo-kernel-5.11.19-1.arm64.xpak 59764011 BLAKE2B 719a3282547c4980ae5b1980be86e4a0b7f881577aee11fec21dcd374b1b89303d0cd6f9528b373a48a61ce0d5bbc6304ca2302a038e81e1bccb34b6d3af2139 SHA512 8b526f37e6d444d43e0b39936b6fa6e644d986794333bb33381fcdb6d78d3e9343ba4353ad558955eee4ce15c777bc2c13224851254fa84868d8e16a29d0243e

diff --git a/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.10.36-r1.ebuild b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.10.36-r1.ebuild
new file mode 100644
index 00000000000..8198cf5ace0
--- /dev/null
+++ b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.10.36-r1.ebuild
@@ -0,0 +1,114 @@
+# Copyright 2020-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit kernel-install toolchain-funcs
+
+MY_P=linux-${PV%.*}
+GENPATCHES_P=genpatches-${PV%.*}-$(( ${PV##*.} + 3 ))
+BINPKG=${P/-bin/}-1
+
+DESCRIPTION="Pre-built Linux kernel with genpatches"
+HOMEPAGE="https://www.kernel.org/"
+SRC_URI+="
+	https://cdn.kernel.org/pub/linux/kernel/v$(ver_cut 1).x/${MY_P}.tar.xz
+	https://dev.gentoo.org/~alicef/dist/genpatches/${GENPATCHES_P}.base.tar.xz
+	https://dev.gentoo.org/~alicef/dist/genpatches/${GENPATCHES_P}.extras.tar.xz
+	arm64? (
+		https://dev.gentoo.org/~sam/binpkg/arm64/kernel/sys-kernel/gentoo-kernel/${BINPKG}.xpak
+			-> ${BINPKG}.arm64.xpak
+	)
+"
+S=${WORKDIR}
+
+LICENSE="GPL-2"
+KEYWORDS="~arm64"
+
+RDEPEND="
+	!sys-kernel/gentoo-kernel:${SLOT}"
+PDEPEND="
+	>=virtual/dist-kernel-${PV}"
+BDEPEND="
+	sys-devel/bc
+	sys-devel/flex
+	virtual/libelf
+	virtual/yacc"
+
+QA_PREBUILT='*'
+
+KV_LOCALVERSION='-gentoo-dist'
+KPV=${PV}${KV_LOCALVERSION}
+
+src_unpack() {
+	default
+	ebegin "Unpacking ${BINPKG}.${ARCH}.xpak"
+	tar -x < <(xz -c -d --single-stream "${DISTDIR}/${BINPKG}.${ARCH}.xpak")
+	eend ${?} || die "Unpacking ${BINPKG} failed"
+}
+
+src_prepare() {
+	local PATCHES=(
+		# meh, genpatches have no directory
+		"${WORKDIR}"/*.patch
+	)
+	cd "${MY_P}" || die
+	default
+}
+
+src_configure() {
+	# force ld.bfd if we can find it easily
+	local LD="$(tc-getLD)"
+	if type -P "${LD}.bfd" &>/dev/null; then
+		LD+=.bfd
+	fi
+
+	tc-export_build_env
+	local makeargs=(
+		V=1
+
+		HOSTCC="$(tc-getBUILD_CC)"
+		HOSTCXX="$(tc-getBUILD_CXX)"
+		HOSTCFLAGS="${BUILD_CFLAGS}"
+		HOSTLDFLAGS="${BUILD_LDFLAGS}"
+
+		CROSS_COMPILE=${CHOST}-
+		AS="$(tc-getAS)"
+		CC="$(tc-getCC)"
+		LD="${LD}"
+		AR="$(tc-getAR)"
+		NM="$(tc-getNM)"
+		STRIP=":"
+		OBJCOPY="$(tc-getOBJCOPY)"
+		OBJDUMP="$(tc-getOBJDUMP)"
+
+		# we need to pass it to override colliding Gentoo envvar
+		ARCH=$(tc-arch-kernel)
+
+		O="${WORKDIR}"/modprep
+	)
+
+	mkdir modprep || die
+	cp "usr/src/linux-${KPV}/.config" modprep/ || die
+	emake -C "${MY_P}" "${makeargs[@]}" modules_prepare
+}
+
+src_test() {
+	kernel-install_test "${KPV}" \
+		"${WORKDIR}/usr/src/linux-${KPV}/$(dist-kernel_get_image_path)" \
+		"lib/modules/${KPV}"
+}
+
+src_install() {
+	mv lib usr "${ED}"/ || die
+
+	# strip out-of-source build stuffs from modprep
+	# and then copy built files
+	find modprep -type f '(' \
+			-name Makefile -o \
+			-name '*.[ao]' -o \
+			'(' -name '.*' -a -not -name '.config' ')' \
+		')' -delete || die
+	rm modprep/source || die
+	cp -p -R modprep/. "${ED}/usr/src/linux-${KPV}"/ || die
+}