[gentoo-commits] repo/gentoo:master commit in: dev-libs/libdnet/

[Sam James]

commit:     de397177f198704042dbfe0499ad1b8813e553f8
Author:     Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Mon May 16 06:03:50 2022 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Mon May 16 19:56:37 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=de397177

dev-libs/libdnet: add 1.16.1

Closes: https://bugs.gentoo.org/612400
Signed-off-by: Sam James <sam <AT> gentoo.org>

 dev-libs/libdnet/Manifest              |  1 +
 dev-libs/libdnet/libdnet-1.16.1.ebuild | 79 ++++++++++++++++++++++++++++++++++
 2 files changed, 80 insertions(+)

diff --git a/dev-libs/libdnet/Manifest b/dev-libs/libdnet/Manifest
index dad5f443f912..50391c5530cf 100644
--- a/dev-libs/libdnet/Manifest
+++ b/dev-libs/libdnet/Manifest
@@ -1 +1,2 @@
 DIST libdnet-1.14.tar.gz 520833 BLAKE2B 97e241fc374fc9489e70d440db5e19199f4e653650af85e24af56bbbc0167db1c451349c43fcb630a26c61f8ca15c58f5c879e0d82654e275189ca3e140bb22a SHA512 ce8d95228f5175e4d9a8ff71bb99eb1ccc3ccd599a85dd07adbfd9842fc54066235d362c8060828fb3ba8129d0e1e8e071e93d60d69c6d03be310c80e61cea93
+DIST libdnet-1.16.1.tar.gz 666619 BLAKE2B 74472af1bc97c4771909e926eb9b27193c50d665036672fc89ff21159408daeef090e682c5e76e19f31d04e802fb73edf01d1aa057b543568f534d31f8db375b SHA512 9c6899b42502f3892463f1ec694934cc3b02831222fa15b5a899868229366ed4e9cc728ea2c70ec857ee9d676d763b1e390f6878a597a33f7d1cd5a7bd870586

diff --git a/dev-libs/libdnet/libdnet-1.16.1.ebuild b/dev-libs/libdnet/libdnet-1.16.1.ebuild
new file mode 100644
index 000000000000..112351021f1d
--- /dev/null
+++ b/dev-libs/libdnet/libdnet-1.16.1.ebuild
@@ -0,0 +1,79 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..10} )
+DISTUTILS_OPTIONAL=1
+inherit autotools distutils-r1
+
+DESCRIPTION="Simplified, portable interface to several low-level networking routines"
+HOMEPAGE="https://github.com/ofalk/libdnet"
+SRC_URI="https://github.com/ofalk/${PN}/archive/${P}.tar.gz"
+S="${WORKDIR}/${PN}-${P}"
+
+LICENSE="LGPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86"
+IUSE="python test"
+RESTRICT="!test? ( test )"
+
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+DEPEND="dev-libs/libbsd
+	python? ( ${PYTHON_DEPS} )"
+RDEPEND="${DEPEND}"
+BDEPEND="python? ( dev-python/cython[${PYTHON_USEDEP}] )
+	test? ( dev-libs/check )"
+
+DOCS=( README.md THANKS )
+
+src_prepare() {
+	default
+
+	sed -i \
+		-e 's/libcheck.a/libcheck.so/g' \
+		configure.ac || die
+	sed -i \
+		-e 's|-L$libdir ||g' \
+		dnet-config.in || die
+	sed -i \
+		-e '/^SUBDIRS/s|python||g' \
+		Makefile.am || die
+
+	# Stale e.g. pkg-config macros w/ bashisms
+	rm aclocal.m4 {config,m4}/libtool.m4 || die
+
+	AT_M4DIR="config" eautoreconf
+
+	if use python; then
+		cd python || die
+		distutils-r1_src_prepare
+	fi
+}
+
+src_configure() {
+	econf \
+		$(use_with python) \
+		--with-check=$(usex test "${ESYSROOT}/usr")
+}
+
+src_compile() {
+	default
+	if use python; then
+		cd python || die
+		distutils-r1_src_compile
+	fi
+}
+
+src_install() {
+	default
+
+	if use python; then
+		cd python || die
+		unset DOCS
+		distutils-r1_src_install
+	fi
+
+	find "${ED}" -name '*.la' -delete || die
+}