[gentoo-commits] gentoo-x86 commit in net-im/empathy: metadata.xml ChangeLog empathy-2.33.2.ebuild empathy-2.32.2.ebuild

[Gilles Dartiguelongue (eva)]

eva         11/02/27 17:28:32

  Modified:             metadata.xml ChangeLog empathy-2.32.2.ebuild
  Added:                empathy-2.33.2.ebuild
  Log:
  Add <folks-0.3 blocker for empathy-2.32. Bump to 2.33.2, uses new telepathy-logger and folks APIs.
  
  (Portage version: 2.2.0_alpha25/cvs/Linux x86_64, RepoMan options: --force)

Revision  Changes    Path
1.9                  net-im/empathy/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/empathy/metadata.xml?rev=1.9&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/empathy/metadata.xml?rev=1.9&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/empathy/metadata.xml?r1=1.8&r2=1.9

Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-im/empathy/metadata.xml,v
retrieving revision 1.8
retrieving revision 1.9
diff -u -r1.8 -r1.9
--- metadata.xml	4 Dec 2010 19:16:37 -0000	1.8
+++ metadata.xml	27 Feb 2011 17:28:32 -0000	1.9
@@ -4,6 +4,7 @@
 <herd>net-im</herd>
 <herd>gnome</herd>
 <use>
+  <flag name="map">Enable world map support through <pkg>media-libs/libchamplain</pkg>.</flag>
   <flag name="nautilus">Enable nautilus-sendto support</flag>
   <flag name="webkit">Build support for Adium-style HTML-based conversation
 	  window themes using <pkg>net-libs/webkit-gtk</pkg></flag>



1.77                 net-im/empathy/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/empathy/ChangeLog?rev=1.77&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/empathy/ChangeLog?rev=1.77&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/empathy/ChangeLog?r1=1.76&r2=1.77

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-im/empathy/ChangeLog,v
retrieving revision 1.76
retrieving revision 1.77
diff -u -r1.76 -r1.77
--- ChangeLog	27 Feb 2011 15:16:28 -0000	1.76
+++ ChangeLog	27 Feb 2011 17:28:32 -0000	1.77
@@ -1,6 +1,13 @@
 # ChangeLog for net-im/empathy
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-im/empathy/ChangeLog,v 1.76 2011/02/27 15:16:28 eva Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-im/empathy/ChangeLog,v 1.77 2011/02/27 17:28:32 eva Exp $
+
+*empathy-2.33.2 (27 Feb 2011)
+
+  27 Feb 2011; Gilles Dartiguelongue <eva@g.o> empathy-2.32.2.ebuild,
+  +empathy-2.33.2.ebuild, metadata.xml:
+  Add <folks-0.3 blocker for empathy-2.32. Bump to 2.33.2, uses new
+  telepathy-logger and folks APIs.
 
   27 Feb 2011; Gilles Dartiguelongue <eva@g.o> empathy-2.32.2.ebuild:
   Pin libunique dependency to slot 1.



1.11                 net-im/empathy/empathy-2.32.2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/empathy/empathy-2.32.2.ebuild?rev=1.11&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/empathy/empathy-2.32.2.ebuild?rev=1.11&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/empathy/empathy-2.32.2.ebuild?r1=1.10&r2=1.11

Index: empathy-2.32.2.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-im/empathy/empathy-2.32.2.ebuild,v
retrieving revision 1.10
retrieving revision 1.11
diff -u -r1.10 -r1.11
--- empathy-2.32.2.ebuild	27 Feb 2011 15:16:28 -0000	1.10
+++ empathy-2.32.2.ebuild	27 Feb 2011 17:28:32 -0000	1.11
@@ -1,6 +1,6 @@
 # Copyright 1999-2011 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/net-im/empathy/empathy-2.32.2.ebuild,v 1.10 2011/02/27 15:16:28 eva Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-im/empathy/empathy-2.32.2.ebuild,v 1.11 2011/02/27 17:28:32 eva Exp $
 
 EAPI="3"
 GCONF_DEBUG="yes"
@@ -29,6 +29,7 @@
 	>=gnome-base/gnome-keyring-2.26
 	>=net-libs/gnutls-2.8.5
 	>=dev-libs/folks-0.1.15
+	<dev-libs/folks-0.3
 
 	>=dev-libs/libunique-1.1.6:1
 	net-libs/farsight2



1.1                  net-im/empathy/empathy-2.33.2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/empathy/empathy-2.33.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/empathy/empathy-2.33.2.ebuild?rev=1.1&content-type=text/plain

Index: empathy-2.33.2.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-im/empathy/empathy-2.33.2.ebuild,v 1.1 2011/02/27 17:28:32 eva Exp $

EAPI="3"
GCONF_DEBUG="yes"
PYTHON_DEPEND="2:2.4"

inherit eutils gnome2 multilib python

DESCRIPTION="Telepathy client and library using GTK+"
HOMEPAGE="http://live.gnome.org/Empathy"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~ia64 ~ppc ~sparc ~x86"
# FIXME: Add location support once geoclue stops being idiotic with automagic deps
IUSE="eds map nautilus networkmanager spell test webkit"

# FIXME: libnotify & libcanberra hard deps
# gst-plugins-bad is required for the valve plugin. This should move to good
# eventually at which point the dep can be dropped
RDEPEND=">=dev-libs/glib-2.27.2:2
	>=x11-libs/gtk+-2.22:2
	>=dev-libs/dbus-glib-0.51
	>=net-libs/telepathy-glib-0.13.12
	>=media-libs/libcanberra-0.4[gtk]
	>=x11-libs/libnotify-0.7
	>=gnome-base/gnome-keyring-2.26
	>=net-libs/gnutls-2.8.5
	>=dev-libs/folks-0.3.5

	>=dev-libs/libunique-1.1.6:1
	net-libs/farsight2
	media-libs/gstreamer:0.10
	media-libs/gst-plugins-base:0.10
	media-libs/gst-plugins-bad
	media-plugins/gst-plugins-gconf
	>=net-libs/telepathy-farsight-0.0.14
	dev-libs/libxml2
	x11-libs/libX11
	net-voip/telepathy-connection-managers
	>=net-im/telepathy-logger-0.2.0

	eds? ( >=gnome-extra/evolution-data-server-1.2 )
	map? (
		>=media-libs/libchamplain-0.7.1:0.8[gtk]
		>=media-libs/clutter-gtk-0.10:0.10 )
	nautilus? ( >=gnome-extra/nautilus-sendto-2.31.7 )
	networkmanager? ( >=net-misc/networkmanager-0.7 )
	spell? (
		>=app-text/enchant-1.2
		>=app-text/iso-codes-0.35 )
	webkit? ( >=net-libs/webkit-gtk-1.1.15 )
"
DEPEND="${RDEPEND}
	app-text/scrollkeeper
	>=app-text/gnome-doc-utils-0.17.3
	>=dev-util/intltool-0.35.0
	>=dev-util/pkgconfig-0.16
	test? (
		sys-apps/grep
		>=dev-libs/check-0.9.4 )
	dev-libs/libxslt
"
PDEPEND=">=net-im/telepathy-mission-control-5"

pkg_setup() {
	DOCS="CONTRIBUTORS AUTHORS ChangeLog NEWS README"

	# call support needs unreleased telepathy-farstream
	G2CONF="${G2CONF}
		--enable-silent-rules
		--disable-coding-style-checks
		--disable-schemas-compile
		--disable-static
		--disable-call
		--disable-location
		--disable-control-center-embedding
		--disable-Werror
		$(use_enable debug)
		$(use_with eds)
		$(use_enable map)
		$(use_enable nautilus nautilus-sendto)
		$(use_with networkmanager connectivity nm)
		$(use_enable spell)
		$(use_enable webkit)"

	# Build time python tools needs python2
	python_set_active_version 2
}

src_prepare() {
	gnome2_src_prepare
	python_convert_shebangs -r 2 .
}

src_test() {
	unset DBUS_SESSION_BUS_ADDRESS
	emake check || die "emake check failed."
}

src_install() {
	gnome2_pkg_postinst
	# nautilus-sendto plugin doesn't need this
	find "${ED}" -name "*.la" -delete
}

pkg_postinst() {
	gnome2_pkg_postinst
	elog "Empathy needs telepathy's connection managers to use any IM protocol."
	elog "See the USE flags on net-voip/telepathy-connection-managers"
	elog "to install them."
}