[gentoo-commits] repo/gentoo:master commit in: dev-python/uranium/

[Dennis Lamm]

commit:     767f013a8bbccfcdbb449cc6da6a34bdba3d4000
Author:     Dennis Lamm <expeditioneer <AT> gentoo <DOT> org>
AuthorDate: Sun Nov 29 09:04:06 2020 +0000
Commit:     Dennis Lamm <expeditioneer <AT> gentoo <DOT> org>
CommitDate: Mon Nov 30 18:37:40 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=767f013a

dev-python/uranium: bump to 4.8.0

Signed-off-by: Dennis Lamm <expeditoneer <AT> gentoo.org>
Signed-off-by: Dennis Lamm <expeditioneer <AT> gentoo.org>

 dev-python/uranium/Manifest             |  1 +
 dev-python/uranium/uranium-4.8.0.ebuild | 96 +++++++++++++++++++++++++++++++++
 2 files changed, 97 insertions(+)

diff --git a/dev-python/uranium/Manifest b/dev-python/uranium/Manifest
index 6e63bbf18ee..3a1277f6a40 100644
--- a/dev-python/uranium/Manifest
+++ b/dev-python/uranium/Manifest
@@ -1,2 +1,3 @@
 DIST uranium-4.6.1.tar.gz 1013314 BLAKE2B 2a89eb1c4ffab35879eea9a681ea20e9cc5f78736d9c8bda5bf33baf5ef6d3f6418fd1f4b779738d644afd2d553d500c4892559ae402eeab0c38a4d95b295cf5 SHA512 ba7ed12d507fb1bd08fc0e77285933802a31b63d09f2dd0c7329e5644f82e6372fa11a1bbc28f3f1928ae0acfb3cb0afdeedf8e90e619c484fd5f623f8af722a
 DIST uranium-4.7.0.tar.gz 1021541 BLAKE2B 2a2e354def88764801f275751aaf7643c9f4ca6329c2c302d87b3d617d0e93921d0aef20b0c25c9b0a082a836f7d0cca962dfedaa0298fcf943b1a0b683e0e28 SHA512 e049fff57823107785b418a368d6c6c399775c35ffad90831c77643dee060be2ab13ad8871b11f8d59d2a090a1d26786f4cf39a5a731b616a1b08a8ae5dea996
+DIST uranium-4.8.0.tar.gz 1027286 BLAKE2B 5e068255918ca3a6125c308a64d47fab30260aa475505edad2abda664d2c2db7d821d4219ff682d4de90e16de2e36d257410a44f2752c733994739ca160e55b0 SHA512 a2cb923d703e626760c885ceb657566abfa5662f63729fef0b5cdf408da2ed3c23fefcd173b8af529ee79c2384505b2558379b82ba2cfd7a2d2291fe723ddbbd

diff --git a/dev-python/uranium/uranium-4.8.0.ebuild b/dev-python/uranium/uranium-4.8.0.ebuild
new file mode 100644
index 00000000000..1f9643331be
--- /dev/null
+++ b/dev-python/uranium/uranium-4.8.0.ebuild
@@ -0,0 +1,96 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DISTUTILS_SINGLE_IMPL=1
+PYTHON_COMPAT=(python3_{6..8})
+
+inherit cmake distutils-r1
+
+MY_PN="Uranium"
+
+DESCRIPTION="A Python framework for building 3D printing related applications"
+HOMEPAGE="https://github.com/Ultimaker/Uranium"
+SRC_URI="https://github.com/Ultimaker/${MY_PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="LGPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="debug doc test"
+
+BDEPEND="${PYTHON_DEPS}
+	sys-devel/gettext
+	doc? ( app-doc/doxygen[dot] )
+	test? (
+		$(python_gen_cond_dep '
+			dev-python/pytest[${PYTHON_USEDEP}]
+			dev-python/mypy[${PYTHON_USEDEP}]
+		')
+	)"
+
+DEPEND="${PYTHON_DEPS}
+	~dev-libs/libarcus-${PV}:=[python,${PYTHON_SINGLE_USEDEP}]
+	$(python_gen_cond_dep '
+		dev-python/PyQt5[${PYTHON_USEDEP},declarative,network,svg]
+		dev-python/numpy[${PYTHON_USEDEP}]
+		>=dev-python/scipy-1.1[${PYTHON_USEDEP}]
+		sci-libs/shapely[${PYTHON_USEDEP}]
+	')"
+
+RDEPEND="${DEPEND}
+	dev-qt/qtquickcontrols:5
+	dev-qt/qtquickcontrols2:5"
+
+DOCS=( README.md )
+
+S="${WORKDIR}/${MY_PN}-${PV}"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	python_fix_shebang .
+
+	cmake_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DCURA_BINARY_DATA_DIRECTORY:STRING="/usr/share/cura/"
+		-DGETTEXT_MSGINIT_EXECUTABLE="msginit"
+	)
+
+	if ! use debug; then
+		sed -i -e 's logging.DEBUG logging.ERROR g' \
+		 plugins/ConsoleLogger/ConsoleLogger.py \
+		 plugins/FileLogger/FileLogger.py || die
+	fi
+
+	sed -i \
+		-e "s/find_package(PythonInterp 3 REQUIRED/find_package(Python3 ${EPYTHON##python} EXACT REQUIRED COMPONENTS Interpreter/g" \
+		CMakeLists.txt cmake/UraniumPluginInstall.cmake
+
+	sed -i \
+		-e "s/find_package(Python3 REQUIRED/find_package(Python3 ${EPYTHON##python} EXACT REQUIRED/g" \
+		-e 's/set(Python3_EXECUTABLE ${PYTHON_EXECUTABLE})//g' \
+		cmake/UraniumPluginInstall.cmake
+
+	sed -i \
+		-e "s lib\${LIB_SUFFIX}/python\${PYTHON_VERSION_MAJOR}.\${PYTHON_VERSION_MINOR}/site-packages $(python_get_sitedir) g" \
+		-e 's cmake-${CMAKE_MAJOR_VERSION}.${CMAKE_MINOR_VERSION} cmake g' \
+		CMakeLists.txt
+
+	cmake_src_configure
+}
+
+src_compile() {
+	cmake_src_compile
+
+	use doc && cmake_src_compile doc
+}
+
+src_install() {
+	cmake_src_install
+
+	python_optimize "${ED}"/usr
+}