[gentoo-commits] repo/gentoo:master commit in: sys-process/psmisc/

[Lars Wendler]

commit:     31a8766e174a9063a21d0c359750f9cbafbb8e0d
Author:     Lars Wendler <polynomial-c <AT> gentoo <DOT> org>
AuthorDate: Thu Oct 27 06:02:28 2016 +0000
Commit:     Lars Wendler <polynomial-c <AT> gentoo <DOT> org>
CommitDate: Thu Oct 27 06:06:00 2016 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=31a8766e

sys-process/psmisc: Revbump to add sub-slot dependency for sys-libs/ncurses.

This was requested in Gentoo bug #598166.
Committed straight to stable where -r2 was stable as nothing changed except for
the EAPI and the ncurses sub-slot dep.

Package-Manager: portage-2.3.2
Signed-off-by: Lars Wendler <polynomial-c <AT> gentoo.org>

 sys-process/psmisc/psmisc-22.21-r3.ebuild | 61 +++++++++++++++++++++++++++++++
 1 file changed, 61 insertions(+)

diff --git a/sys-process/psmisc/psmisc-22.21-r3.ebuild b/sys-process/psmisc/psmisc-22.21-r3.ebuild
new file mode 100644
index 00000000..f0859ec
--- /dev/null
+++ b/sys-process/psmisc/psmisc-22.21-r3.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+inherit eutils
+
+DESCRIPTION="A set of tools that use the proc filesystem"
+HOMEPAGE="http://psmisc.sourceforge.net/"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="alpha amd64 arm arm64 hppa ia64 m68k ~mips ppc ppc64 s390 sh sparc x86 ~amd64-linux ~arm-linux ~ia64-linux ~x86-linux"
+IUSE="ipv6 nls selinux X"
+
+RDEPEND=">=sys-libs/ncurses-5.7-r7:0=
+	nls? ( virtual/libintl )
+	selinux? ( sys-libs/libselinux )"
+DEPEND="${RDEPEND}
+	>=sys-devel/libtool-2.2.6b
+	nls? ( sys-devel/gettext )"
+
+DOCS="AUTHORS ChangeLog NEWS README"
+
+PATCHES=(
+	"${FILESDIR}/${P}-fuser_typo_fix.patch"
+	"${FILESDIR}/${P}-sysmacros.patch"
+)
+
+src_prepare() {
+	epatch "${PATCHES[@]}"
+}
+
+src_configure() {
+	econf \
+		$(use_enable selinux) \
+		--disable-harden-flags \
+		$(use_enable ipv6) \
+		$(use_enable nls)
+}
+
+src_compile() {
+	# peekfd is a fragile crap hack #330631
+	nonfatal emake -C src peekfd || touch src/peekfd{.o,}
+	emake
+}
+
+src_install() {
+	default
+
+	use X || rm -f "${ED}"/usr/bin/pstree.x11
+
+	[[ -s ${ED}/usr/bin/peekfd ]] || rm -f "${ED}"/usr/bin/peekfd
+	[[ -e ${ED}/usr/bin/peekfd ]] || rm -f "${ED}"/usr/share/man/man1/peekfd.1
+
+	# fuser is needed by init.d scripts; use * wildcard for #458250
+	dodir /bin
+	mv "${ED}"/usr/bin/*fuser "${ED}"/bin || die
+}