[gentoo-commits] repo/gentoo:master commit in: net-analyzer/echoping/

[Anthony G. Basile]

commit:     24fd1deb6d47c3230b6ce1aa748c2ddd59d972c5
Author:     Anthony G. Basile <blueness <AT> gentoo <DOT> org>
AuthorDate: Wed Jul 13 15:49:54 2016 +0000
Commit:     Anthony G. Basile <blueness <AT> gentoo <DOT> org>
CommitDate: Wed Jul 13 15:50:11 2016 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=24fd1deb

net-analyzer/echoping: add libressl support

Package-Manager: portage-2.2.28

 .../echoping/echoping-6.0.2_p434-r3.ebuild         | 60 ++++++++++++++++++++++
 1 file changed, 60 insertions(+)

diff --git a/net-analyzer/echoping/echoping-6.0.2_p434-r3.ebuild b/net-analyzer/echoping/echoping-6.0.2_p434-r3.ebuild
new file mode 100644
index 0000000..cfb0b92
--- /dev/null
+++ b/net-analyzer/echoping/echoping-6.0.2_p434-r3.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+inherit autotools eutils
+
+DESCRIPTION="Small program to test performances of remote servers"
+HOMEPAGE="http://echoping.sourceforge.net/"
+SRC_URI="https://dev.gentoo.org/~jer/${P}.tar.gz"
+LICENSE="GPL-2"
+
+SLOT="0"
+KEYWORDS="~amd64 ~hppa ~x86"
+IUSE="libressl gnutls http icp idn priority smtp ssl tos postgres ldap"
+RESTRICT="test"
+
+RDEPEND="idn? ( net-dns/libidn )
+	postgres? ( dev-db/postgresql:* )
+	ldap? ( net-nds/openldap )
+	ssl? (
+		gnutls? ( >=net-libs/gnutls-3.3:= )
+		!gnutls? (
+			!libressl? ( dev-libs/openssl:0= )
+			libressl? ( dev-libs/libressl:0= )
+		)
+	)"
+DEPEND="${RDEPEND}
+	>=sys-devel/libtool-2"
+
+REQUIRED_USE="gnutls? ( ssl )"
+
+DOCS=( README AUTHORS ChangeLog DETAILS NEWS TODO )
+
+src_prepare() {
+	epatch "${FILESDIR}"/${PN}-6.0.2_p434-fix_implicit_declarations.patch
+	epatch "${FILESDIR}"/${PN}-6.0.2_p434-gnutls_certificate_type_set_priority.patch
+	epatch "${FILESDIR}"/${PN}-6.0.2_p434-gnutls_session.patch
+
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		$(use_enable http)  \
+		$(use_enable icp) \
+		$(use_enable priority) \
+		$(use_enable smtp) \
+		$(use_enable tos) \
+		$(use_with idn libidn) \
+		$(usex gnutls $(use_with gnutls) $(use_with ssl)) \
+		--config-cache \
+		--disable-static \
+		--disable-ttcp
+}
+
+src_install() {
+	default
+	prune_libtool_files
+}