[gentoo-commits] repo/gentoo:master commit in: sci-libs/htslib/

[David Seifert]

commit:     a7e45d492762de669f6e84b5df12aaf95cae1a1d
Author:     David Seifert <soap <AT> gentoo <DOT> org>
AuthorDate: Sun Oct  3 17:41:36 2021 +0000
Commit:     David Seifert <soap <AT> gentoo <DOT> org>
CommitDate: Sun Oct  3 17:41:36 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=a7e45d49

sci-libs/htslib: add 1.13

Bug: https://bugs.gentoo.org/799788
Signed-off-by: David Seifert <soap <AT> gentoo.org>

 sci-libs/htslib/Manifest           |  1 +
 sci-libs/htslib/htslib-1.13.ebuild | 52 ++++++++++++++++++++++++++++++++++++++
 2 files changed, 53 insertions(+)

diff --git a/sci-libs/htslib/Manifest b/sci-libs/htslib/Manifest
index 3aac577a0cf..9e65f247fdf 100644
--- a/sci-libs/htslib/Manifest
+++ b/sci-libs/htslib/Manifest
@@ -1 +1,2 @@
 DIST htslib-1.10.2.tar.bz2 1306320 BLAKE2B f877bd9c160921f498f4160f687094a1a369732bc9f61cd94a3c9ca311fa9f865505a205e38e0d348a1010b627f1ef07b590cd7e69c945df1d804133b17b2fd1 SHA512 3ecb83b0abccf731cd42b889e352e10dd922524f6e78bcafb04f8c6c71457b0dc1f5f22690b36f03cce7d97a6a905db286243ef4858138068dcac368e4ae1075
+DIST htslib-1.13.tar.bz2 4226834 BLAKE2B ae1f64e564f0f7bea80ea9d276b5d5b2b04fa3c8bd58f2c68966225b4324962f34d8a26b74267ab90dc530dfced1b9c01702d25918fd7a7c74e13913f00d5007 SHA512 16a3d61c115b71406bc4411a0c1176909166b52c4f7bb11614e398df4defaec4d09763413053e4d0d5916921c866d20019096d8fed866e77f9f1cafbd1e95b16

diff --git a/sci-libs/htslib/htslib-1.13.ebuild b/sci-libs/htslib/htslib-1.13.ebuild
new file mode 100644
index 00000000000..cfd9cfb3263
--- /dev/null
+++ b/sci-libs/htslib/htslib-1.13.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit toolchain-funcs
+
+DESCRIPTION="C library for high-throughput sequencing data formats"
+HOMEPAGE="http://www.htslib.org/"
+SRC_URI="mirror://sourceforge/samtools/${PV}/${P}.tar.bz2"
+
+LICENSE="MIT"
+SLOT="0/3"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="+bzip2 curl +lzma"
+
+RDEPEND="
+	sys-libs/zlib
+	bzip2? ( app-arch/bzip2 )
+	curl? ( net-misc/curl )
+	lzma? ( app-arch/xz-utils )"
+DEPEND="${RDEPEND}"
+
+src_prepare() {
+	default
+
+	# upstream injects LDFLAGS into the .pc file,
+	# which is a big nono for QA
+	sed -e '/^\(static_l\|Libs.private\|Requires.private\)/d' \
+		-i htslib.pc.in || die
+}
+
+src_configure() {
+	econf \
+		--disable-gcs \
+		--disable-plugins \
+		--disable-s3 \
+		$(use_enable bzip2 bz2) \
+		$(use_enable curl libcurl) \
+		$(use_enable lzma)
+}
+
+src_compile() {
+	emake AR="$(tc-getAR)"
+}
+
+src_install() {
+	default
+
+	# doesn't use libtool, can't disable static libraries
+	find "${ED}" -name '*.a' -delete || die
+}