[gentoo-commits] repo/gentoo:master commit in: net-misc/modemmanager/

[Matt Turner]

commit:     acd598b815b2c6b49a76954fb6d642ec9ad0f641
Author:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
AuthorDate: Wed Sep 15 20:25:13 2021 +0000
Commit:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
CommitDate: Wed Sep 15 20:27:10 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=acd598b8

net-misc/modemmanager: Version bump to 1.18.0

Signed-off-by: Matt Turner <mattst88 <AT> gentoo.org>

 net-misc/modemmanager/Manifest                   |   1 +
 net-misc/modemmanager/modemmanager-1.18.0.ebuild | 129 +++++++++++++++++++++++
 2 files changed, 130 insertions(+)

diff --git a/net-misc/modemmanager/Manifest b/net-misc/modemmanager/Manifest
index 7d8745f3117..8fe2293a97a 100644
--- a/net-misc/modemmanager/Manifest
+++ b/net-misc/modemmanager/Manifest
@@ -1,2 +1,3 @@
 DIST ModemManager-1.16.6.tar.xz 2339528 BLAKE2B b76a8b6959d988a27d411384440b9bd1b7ac1a9d780b77319e735c4b42c55c51f51304ae936aa9b385634640bcb1a55696d4bd25ffdaf88eb73839bfefe5e091 SHA512 78a928007732baaa0eaed9d587913774d4fb79049d652474f39176190496012dc4c93fd0bd774ed6f86f845f3b9f345bcccf4c7b2438b83cf5846b2bcdcb39d5
 DIST ModemManager-1.16.8.tar.xz 2344748 BLAKE2B 70ed052a7cd5561518577948419b0363816805d8a1af7de2874fa3dae795e38611d34733f5ed5dcfb12270421430249ee0a49bf54e4dcb87abe4ab595bd0b4c2 SHA512 be32ef03210035a93bad5ac0e339863c247cd000276e1bfa1acf584df652a78eda74990226a00a20e957481ce92801ed365b153de8f927a983cec41d3bbe3082
+DIST ModemManager-1.18.0.tar.xz 2493576 BLAKE2B 36034a589fb38447c83a232b6d24ca2fceed15ebc89a41af969bdcebeb482d4baf2657d063b1011c0df252b4ba7f703284cbf111b90d565d66157006331d6e69 SHA512 6e99e5529a74e6fdf814b4fcb9c9f5cd6a0398cd75303feee62c3564f9d62f54bb5a435a9847ed085fe2031af5a8d821d43f9cabed7d3be019ae0f5c8b0e11d2

diff --git a/net-misc/modemmanager/modemmanager-1.18.0.ebuild b/net-misc/modemmanager/modemmanager-1.18.0.ebuild
new file mode 100644
index 00000000000..efa8c2c4ef4
--- /dev/null
+++ b/net-misc/modemmanager/modemmanager-1.18.0.ebuild
@@ -0,0 +1,129 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+VALA_USE_DEPEND="vapigen"
+
+inherit gnome2 readme.gentoo-r1 systemd toolchain-funcs udev vala
+
+DESCRIPTION="Modem and mobile broadband management libraries"
+HOMEPAGE="https://www.freedesktop.org/wiki/Software/ModemManager/"
+SRC_URI="https://www.freedesktop.org/software/ModemManager/ModemManager-${PV}.tar.xz"
+
+LICENSE="GPL-2+"
+SLOT="0/1" # subslot = dbus interface version, i.e. N in org.freedesktop.ModemManager${N}
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86"
+
+IUSE="elogind +introspection mbim policykit +qmi systemd +udev vala"
+REQUIRED_USE="
+	?? ( elogind systemd )
+	vala? ( introspection )
+"
+
+DEPEND="
+	>=dev-libs/glib-2.56.0:2
+	udev? ( >=dev-libs/libgudev-232:= )
+	introspection? ( >=dev-libs/gobject-introspection-0.9.6:= )
+	mbim? ( >=net-libs/libmbim-1.26.0 )
+	policykit? ( >=sys-auth/polkit-0.106[introspection?] )
+	qmi? ( >=net-libs/libqmi-1.30.2:= )
+	elogind? ( sys-auth/elogind )
+	systemd? ( >=sys-apps/systemd-209 )
+"
+RDEPEND="${DEPEND}
+	policykit? ( acct-group/plugdev )
+"
+BDEPEND="
+	dev-util/gdbus-codegen
+	dev-util/glib-utils
+	>=dev-util/gtk-doc-am-1
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+	vala? ( $(vala_depend) )
+"
+
+S="${WORKDIR}/ModemManager-${PV}"
+
+src_prepare() {
+	DOC_CONTENTS="
+		If your USB modem shows up only as a storage device when you plug it in,
+		then you should install sys-apps/usb_modeswitch, which will automatically
+		switch it over to USB modem mode whenever you plug it in.\n"
+
+	if use policykit; then
+		DOC_CONTENTS+="\nTo control your modem without needing to enter the root password,
+			add your user account to the 'plugdev' group."
+	fi
+
+	use vala && vala_src_prepare
+	gnome2_src_prepare
+}
+
+src_configure() {
+	local myconf=(
+		--disable-Werror
+		--disable-static
+		--with-dist-version=${PVR}
+		--with-udev-base-dir="$(get_udevdir)"
+		$(use_with udev)
+		$(use_enable introspection)
+		$(use_with mbim)
+		$(use_with policykit polkit)
+		$(use_with systemd systemd-journal)
+		$(use_with qmi)
+		--without-qrtr # libqrtr-glib not packaged
+		$(use_enable vala)
+	)
+	if use systemd || use elogind; then
+		myconf+=(--with-systemd-suspend-resume)
+	else
+		myconf+=(--without-systemd-suspend-resume)
+	fi
+	gnome2_src_configure "${myconf[@]}"
+}
+
+src_install() {
+	gnome2_src_install
+
+	# Allow users in plugdev group full control over their modem
+	if use policykit; then
+		insinto /usr/share/polkit-1/rules.d/
+		doins "${FILESDIR}"/01-org.freedesktop.ModemManager1.rules
+	fi
+
+	readme.gentoo_create_doc
+
+	newinitd "${FILESDIR}/modemmanager.initd" modemmanager
+}
+
+pkg_postinst() {
+	gnome2_pkg_postinst
+
+	# The polkit rules file moved to /usr/share
+	old_rules="${EROOT}/etc/polkit-1/rules.d/01-org.freedesktop.ModemManager.rules"
+	if [[ -f "${old_rules}" ]]; then
+		case "$(md5sum ${old_rules})" in
+		  c5ff02532cb1da2c7545c3069e5d0992* | 5c50f0dc603c0a56e2851a5ce9389335* )
+			# Automatically delete the old rules.d file if the user did not change it
+			elog
+			elog "Removing old ${old_rules} ..."
+			rm -f "${old_rules}" || eerror "Failed, please remove ${old_rules} manually"
+			;;
+		  * )
+			elog "The ${old_rules}"
+			elog "file moved to /usr/share/polkit-1/rules.d/ in >=modemmanager-0.5.2.0-r2"
+			elog "If you edited ${old_rules}"
+			elog "without changing its behavior, you may want to remove it."
+			;;
+		esac
+	fi
+
+	if ! use udev; then
+		ewarn "You have built ModemManager without udev support. You may have to teach it"
+		ewarn "about your modem port manually."
+	fi
+
+	systemd_reenable ModemManager.service
+
+	readme.gentoo_print_elog
+}