[gentoo-commits] gentoo-x86 commit in dev-util/duma: duma-2.5.15.ebuild ChangeLog

[Steve Arnold (nerdboy)]

nerdboy     09/08/01 20:00:23

  Modified:             ChangeLog
  Added:                duma-2.5.15.ebuild
  Log:
  Updated to latest version using new ebuild (closes bug #275011).
  (Portage version: 2.2_rc33/cvs/Linux x86_64)

Revision  Changes    Path
1.10                 dev-util/duma/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-util/duma/ChangeLog?rev=1.10&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-util/duma/ChangeLog?rev=1.10&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-util/duma/ChangeLog?r1=1.9&r2=1.10

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-util/duma/ChangeLog,v
retrieving revision 1.9
retrieving revision 1.10
diff -u -r1.9 -r1.10
--- ChangeLog	1 Apr 2009 00:47:27 -0000	1.9
+++ ChangeLog	1 Aug 2009 20:00:23 -0000	1.10
@@ -1,6 +1,13 @@
 # ChangeLog for dev-util/duma
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-util/duma/ChangeLog,v 1.9 2009/04/01 00:47:27 nerdboy Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-util/duma/ChangeLog,v 1.10 2009/08/01 20:00:23 nerdboy Exp $
+
+*duma-2.5.15 (01 Aug 2009)
+
+  01 Aug 2009; Steve Arnold <nerdboy@g.o> +duma-2.5.15.ebuild,
+  +files/duma-2.5.15-GNUmakefile.patch:
+  Updated to latest version using ebuild and patch contributed by 
+  ssuominen with one or two minor enhancements.  Closes bug #275011.
 
 *duma-2.5.14-r1 (01 Apr 2009)
 



1.1                  dev-util/duma/duma-2.5.15.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-util/duma/duma-2.5.15.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-util/duma/duma-2.5.15.ebuild?rev=1.1&content-type=text/plain

Index: duma-2.5.15.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-util/duma/duma-2.5.15.ebuild,v 1.1 2009/08/01 20:00:23 nerdboy Exp $

EAPI=2
inherit eutils flag-o-matic multilib toolchain-funcs versionator

MY_P=${PN}_$(replace_all_version_separators '_')

DESCRIPTION="DUMA (Detect Unintended Memory Access) is a memory debugging library"
HOMEPAGE="http://duma.sourceforge.net"
SRC_URI="mirror://sourceforge/duma/${MY_P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE="examples"

RDEPEND="app-shells/bash"
DEPEND="${RDEPEND}"

S=${WORKDIR}/${MY_P}

src_prepare() {
	epatch "${FILESDIR}"/${P}-GNUmakefile.patch
}

src_compile() {
	# strip-flags
	replace-flags O? O0
	append-flags -Wall -Wextra -U_FORTIFY_SOURCE
	tc-export AR CC CXX LD RANLIB

	case "${CHOST}" in
	    *-linux-gnu)
			OS=linux;;
	    *-solaris*)
			OS=solaris;;
	    *-darwin*)
			OS=osx;;
	    *-freebsd*)
			OS=freebsd;;
	    *-netbsd*)
			OS=netbsd;;
	    *-cygwin*)
			OS=cygwin;;
	    **-irix**)
			OS=irix;;
	esac
	export OS="${OS}"
	elog "Detected OS is: ${OS}"

	if use amd64 && ! [ -n "${DUMA_ALIGNMENT}" ]; then
		export DUMA_ALIGNMENT=16
		elog "Exported DUMA_ALIGNMENT=${DUMA_ALIGNMENT} for x86_64,"
	fi

	make reconfig || die "make config failed"
	# The above must be run first if distcc is enabled, otherwise
	# the real build breaks on parallel makes.
	emake || die "emake failed"
}

src_test() {
	emake test || die "emake test failed"

	elog "Please, see the output above to verify all tests have passed."
	elog "Both static and dynamic confidence tests should say PASSED."
}

src_install(){
	emake prefix="${D}/usr" libdir="${D}/usr/$(get_libdir)" \
		docdir="${D}/usr/share/doc/${PF}" install || die "emake install failed"

	dodoc CHANGELOG TODO GNUmakefile

	if use examples; then
	    insinto /usr/share/doc/${PF}/examples
	    doins example[1-6].cpp example_makes/ex6/Makefile || die "doins failed"
	fi
}

pkg_postinst() {
	elog "See the GNUmakefile which will be also installed at"
	elog "/usr/share/doc/${PF} for more options. You can now export"
	elog "varibles to the build system easily, e.g.:"
	elog "# export CPPFLAGS=\"-DFLAG\" (or by using append-cppflags)"
	elog "# export DUMA_ALIGNMENT=${DUMA_ALIGNMENT} (Default is 16 for x86_64)"
	elog "See more information about DUMA_ALIGNMENT from Readme.txt"
}