[gentoo-commits] gentoo-x86 commit in sys-apps/file: file-9999.ebuild file-5.18-r1.ebuild ChangeLog

[Mike Frysinger (vapier)]

vapier      14/03/27 03:30:14

  Modified:             file-9999.ebuild ChangeLog
  Added:                file-5.18-r1.ebuild
  Log:
  Add multilib support.
  
  (Portage version: 2.2.8-r1/cvs/Linux x86_64, signed Manifest commit with key D2E96200)

Revision  Changes    Path
1.6                  sys-apps/file/file-9999.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/file/file-9999.ebuild?rev=1.6&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/file/file-9999.ebuild?rev=1.6&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/file/file-9999.ebuild?r1=1.5&r2=1.6

Index: file-9999.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-apps/file/file-9999.ebuild,v
retrieving revision 1.5
retrieving revision 1.6
diff -u -r1.5 -r1.6
--- file-9999.ebuild	18 Jan 2014 03:06:30 -0000	1.5
+++ file-9999.ebuild	27 Mar 2014 03:30:14 -0000	1.6
@@ -1,12 +1,12 @@
 # Copyright 1999-2014 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/sys-apps/file/file-9999.ebuild,v 1.5 2014/01/18 03:06:30 vapier Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/file/file-9999.ebuild,v 1.6 2014/03/27 03:30:14 vapier Exp $
 
 EAPI="4"
 PYTHON_COMPAT=( python{2_6,2_7,3_2,3_3} pypy2_0 )
 DISTUTILS_OPTIONAL=1
 
-inherit eutils distutils-r1 libtool toolchain-funcs
+inherit eutils distutils-r1 libtool toolchain-funcs multilib-minimal
 
 if [[ ${PV} == "9999" ]] ; then
 	EGIT_REPO_URI="git://github.com/glensc/file.git"
@@ -37,17 +37,12 @@
 	mv python/README{,.python}
 }
 
-wd() { echo "${WORKDIR}"/build-${CHOST}; }
-
-do_configure() {
-	ECONF_SOURCE=${S}
-
-	mkdir "$(wd)"
-	pushd "$(wd)" >/dev/null
-
-	econf "$@"
-
-	popd >/dev/null
+multilib_src_configure() {
+	ECONF_SOURCE=${S} \
+	ac_cv_header_zlib_h=$(usex zlib) \
+	ac_cv_lib_z_gzopen=$(usex zlib)
+	econf \
+		$(use_enable static-libs static)
 }
 
 src_configure() {
@@ -55,7 +50,10 @@
 	# because people often don't keep matching host/target
 	# file versions #362941
 	if tc-is-cross-compiler && ! ROOT=/ has_version ~${CATEGORY}/${P} ; then
+		mkdir -p "${WORKDIR}"/build
+		cd "${WORKDIR}"/build
 		tc-export_build_env BUILD_C{C,XX}
+		ECONF_SOURCE=${S} \
 		ac_cv_header_zlib_h=no \
 		ac_cv_lib_z_gzopen=no \
 		CHOST=${CBUILD} \
@@ -65,29 +63,39 @@
 		LDFLAGS="${BUILD_LDFLAGS} -static" \
 		CC=${BUILD_CC} \
 		CXX=${BUILD_CXX} \
-		do_configure --disable-shared
+		econf --disable-shared
 	fi
 
-	export ac_cv_header_zlib_h=$(usex zlib) ac_cv_lib_z_gzopen=$(usex zlib)
-	do_configure $(use_enable static-libs static)
+	multilib-minimal_src_configure
 }
 
-do_make() {
-	emake -C "$(wd)" "$@"
+multilib_src_compile() {
+	if multilib_build_binaries ; then
+		emake
+	else
+		emake -C src libmagic.la
+	fi
 }
 
 src_compile() {
 	if tc-is-cross-compiler && ! ROOT=/ has_version ~${CATEGORY}/${P} ; then
-		CHOST=${CBUILD} do_make -C src file
-		PATH=$(CHOST=${CBUILD} wd)/src:${PATH}
+		emake -C "${WORKDIR}"/build/src file
+		PATH="${WORKDIR}/build/src:${PATH}"
 	fi
-	do_make
+	multilib-minimal_src_compile
 
 	use python && cd python && distutils-r1_src_compile
 }
 
-src_install() {
-	do_make DESTDIR="${D}" install
+multilib_src_install() {
+	if multilib_build_binaries ; then
+		default
+	else
+		emake -C src install-{includeHEADERS,libLTLIBRARIES} DESTDIR="${D}"
+	fi
+}
+
+multilib_src_install_all() {
 	dodoc ChangeLog MAINT README
 
 	use python && cd python && distutils-r1_src_install



1.272                sys-apps/file/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/file/ChangeLog?rev=1.272&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/file/ChangeLog?rev=1.272&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/file/ChangeLog?r1=1.271&r2=1.272

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-apps/file/ChangeLog,v
retrieving revision 1.271
retrieving revision 1.272
diff -u -r1.271 -r1.272
--- ChangeLog	26 Mar 2014 16:10:39 -0000	1.271
+++ ChangeLog	27 Mar 2014 03:30:14 -0000	1.272
@@ -1,6 +1,12 @@
 # ChangeLog for sys-apps/file
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-apps/file/ChangeLog,v 1.271 2014/03/26 16:10:39 vapier Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/file/ChangeLog,v 1.272 2014/03/27 03:30:14 vapier Exp $
+
+*file-5.18-r1 (27 Mar 2014)
+
+  27 Mar 2014; Mike Frysinger <vapier@g.o> +file-5.18-r1.ebuild,
+  file-9999.ebuild:
+  Add multilib support.
 
 *file-5.18 (26 Mar 2014)
 



1.1                  sys-apps/file/file-5.18-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/file/file-5.18-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/file/file-5.18-r1.ebuild?rev=1.1&content-type=text/plain

Index: file-5.18-r1.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-apps/file/file-5.18-r1.ebuild,v 1.1 2014/03/27 03:30:14 vapier Exp $

EAPI="4"
PYTHON_COMPAT=( python{2_6,2_7,3_2,3_3} pypy2_0 )
DISTUTILS_OPTIONAL=1

inherit eutils distutils-r1 libtool toolchain-funcs multilib-minimal

if [[ ${PV} == "9999" ]] ; then
	EGIT_REPO_URI="git://github.com/glensc/file.git"
	inherit autotools git-r3
else
	SRC_URI="ftp://ftp.astron.com/pub/file/${P}.tar.gz
		ftp://ftp.gw.com/mirrors/pub/unix/file/${P}.tar.gz"
	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~sparc-fbsd ~x86-fbsd"
fi

DESCRIPTION="identify a file's format by scanning binary data for patterns"
HOMEPAGE="http://www.darwinsys.com/file/"

LICENSE="BSD-2"
SLOT="0"
IUSE="python static-libs zlib"

DEPEND="python? ( ${PYTHON_DEPS} )
	zlib? ( sys-libs/zlib[${MULTILIB_USEDEP}] )"
RDEPEND="${DEPEND}
	python? ( !dev-python/python-magic )"

src_prepare() {
	[[ ${PV} == "9999" ]] && eautoreconf
	elibtoolize

	# don't let python README kill main README #60043
	mv python/README{,.python}
}

multilib_src_configure() {
	ECONF_SOURCE=${S} \
	ac_cv_header_zlib_h=$(usex zlib) \
	ac_cv_lib_z_gzopen=$(usex zlib)
	econf \
		$(use_enable static-libs static)
}

src_configure() {
	# when cross-compiling, we need to build up our own file
	# because people often don't keep matching host/target
	# file versions #362941
	if tc-is-cross-compiler && ! ROOT=/ has_version ~${CATEGORY}/${P} ; then
		mkdir -p "${WORKDIR}"/build
		cd "${WORKDIR}"/build
		tc-export_build_env BUILD_C{C,XX}
		ECONF_SOURCE=${S} \
		ac_cv_header_zlib_h=no \
		ac_cv_lib_z_gzopen=no \
		CHOST=${CBUILD} \
		CFLAGS=${BUILD_CFLAGS} \
		CXXFLAGS=${BUILD_CXXFLAGS} \
		CPPFLAGS=${BUILD_CPPFLAGS} \
		LDFLAGS="${BUILD_LDFLAGS} -static" \
		CC=${BUILD_CC} \
		CXX=${BUILD_CXX} \
		econf --disable-shared
	fi

	multilib-minimal_src_configure
}

multilib_src_compile() {
	if multilib_build_binaries ; then
		emake
	else
		emake -C src libmagic.la
	fi
}

src_compile() {
	if tc-is-cross-compiler && ! ROOT=/ has_version ~${CATEGORY}/${P} ; then
		emake -C "${WORKDIR}"/build/src file
		PATH="${WORKDIR}/build/src:${PATH}"
	fi
	multilib-minimal_src_compile

	use python && cd python && distutils-r1_src_compile
}

multilib_src_install() {
	if multilib_build_binaries ; then
		default
	else
		emake -C src install-{includeHEADERS,libLTLIBRARIES} DESTDIR="${D}"
	fi
}

multilib_src_install_all() {
	dodoc ChangeLog MAINT README

	use python && cd python && distutils-r1_src_install
	prune_libtool_files
}