[gentoo-commits] repo/gentoo:master commit in: games-puzzle/gfifteen/

[Ionen Wolkens]

commit:     61d64cb25affe8e5fcebf4a032a4a4c680f37846
Author:     Ionen Wolkens <ionen <AT> gentoo <DOT> org>
AuthorDate: Tue Jul 13 13:39:04 2021 +0000
Commit:     Ionen Wolkens <ionen <AT> gentoo <DOT> org>
CommitDate: Tue Jul 13 16:07:43 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=61d64cb2

games-puzzle/gfifteen: EAPI 6->8, tighten deps, remove homepage

Non-https HOMEPAGE redirects to another (wrong) site, and
https is unresponsive. Does not seem to be a replacement.

Signed-off-by: Ionen Wolkens <ionen <AT> gentoo.org>

 games-puzzle/gfifteen/gfifteen-1.0.3-r1.ebuild | 49 --------------------------
 games-puzzle/gfifteen/gfifteen-1.0.3-r2.ebuild | 39 ++++++++++++++++++++
 2 files changed, 39 insertions(+), 49 deletions(-)

diff --git a/games-puzzle/gfifteen/gfifteen-1.0.3-r1.ebuild b/games-puzzle/gfifteen/gfifteen-1.0.3-r1.ebuild
deleted file mode 100644
index 863fc84ff7f..00000000000
--- a/games-puzzle/gfifteen/gfifteen-1.0.3-r1.ebuild
+++ /dev/null
@@ -1,49 +0,0 @@
-# Copyright 1999-2018 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=6
-inherit desktop gnome2-utils
-
-DESCRIPTION="Graphical implementation of the sliding puzzle game fifteen"
-HOMEPAGE="https://frigidcode.com/code/gfifteen/"
-SRC_URI="https://frigidcode.com/code/gfifteen/${P}.tar.gz"
-
-LICENSE="GPL-3"
-SLOT="0"
-KEYWORDS="~amd64 ~x86"
-IUSE=""
-
-RDEPEND="x11-libs/gtk+:3"
-DEPEND="${RDEPEND}
-	virtual/pkgconfig
-"
-
-src_prepare() {
-	default
-	# make it compile against newer gtk+:3 (bug #536994)
-	sed -i \
-		-e 's/-DGTK_DISABLE_DEPRECATED=1 //' \
-		Makefile.in || die
-}
-
-src_configure() {
-	econf --disable-assembly
-}
-
-src_install() {
-	default
-	doicon -s scalable ${PN}.svg
-	domenu gfifteen.desktop
-}
-
-pkg_preinst() {
-	gnome2_icon_savelist
-}
-
-pkg_postinst() {
-	gnome2_icon_cache_update
-}
-
-pkg_postrm() {
-	gnome2_icon_cache_update
-}

diff --git a/games-puzzle/gfifteen/gfifteen-1.0.3-r2.ebuild b/games-puzzle/gfifteen/gfifteen-1.0.3-r2.ebuild
new file mode 100644
index 00000000000..d5c8a049704
--- /dev/null
+++ b/games-puzzle/gfifteen/gfifteen-1.0.3-r2.ebuild
@@ -0,0 +1,39 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit desktop
+
+DESCRIPTION="Graphical implementation of the sliding puzzle game fifteen"
+HOMEPAGE="https://wiki.gentoo.org/wiki/No_homepage"
+SRC_URI="mirror://gentoo/${P}.tar.gz"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="
+	dev-libs/glib:2
+	x11-libs/cairo
+	x11-libs/gtk+:3"
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig"
+
+src_prepare() {
+	default
+
+	# allow using newer gtk+:3 (bug #536994)
+	sed -i 's/-DGTK_DISABLE_DEPRECATED=1 //' Makefile.in || die
+}
+
+src_configure() {
+	econf --disable-assembly
+}
+
+src_install() {
+	default
+
+	doicon ${PN}.svg
+	domenu gfifteen.desktop
+}