[gentoo-commits] proj/gnome:master commit in: x11-libs/gtksourceview/

[Gilles Dartiguelongue]

commit:     6b4abc80ae9bde121d5951f33e375a8c2c21eb28
Author:     Gilles Dartiguelongue <eva <AT> gentoo <DOT> org>
AuthorDate: Sun Dec  1 17:39:19 2013 +0000
Commit:     Gilles Dartiguelongue <eva <AT> gentoo <DOT> org>
CommitDate: Sun Dec  1 17:40:59 2013 +0000
URL:        http://git.overlays.gentoo.org/gitweb/?p=proj/gnome.git;a=commit;h=6b4abc80

x11-libs/gtksourceview: 3.8.2 → 3.10.1

---
 x11-libs/gtksourceview/gtksourceview-3.10.1.ebuild | 51 ++++++++++++++++++++++
 x11-libs/gtksourceview/gtksourceview-9999.ebuild   | 39 +++++++----------
 2 files changed, 67 insertions(+), 23 deletions(-)

diff --git a/x11-libs/gtksourceview/gtksourceview-3.10.1.ebuild b/x11-libs/gtksourceview/gtksourceview-3.10.1.ebuild
new file mode 100644
index 0000000..e593ab1
--- /dev/null
+++ b/x11-libs/gtksourceview/gtksourceview-3.10.1.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI="5"
+GCONF_DEBUG="no"
+
+inherit gnome2 virtualx
+
+DESCRIPTION="A text widget implementing syntax highlighting and other features"
+HOMEPAGE="http://projects.gnome.org/gtksourceview/"
+
+LICENSE="GPL-2+ LGPL-2.1+"
+SLOT="3.0/2"
+IUSE="glade +introspection"
+KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~x86-freebsd ~x86-interix ~amd64-linux ~x86-linux ~ppc-macos ~x86-solaris"
+
+# Note: has native OSX support, prefix teams, attack!
+RDEPEND="
+	>=dev-libs/glib-2.37.3:2
+	>=dev-libs/libxml2-2.6:2
+	>=x11-libs/gtk+-3.9.9:3[introspection?]
+	glade? ( >=dev-util/glade-3.9:3.10 )
+	introspection? ( >=dev-libs/gobject-introspection-0.9.0 )
+"
+DEPEND="${RDEPEND}
+	dev-util/gtk-doc-am
+	>=dev-util/intltool-0.50
+	>=sys-devel/gettext-0.17
+	virtual/pkgconfig
+"
+
+src_configure() {
+	gnome2_src_configure \
+		--disable-deprecations \
+		--enable-providers \
+		$(use_enable glade glade-catalog) \
+		$(use_enable introspection)
+}
+
+src_test() {
+	Xemake check
+}
+
+src_install() {
+	DOCS="AUTHORS ChangeLog HACKING MAINTAINERS NEWS README"
+	gnome2_src_install
+
+	insinto /usr/share/${PN}-3.0/language-specs
+	doins "${FILESDIR}"/2.0/gentoo.lang
+}

diff --git a/x11-libs/gtksourceview/gtksourceview-9999.ebuild b/x11-libs/gtksourceview/gtksourceview-9999.ebuild
index 1ffdecc..8269551 100644
--- a/x11-libs/gtksourceview/gtksourceview-9999.ebuild
+++ b/x11-libs/gtksourceview/gtksourceview-9999.ebuild
@@ -1,10 +1,9 @@
-# Copyright 1999-2012 Gentoo Foundation
+# Copyright 1999-2013 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
 # $Header: $
 
 EAPI="5"
 GCONF_DEBUG="no"
-GNOME2_LA_PUNT="yes"
 
 inherit gnome2 virtualx
 if [[ ${PV} = 9999 ]]; then
@@ -15,7 +14,7 @@ DESCRIPTION="A text widget implementing syntax highlighting and other features"
 HOMEPAGE="http://projects.gnome.org/gtksourceview/"
 
 LICENSE="GPL-2+ LGPL-2.1+"
-SLOT="3.0"
+SLOT="3.0/2"
 IUSE="glade +introspection"
 if [[ ${PV} = 9999 ]]; then
 	IUSE="${IUSE} doc"
@@ -25,38 +24,31 @@ else
 fi
 
 # Note: has native OSX support, prefix teams, attack!
-RDEPEND=">=x11-libs/gtk+-3.4:3[introspection?]
+RDEPEND="
+	>=dev-libs/glib-2.37.3:2
 	>=dev-libs/libxml2-2.6:2
-	>=dev-libs/glib-2.32:2
+	>=x11-libs/gtk+-3.9.9:3[introspection?]
 	glade? ( >=dev-util/glade-3.9:3.10 )
-	introspection? ( >=dev-libs/gobject-introspection-0.9.0 )"
+	introspection? ( >=dev-libs/gobject-introspection-0.9.0 )
+"
 DEPEND="${RDEPEND}
 	dev-util/gtk-doc-am
 	>=dev-util/intltool-0.50
 	>=sys-devel/gettext-0.17
-	virtual/pkgconfig"
+	virtual/pkgconfig
+"
 
 if [[ ${PV} = 9999 ]]; then
 	 DEPEND="${DEPEND}
 		doc? ( >=dev-util/gtk-doc-1.11 )"
 fi
 
-src_prepare() {
-	DOCS="AUTHORS ChangeLog HACKING MAINTAINERS NEWS README"
-	G2CONF="${G2CONF}
-		--disable-deprecations
-		--enable-providers
-		$(use_enable glade glade-catalog)
-		$(use_enable introspection)"
-
-	gnome2_src_prepare
-
-	sed -i -e 's:--warn-all::' gtksourceview/Makefile.in || die
-
-	# Skip broken test until upstream bug #621383 is solved
-	sed -e "/guess-language/d" \
-		-e "/get-language/d" \
-		-i tests/test-languagemanager.c || die
+src_configure() {
+	gnome2_src_configure \
+		--disable-deprecations \
+		--enable-providers \
+		$(use_enable glade glade-catalog) \
+		$(use_enable introspection)
 }
 
 src_test() {
@@ -64,6 +56,7 @@ src_test() {
 }
 
 src_install() {
+	DOCS="AUTHORS ChangeLog HACKING MAINTAINERS NEWS README"
 	gnome2_src_install
 
 	insinto /usr/share/${PN}-3.0/language-specs