[gentoo-commits] repo/gentoo:master commit in: www-client/chromium/

[Mike Gilbert]

commit:     54660b6e0b4766d8150b544b969eef9231c3489f
Author:     Mike Gilbert <floppym <AT> gentoo <DOT> org>
AuthorDate: Sat Sep 26 15:51:24 2015 +0000
Commit:     Mike Gilbert <floppym <AT> gentoo <DOT> org>
CommitDate: Sat Sep 26 15:51:24 2015 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=54660b6e

www-client/chromium: Stable bump to 45.0.2454.101

Package-Manager: portage-2.2.21_p119

 www-client/chromium/Manifest                      |   1 +
 www-client/chromium/chromium-45.0.2454.101.ebuild | 631 ++++++++++++++++++++++
 2 files changed, 632 insertions(+)

diff --git a/www-client/chromium/Manifest b/www-client/chromium/Manifest
index 5d02d4a..49fcd4e 100644
--- a/www-client/chromium/Manifest
+++ b/www-client/chromium/Manifest
@@ -1,3 +1,4 @@
+DIST chromium-45.0.2454.101-lite.tar.xz 242364644 SHA256 014720920ad049e354aa190eba66badb4eef106ad1064209141d3f5272a308fa SHA512 e43f9ba6424370258eecbeba53275553988453ba1e5d665857c5cae9a7238a428e24d2462a33831e83108d17c4d170747f234403ab94251097ed6a4b5b151edd WHIRLPOOL 5977fef019ada796960582ac175f013b83d666d215e02fbba82556bfe76281fff684a77974832be9cb5c81992a267ecefbe0da192fdb534c59786275b3560a62
 DIST chromium-45.0.2454.85-lite.tar.xz 242569440 SHA256 fafb4792c69c235d6ea85e904df68a64c51783cb338b783a1092b4ea6c888e71 SHA512 04f482ef18cddaf140224a98189ebd565416e3fe617877d58b2e691fb6030a3c9248720efcb7285cd18a034c345f9a65c677489d8a49f1ac95deafecb9b7d82a WHIRLPOOL 86b382b4dd2406559cef76ae260fcfe26e376bd957be3381b9822f706e8a5fb0ac7240fb00d64858ee1262eec17fadd253acae2b8a9318d3d996fb5d596de665
 DIST chromium-46.0.2490.13-lite.tar.xz 261760812 SHA256 8b582b05a61b207ebec6a65577e413c00e5f7d330ec1adb24d9681d14640fc88 SHA512 d73f10a8521183ec8253dad8e82c8b6357c080cb76b91b8a8eb69cce05225dd843edf01c04a7478e04a7da22330332832f9c7a63f59346333eda83b9133c4213 WHIRLPOOL 098ec84c56ac43800bd3f5d5f60dcdc167b045b1cf3736bca72b21e1ffbf33937541f810cc2e976f6a86dca0035c4b59000a5532f4974ec2cee9156acd7c488d
 DIST chromium-46.0.2490.22-lite.tar.xz 261632508 SHA256 23a7448cfca032c240262a8d5760f23d9e89bf783ef54467353297856620edb6 SHA512 8d4f8c4cb2c7a4c3c9fb557b4fb2d34c5d7313a82c84fce340254ae59b5fcbc21b2d7b7723d8dd3f7b717175ac12e87373d0889397f01ce189c5718a7deb6de4 WHIRLPOOL dc1fee05d0acc46f9842281e475d1f9d006216c8d8e264ea3eecee63eb14054ff94ed6dd15e6d690305b08670516888a3361f5a3be8f0189c41472d77f0172bb

diff --git a/www-client/chromium/chromium-45.0.2454.101.ebuild b/www-client/chromium/chromium-45.0.2454.101.ebuild
new file mode 100644
index 0000000..a640c07
--- /dev/null
+++ b/www-client/chromium/chromium-45.0.2454.101.ebuild
@@ -0,0 +1,631 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="5"
+PYTHON_COMPAT=( python2_7 )
+
+CHROMIUM_LANGS="am ar bg bn ca cs da de el en_GB es es_LA et fa fi fil fr gu he
+	hi hr hu id it ja kn ko lt lv ml mr ms nb nl pl pt_BR pt_PT ro ru sk sl sr
+	sv sw ta te th tr uk vi zh_CN zh_TW"
+
+inherit check-reqs chromium eutils flag-o-matic multilib multiprocessing pax-utils \
+	portability python-any-r1 readme.gentoo toolchain-funcs versionator virtualx
+
+DESCRIPTION="Open-source version of Google Chrome web browser"
+HOMEPAGE="http://chromium.org/"
+SRC_URI="https://commondatastorage.googleapis.com/chromium-browser-official/${P}-lite.tar.xz"
+
+LICENSE="BSD hotwording? ( no-source-code )"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~x86"
+IUSE="cups gnome gnome-keyring hidpi hotwording kerberos neon pic +proprietary-codecs pulseaudio selinux +tcmalloc"
+RESTRICT="proprietary-codecs? ( bindist )"
+
+# Native Client binaries are compiled with different set of flags, bug #452066.
+QA_FLAGS_IGNORED=".*\.nexe"
+
+# Native Client binaries may be stripped by the build system, which uses the
+# right tools for it, bug #469144 .
+QA_PRESTRIPPED=".*\.nexe"
+
+RDEPEND=">=app-accessibility/speech-dispatcher-0.8:=
+	app-arch/bzip2:=
+	app-arch/snappy:=
+	cups? ( >=net-print/cups-1.3.11:= )
+	>=dev-libs/elfutils-0.149
+	dev-libs/expat:=
+	dev-libs/glib:=
+	>=dev-libs/icu-55.1:=
+	>=dev-libs/jsoncpp-0.5.0-r1:=
+	>=dev-libs/libevent-1.4.13:=
+	dev-libs/libxml2:=[icu]
+	dev-libs/libxslt:=
+	dev-libs/nspr:=
+	>=dev-libs/nss-3.14.3:=
+	dev-libs/re2:=
+	gnome? ( >=gnome-base/gconf-2.24.0:= )
+	gnome-keyring? ( >=gnome-base/libgnome-keyring-3.12:= )
+	>=media-libs/alsa-lib-1.0.19:=
+	media-libs/flac:=
+	media-libs/fontconfig:=
+	media-libs/freetype:=
+	media-libs/harfbuzz:=[icu(+)]
+	media-libs/libexif:=
+	>=media-libs/libjpeg-turbo-1.2.0-r1:=
+	media-libs/libpng:0=
+	>=media-libs/libwebp-0.4.0:=
+	media-libs/speex:=
+	pulseaudio? ( media-sound/pulseaudio:= )
+	sys-apps/dbus:=
+	sys-apps/pciutils:=
+	>=sys-libs/libcap-2.22:=
+	sys-libs/zlib:=[minizip]
+	virtual/udev
+	x11-libs/cairo:=
+	x11-libs/gdk-pixbuf:=
+	x11-libs/gtk+:2=
+	x11-libs/libdrm
+	x11-libs/libX11:=
+	x11-libs/libXcomposite:=
+	x11-libs/libXcursor:=
+	x11-libs/libXdamage:=
+	x11-libs/libXext:=
+	x11-libs/libXfixes:=
+	>=x11-libs/libXi-1.6.0:=
+	x11-libs/libXinerama:=
+	x11-libs/libXrandr:=
+	x11-libs/libXrender:=
+	x11-libs/libXScrnSaver:=
+	x11-libs/libXtst:=
+	x11-libs/pango:=
+	kerberos? ( virtual/krb5 )"
+DEPEND="${RDEPEND}
+	!arm? (
+		dev-lang/yasm
+	)
+	dev-lang/perl
+	dev-perl/JSON
+	>=dev-util/gperf-3.0.3
+	dev-util/ninja
+	sys-apps/hwids[usb(+)]
+	>=sys-devel/bison-2.4.3
+	sys-devel/flex
+	virtual/pkgconfig"
+
+# For nvidia-drivers blocker, see bug #413637 .
+RDEPEND+="
+	!=www-client/chromium-9999
+	!<www-plugins/chrome-binary-plugins-37
+	x11-misc/xdg-utils
+	virtual/opengl
+	virtual/ttf-fonts
+	selinux? ( sec-policy/selinux-chromium )
+	tcmalloc? ( !<x11-drivers/nvidia-drivers-331.20 )"
+
+# Python dependencies. The DEPEND part needs to be kept in sync
+# with python_check_deps.
+DEPEND+=" $(python_gen_any_dep '
+	dev-python/beautifulsoup:python-2[${PYTHON_USEDEP}]
+	dev-python/jinja[${PYTHON_USEDEP}]
+	dev-python/ply[${PYTHON_USEDEP}]
+	dev-python/simplejson[${PYTHON_USEDEP}]
+')"
+python_check_deps() {
+	has_version "dev-python/beautifulsoup:python-2[${PYTHON_USEDEP}]" && \
+		has_version "dev-python/jinja[${PYTHON_USEDEP}]" && \
+		has_version "dev-python/ply[${PYTHON_USEDEP}]" && \
+		has_version "dev-python/simplejson[${PYTHON_USEDEP}]"
+}
+
+if ! has chromium_pkg_die ${EBUILD_DEATH_HOOKS}; then
+	EBUILD_DEATH_HOOKS+=" chromium_pkg_die";
+fi
+
+DISABLE_AUTOFORMATTING="yes"
+DOC_CONTENTS="
+Some web pages may require additional fonts to display properly.
+Try installing some of the following packages if some characters
+are not displayed properly:
+- media-fonts/arphicfonts
+- media-fonts/bitstream-cyberbit
+- media-fonts/droid
+- media-fonts/ipamonafont
+- media-fonts/ja-ipafonts
+- media-fonts/takao-fonts
+- media-fonts/wqy-microhei
+- media-fonts/wqy-zenhei
+
+Depending on your desktop environment, you may need
+to install additional packages to get icons on the Downloads page.
+
+For KDE, the required package is kde-apps/oxygen-icons.
+
+For other desktop environments, try one of the following:
+- x11-themes/gnome-icon-theme
+- x11-themes/tango-icon-theme
+"
+
+pkg_pretend() {
+	if [[ $(tc-getCC)$ == *gcc* ]] && \
+		[[ $(gcc-major-version)$(gcc-minor-version) -lt 48 ]]; then
+		die 'At least gcc 4.8 is required, see bugs: #535730, #525374, #518668.'
+	fi
+
+	# Check build requirements, bug #541816 and bug #471810 .
+	CHECKREQS_MEMORY="3G"
+	CHECKREQS_DISK_BUILD="5G"
+	eshopts_push -s extglob
+	if is-flagq '-g?(gdb)?([1-9])'; then
+		CHECKREQS_DISK_BUILD="25G"
+	fi
+	eshopts_pop
+	check-reqs_pkg_pretend
+}
+
+pkg_setup() {
+	if [[ "${SLOT}" == "0" ]]; then
+		CHROMIUM_SUFFIX=""
+	else
+		CHROMIUM_SUFFIX="-${SLOT}"
+	fi
+	CHROMIUM_HOME="/usr/$(get_libdir)/chromium-browser${CHROMIUM_SUFFIX}"
+
+	# Make sure the build system will use the right python, bug #344367.
+	python-any-r1_pkg_setup
+
+	chromium_suid_sandbox_check_kernel_config
+}
+
+src_prepare() {
+	# if ! use arm; then
+	#	mkdir -p out/Release/gen/sdk/toolchain || die
+	#	# Do not preserve SELinux context, bug #460892 .
+	#	cp -a --no-preserve=context /usr/$(get_libdir)/nacl-toolchain-newlib \
+	#		out/Release/gen/sdk/toolchain/linux_x86_newlib || die
+	#	touch out/Release/gen/sdk/toolchain/linux_x86_newlib/stamp.untar || die
+	# fi
+
+	epatch "${FILESDIR}/${PN}-system-jinja-r7.patch"
+	epatch "${FILESDIR}/${PN}-tracing-r0.patch"
+
+	epatch_user
+
+	# Remove most bundled libraries. Some are still needed.
+	build/linux/unbundle/remove_bundled_libraries.py \
+		'base/third_party/dmg_fp' \
+		'base/third_party/dynamic_annotations' \
+		'base/third_party/icu' \
+		'base/third_party/nspr' \
+		'base/third_party/superfasthash' \
+		'base/third_party/symbolize' \
+		'base/third_party/valgrind' \
+		'base/third_party/xdg_mime' \
+		'base/third_party/xdg_user_dirs' \
+		'breakpad/src/third_party/curl' \
+		'chrome/third_party/mozilla_security_manager' \
+		'courgette/third_party' \
+		'crypto/third_party/nss' \
+		'net/third_party/mozilla_security_manager' \
+		'net/third_party/nss' \
+		'third_party/WebKit' \
+		'third_party/analytics' \
+		'third_party/angle' \
+		'third_party/angle/src/third_party/compiler' \
+		'third_party/boringssl' \
+		'third_party/brotli' \
+		'third_party/cacheinvalidation' \
+		'third_party/cld_2' \
+		'third_party/cros_system_api' \
+		'third_party/cython/python_flags.py' \
+		'third_party/devscripts' \
+		'third_party/dom_distiller_js' \
+		'third_party/dom_distiller_js/dist/proto_gen/third_party/dom_distiller_js' \
+		'third_party/ffmpeg' \
+		'third_party/fips181' \
+		'third_party/flot' \
+		'third_party/google_input_tools' \
+		'third_party/google_input_tools/third_party/closure_library' \
+		'third_party/google_input_tools/third_party/closure_library/third_party/closure' \
+		'third_party/hunspell' \
+		'third_party/iccjpeg' \
+		'third_party/jstemplate' \
+		'third_party/khronos' \
+		'third_party/leveldatabase' \
+		'third_party/libXNVCtrl' \
+		'third_party/libaddressinput' \
+		'third_party/libjingle' \
+		'third_party/libphonenumber' \
+		'third_party/libsecret' \
+		'third_party/libsrtp' \
+		'third_party/libudev' \
+		'third_party/libusb' \
+		'third_party/libvpx' \
+		'third_party/libvpx/source/libvpx/third_party/x86inc' \
+		'third_party/libxml/chromium' \
+		'third_party/libyuv' \
+		'third_party/lss' \
+		'third_party/lzma_sdk' \
+		'third_party/mesa' \
+		'third_party/modp_b64' \
+		'third_party/mojo' \
+		'third_party/mt19937ar' \
+		'third_party/npapi' \
+		'third_party/openmax_dl' \
+		'third_party/opus' \
+		'third_party/ots' \
+		'third_party/pdfium' \
+		'third_party/pdfium/third_party/agg23' \
+		'third_party/pdfium/third_party/base' \
+		'third_party/pdfium/third_party/bigint' \
+		'third_party/pdfium/third_party/freetype' \
+		'third_party/pdfium/third_party/lcms2-2.6' \
+		'third_party/pdfium/third_party/libjpeg' \
+		'third_party/pdfium/third_party/libopenjpeg20' \
+		'third_party/pdfium/third_party/zlib_v128' \
+		'third_party/polymer' \
+		'third_party/protobuf' \
+		'third_party/qcms' \
+		'third_party/readability' \
+		'third_party/sfntly' \
+		'third_party/skia' \
+		'third_party/smhasher' \
+		'third_party/sqlite' \
+		'third_party/tcmalloc' \
+		'third_party/trace-viewer' \
+		'third_party/trace-viewer/tracing/third_party/components/polymer' \
+		'third_party/trace-viewer/tracing/third_party/d3' \
+		'third_party/trace-viewer/tracing/third_party/gl-matrix' \
+		'third_party/trace-viewer/tracing/third_party/jszip' \
+		'third_party/trace-viewer/tracing/third_party/tvcm' \
+		'third_party/trace-viewer/tracing/third_party/tvcm/third_party/beautifulsoup/polymer_soup.py' \
+		'third_party/trace-viewer/tracing/third_party/tvcm/third_party/rcssmin' \
+		'third_party/trace-viewer/tracing/third_party/tvcm/third_party/rjsmin' \
+		'third_party/usrsctp' \
+		'third_party/web-animations-js' \
+		'third_party/webdriver' \
+		'third_party/webrtc' \
+		'third_party/widevine' \
+		'third_party/x86inc' \
+		'third_party/zlib/google' \
+		'url/third_party/mozilla' \
+		'v8/src/third_party/fdlibm' \
+		'v8/src/third_party/valgrind' \
+		--do-remove || die
+}
+
+src_configure() {
+	local myconf=""
+
+	# Never tell the build system to "enable" SSE2, it has a few unexpected
+	# additions, bug #336871.
+	myconf+=" -Ddisable_sse2=1"
+
+	# Disable nacl, we can't build without pnacl (http://crbug.com/269560).
+	myconf+=" -Ddisable_nacl=1"
+
+	# Disable glibc Native Client toolchain, we don't need it (bug #417019).
+	# myconf+=" -Ddisable_glibc=1"
+
+	# TODO: also build with pnacl
+	# myconf+=" -Ddisable_pnacl=1"
+
+	# It would be awkward for us to tar the toolchain and get it untarred again
+	# during the build.
+	# myconf+=" -Ddisable_newlib_untar=1"
+
+	# Make it possible to remove third_party/adobe.
+	echo > "${T}/flapper_version.h" || die
+	myconf+=" -Dflapper_version_h_file=${T}/flapper_version.h"
+
+	# Use system-provided libraries.
+	# TODO: use_system_hunspell (upstream changes needed).
+	# TODO: use_system_libsrtp (bug #459932).
+	# TODO: use_system_libusb (http://crbug.com/266149).
+	# TODO: use_system_libvpx (http://crbug.com/494939).
+	# TODO: use_system_opus (https://code.google.com/p/webrtc/issues/detail?id=3077).
+	# TODO: use_system_protobuf (bug #525560).
+	# TODO: use_system_ssl (http://crbug.com/58087).
+	# TODO: use_system_sqlite (http://crbug.com/22208).
+	myconf+="
+		-Duse_system_bzip2=1
+		-Duse_system_flac=1
+		-Duse_system_harfbuzz=1
+		-Duse_system_icu=1
+		-Duse_system_jsoncpp=1
+		-Duse_system_libevent=1
+		-Duse_system_libjpeg=1
+		-Duse_system_libpng=1
+		-Duse_system_libwebp=1
+		-Duse_system_libxml=1
+		-Duse_system_libxslt=1
+		-Duse_system_minizip=1
+		-Duse_system_nspr=1
+		-Duse_system_re2=1
+		-Duse_system_snappy=1
+		-Duse_system_speex=1
+		-Duse_system_xdg_utils=1
+		-Duse_system_zlib=1"
+
+	# Needed for system icu - we don't need additional data files.
+	myconf+=" -Dicu_use_data_file_flag=0"
+
+	# TODO: patch gyp so that this arm conditional is not needed.
+	if ! use arm; then
+		myconf+="
+			-Duse_system_yasm=1"
+	fi
+
+	# Optional dependencies.
+	# TODO: linux_link_kerberos, bug #381289.
+	myconf+="
+		$(gyp_use cups)
+		$(gyp_use gnome use_gconf)
+		$(gyp_use gnome-keyring use_gnome_keyring)
+		$(gyp_use gnome-keyring linux_link_gnome_keyring)
+		$(gyp_use hidpi enable_hidpi)
+		$(gyp_use hotwording enable_hotwording)
+		$(gyp_use kerberos)
+		$(gyp_use pulseaudio)
+		$(gyp_use tcmalloc use_allocator tcmalloc none)"
+
+	# Use explicit library dependencies instead of dlopen.
+	# This makes breakages easier to detect by revdep-rebuild.
+	myconf+="
+		-Dlinux_link_gsettings=1
+		-Dlinux_link_libpci=1
+		-Dlinux_link_libspeechd=1
+		-Dlibspeechd_h_prefix=speech-dispatcher/"
+
+	# TODO: use the file at run time instead of effectively compiling it in.
+	myconf+="
+		-Dusb_ids_path=/usr/share/misc/usb.ids"
+
+	# Save space by removing DLOG and DCHECK messages (about 6% reduction).
+	myconf+="
+		-Dlogging_like_official_build=1"
+
+	if [[ $(tc-getCC) == *clang* ]]; then
+		myconf+=" -Dclang=1"
+	else
+		myconf+=" -Dclang=0"
+	fi
+
+	# Never use bundled gold binary. Disable gold linker flags for now.
+	# Do not use bundled clang.
+	myconf+="
+		-Dclang_use_chrome_plugins=0
+		-Dhost_clang=0
+		-Dlinux_use_bundled_binutils=0
+		-Dlinux_use_bundled_gold=0
+		-Dlinux_use_gold_flags=0"
+
+	ffmpeg_branding="$(usex proprietary-codecs Chrome Chromium)"
+	myconf+=" -Dproprietary_codecs=1 -Dffmpeg_branding=${ffmpeg_branding}"
+
+	# Set up Google API keys, see http://www.chromium.org/developers/how-tos/api-keys .
+	# Note: these are for Gentoo use ONLY. For your own distribution,
+	# please get your own set of keys. Feel free to contact chromium@g.o
+	# for more info.
+	myconf+=" -Dgoogle_api_key=AIzaSyDEAOvatFo0eTgsV_ZlEzx0ObmepsMzfAc
+		-Dgoogle_default_client_id=329227923882.apps.googleusercontent.com
+		-Dgoogle_default_client_secret=vgKG0NNv7GoDpbtoFNLxCUXu"
+
+	local myarch="$(tc-arch)"
+	if [[ $myarch = amd64 ]] ; then
+		target_arch=x64
+		ffmpeg_target_arch=x64
+	elif [[ $myarch = x86 ]] ; then
+		target_arch=ia32
+		ffmpeg_target_arch=ia32
+	elif [[ $myarch = arm ]] ; then
+		target_arch=arm
+		ffmpeg_target_arch=$(usex neon arm-neon arm)
+		# TODO: re-enable NaCl (NativeClient).
+		local CTARGET=${CTARGET:-${CHOST}}
+		if [[ $(tc-is-softfloat) == "no" ]]; then
+
+			myconf+=" -Darm_float_abi=hard"
+		fi
+		filter-flags "-mfpu=*"
+		use neon || myconf+=" -Darm_fpu=${ARM_FPU:-vfpv3-d16}"
+
+		if [[ ${CTARGET} == armv[78]* ]]; then
+			myconf+=" -Darmv7=1"
+		else
+			myconf+=" -Darmv7=0"
+		fi
+		myconf+=" -Dsysroot=
+			$(gyp_use neon arm_neon)
+			-Ddisable_nacl=1"
+	else
+		die "Failed to determine target arch, got '$myarch'."
+	fi
+
+	myconf+=" -Dtarget_arch=${target_arch}"
+
+	# Make sure that -Werror doesn't get added to CFLAGS by the build system.
+	# Depending on GCC version the warnings are different and we don't want
+	# the build to fail because of that.
+	myconf+=" -Dwerror="
+
+	# Disable fatal linker warnings, bug 506268.
+	myconf+=" -Ddisable_fatal_linker_warnings=1"
+
+	# Avoid CFLAGS problems, bug #352457, bug #390147.
+	if ! use custom-cflags; then
+		replace-flags "-Os" "-O2"
+		strip-flags
+
+		# Prevent linker from running out of address space, bug #471810 .
+		if use x86; then
+			filter-flags "-g*"
+		fi
+
+		# Prevent libvpx build failures. Bug 530248, 544702, 546984.
+		if [[ ${myarch} == amd64 || ${myarch} == x86 ]]; then
+			filter-flags -mno-mmx -mno-sse2 -mno-ssse3 -mno-sse4.1 -mno-avx -mno-avx2
+		fi
+	fi
+
+	# Make sure the build system will use the right tools, bug #340795.
+	tc-export AR CC CXX RANLIB
+
+	# Tools for building programs to be executed on the build system, bug #410883.
+	export AR_host=$(tc-getBUILD_AR)
+	export CC_host=$(tc-getBUILD_CC)
+	export CXX_host=$(tc-getBUILD_CXX)
+	export LD_host=${CXX_host}
+
+	# Bug 491582.
+	export TMPDIR="${WORKDIR}/temp"
+	mkdir -m 755 "${TMPDIR}" || die
+
+	local build_ffmpeg_args=""
+	if use pic && [[ "${ffmpeg_target_arch}" == "ia32" ]]; then
+		build_ffmpeg_args+=" --disable-asm"
+	fi
+
+	# Re-configure bundled ffmpeg. See bug #491378 for example reasons.
+	einfo "Configuring bundled ffmpeg..."
+	pushd third_party/ffmpeg > /dev/null || die
+	chromium/scripts/build_ffmpeg.py linux ${ffmpeg_target_arch} \
+		--branding ${ffmpeg_branding} -- ${build_ffmpeg_args} || die
+	chromium/scripts/copy_config.sh || die
+	chromium/scripts/generate_gyp.py || die
+	popd > /dev/null || die
+
+	third_party/libaddressinput/chromium/tools/update-strings.py || die
+
+	einfo "Configuring Chromium..."
+	build/linux/unbundle/replace_gyp_files.py ${myconf} || die
+	egyp_chromium ${myconf} || die
+}
+
+eninja() {
+	if [[ -z ${NINJAOPTS+set} ]]; then
+		local jobs=$(makeopts_jobs)
+		local loadavg=$(makeopts_loadavg)
+
+		if [[ ${MAKEOPTS} == *-j* && ${jobs} != 999 ]]; then
+			NINJAOPTS+=" -j ${jobs}"
+		fi
+		if [[ ${MAKEOPTS} == *-l* && ${loadavg} != 999 ]]; then
+			NINJAOPTS+=" -l ${loadavg}"
+		fi
+	fi
+	set -- ninja -v ${NINJAOPTS} "$@"
+	echo "$@"
+	"$@"
+}
+
+src_compile() {
+	local ninja_targets="chrome chrome_sandbox chromedriver"
+
+	# Build mksnapshot and pax-mark it.
+	eninja -C out/Release mksnapshot || die
+	pax-mark m out/Release/mksnapshot
+
+	# Even though ninja autodetects number of CPUs, we respect
+	# user's options, for debugging with -j 1 or any other reason.
+	eninja -C out/Release ${ninja_targets} || die
+
+	pax-mark m out/Release/chrome
+}
+
+src_install() {
+	exeinto "${CHROMIUM_HOME}"
+	doexe out/Release/chrome || die
+
+	newexe out/Release/chrome_sandbox chrome-sandbox || die
+	fperms 4755 "${CHROMIUM_HOME}/chrome-sandbox"
+
+	doexe out/Release/chromedriver || die
+
+	# if ! use arm; then
+	#	doexe out/Release/nacl_helper{,_bootstrap} || die
+	#	insinto "${CHROMIUM_HOME}"
+	#	doins out/Release/nacl_irt_*.nexe || die
+	#	doins out/Release/libppGoogleNaClPluginChrome.so || die
+	# fi
+
+	local sedargs=( -e "s:/usr/lib/:/usr/$(get_libdir)/:g" )
+	if [[ -n ${CHROMIUM_SUFFIX} ]]; then
+		sedargs+=(
+			-e "s:chromium-browser:chromium-browser${CHROMIUM_SUFFIX}:g"
+			-e "s:chromium.desktop:chromium${CHROMIUM_SUFFIX}.desktop:g"
+			-e "s:plugins:plugins --user-data-dir=\${HOME}/.config/chromium${CHROMIUM_SUFFIX}:"
+		)
+	fi
+	sed "${sedargs[@]}" "${FILESDIR}/chromium-launcher-r3.sh" > chromium-launcher.sh || die
+	doexe chromium-launcher.sh
+
+	# It is important that we name the target "chromium-browser",
+	# xdg-utils expect it; bug #355517.
+	dosym "${CHROMIUM_HOME}/chromium-launcher.sh" /usr/bin/chromium-browser${CHROMIUM_SUFFIX} || die
+	# keep the old symlink around for consistency
+	dosym "${CHROMIUM_HOME}/chromium-launcher.sh" /usr/bin/chromium${CHROMIUM_SUFFIX} || die
+
+	dosym "${CHROMIUM_HOME}/chromedriver" /usr/bin/chromedriver${CHROMIUM_SUFFIX} || die
+
+	# Allow users to override command-line options, bug #357629.
+	dodir /etc/chromium || die
+	insinto /etc/chromium
+	newins "${FILESDIR}/chromium.default" "default" || die
+
+	pushd out/Release/locales > /dev/null || die
+	chromium_remove_language_paks
+	popd
+
+	insinto "${CHROMIUM_HOME}"
+	doins out/Release/*.bin || die
+	doins out/Release/*.pak || die
+
+	doins -r out/Release/locales || die
+	doins -r out/Release/resources || die
+
+	newman out/Release/chrome.1 chromium${CHROMIUM_SUFFIX}.1 || die
+	newman out/Release/chrome.1 chromium-browser${CHROMIUM_SUFFIX}.1 || die
+
+	# Install icons and desktop entry.
+	local branding size
+	for size in 16 22 24 32 48 64 128 256 ; do
+		case ${size} in
+			16|32) branding="chrome/app/theme/default_100_percent/chromium" ;;
+				*) branding="chrome/app/theme/chromium" ;;
+		esac
+		newicon -s ${size} "${branding}/product_logo_${size}.png" \
+			chromium-browser${CHROMIUM_SUFFIX}.png
+	done
+
+	local mime_types="text/html;text/xml;application/xhtml+xml;"
+	mime_types+="x-scheme-handler/http;x-scheme-handler/https;" # bug #360797
+	mime_types+="x-scheme-handler/ftp;" # bug #412185
+	mime_types+="x-scheme-handler/mailto;x-scheme-handler/webcal;" # bug #416393
+	make_desktop_entry \
+		chromium-browser${CHROMIUM_SUFFIX} \
+		"Chromium${CHROMIUM_SUFFIX}" \
+		chromium-browser${CHROMIUM_SUFFIX} \
+		"Network;WebBrowser" \
+		"MimeType=${mime_types}\nStartupWMClass=chromium-browser"
+	sed -e "/^Exec/s/$/ %U/" -i "${ED}"/usr/share/applications/*.desktop || die
+
+	# Install GNOME default application entry (bug #303100).
+	if use gnome; then
+		dodir /usr/share/gnome-control-center/default-apps || die
+		insinto /usr/share/gnome-control-center/default-apps
+		newins "${FILESDIR}"/chromium-browser.xml chromium-browser${CHROMIUM_SUFFIX}.xml || die
+		if [[ "${CHROMIUM_SUFFIX}" != "" ]]; then
+			sed "s:chromium-browser:chromium-browser${CHROMIUM_SUFFIX}:g" -i \
+				"${ED}"/usr/share/gnome-control-center/default-apps/chromium-browser${CHROMIUM_SUFFIX}.xml
+		fi
+	fi
+
+	readme.gentoo_create_doc
+}
+
+pkg_postinst() {
+	fdo-mime_desktop_database_update
+	gnome2_icon_cache_update
+	readme.gentoo_print_elog
+}