[gentoo-commits] gentoo-x86 commit in media-sound/sonic-visualiser: sonic-visualiser-1.9.ebuild ChangeLog

[Alexis Ballier (aballier)]

aballier    12/01/07 14:49:22

  Modified:             ChangeLog
  Added:                sonic-visualiser-1.9.ebuild
  Log:
  version bump
  
  (Portage version: 2.2.0_alpha84/cvs/Linux x86_64)

Revision  Changes    Path
1.22                 media-sound/sonic-visualiser/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/sonic-visualiser/ChangeLog?rev=1.22&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/sonic-visualiser/ChangeLog?rev=1.22&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/sonic-visualiser/ChangeLog?r1=1.21&r2=1.22

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-sound/sonic-visualiser/ChangeLog,v
retrieving revision 1.21
retrieving revision 1.22
diff -u -r1.21 -r1.22
--- ChangeLog	11 Sep 2011 19:31:11 -0000	1.21
+++ ChangeLog	7 Jan 2012 14:49:22 -0000	1.22
@@ -1,6 +1,12 @@
 # ChangeLog for media-sound/sonic-visualiser
-# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/sonic-visualiser/ChangeLog,v 1.21 2011/09/11 19:31:11 ssuominen Exp $
+# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/media-sound/sonic-visualiser/ChangeLog,v 1.22 2012/01/07 14:49:22 aballier Exp $
+
+*sonic-visualiser-1.9 (07 Jan 2012)
+
+  07 Jan 2012; Alexis Ballier <aballier@g.o>
+  +sonic-visualiser-1.9.ebuild:
+  version bump
 
   11 Sep 2011; Samuli Suominen <ssuominen@g.o>
   -sonic-visualiser-1.7.2.ebuild:



1.1                  media-sound/sonic-visualiser/sonic-visualiser-1.9.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/sonic-visualiser/sonic-visualiser-1.9.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/sonic-visualiser/sonic-visualiser-1.9.ebuild?rev=1.1&content-type=text/plain

Index: sonic-visualiser-1.9.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-sound/sonic-visualiser/sonic-visualiser-1.9.ebuild,v 1.1 2012/01/07 14:49:22 aballier Exp $

EAPI=4
inherit eutils qt4-r2 autotools fdo-mime

DESCRIPTION="Music audio files viewer and analiser"
HOMEPAGE="http://www.sonicvisualiser.org/"
SRC_URI="http://code.soundsoftware.ac.uk/attachments/download/194/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="fftw id3tag jack mad ogg osc portaudio pulseaudio"

RDEPEND="x11-libs/qt-core:4
	x11-libs/qt-gui:4
	media-libs/libsndfile
	media-libs/libsamplerate
	fftw? ( sci-libs/fftw:3.0 )
	app-arch/bzip2
	>=media-libs/dssi-0.9.1
	media-libs/liblrdf
	dev-libs/redland
	media-libs/ladspa-sdk
	osc? ( media-libs/liblo )
	media-libs/speex
	>=media-libs/vamp-plugin-sdk-2.0
	media-libs/rubberband
	jack? ( media-sound/jack-audio-connection-kit )
	mad? ( media-libs/libmad )
	id3tag? ( media-libs/libid3tag )
	ogg? ( media-libs/libfishsound >=media-libs/liboggz-1.1.0 )
	portaudio? ( >=media-libs/portaudio-19_pre20071207 )
	pulseaudio? ( media-sound/pulseaudio )"

DEPEND="${RDEPEND}
	>=dev-util/pkgconfig-0.9"

REQUIRED_USE="|| ( jack pulseaudio portaudio )"

sv_disable_opt() {
	einfo "Disabling $1"
	for i in sonic-visualiser svapp svcore svgui ; do
		sed -i -e "/$1/d" "${S}/$i/configure.ac" || die "failed to remove $1 support"
	done
}

src_prepare() {
	epatch "${FILESDIR}"/${PN}-1.8-configure.patch
	cd svcore
	epatch "${FILESDIR}"/${PN}-1.7.1-liboggz11.patch

	use fftw || sv_disable_opt fftw3f
	use fftw || sv_disable_opt fftw3
	use id3tag || sv_disable_opt id3tag
	use jack || sv_disable_opt jack
	use mad || sv_disable_opt mad
	use ogg || sv_disable_opt fishsound
	use ogg || sv_disable_opt oggz
	use osc || sv_disable_opt liblo
	use portaudio || sv_disable_opt portaudio
	use pulseaudio || sv_disable_opt libpulse

	for i in sonic-visualiser svapp svcore svgui ; do
	   pushd "${S}"/$i > /dev/null
	   eautoreconf
	   popd > /dev/null
	done
}

src_install() {
	cd ${PN}
	dobin ${PN}
	dodoc README*
	#install samples
	insinto /usr/share/${PN}/samples
	doins samples/*
	# desktop entry
	doicon icons/sv-icon.svg
	domenu *.desktop
}

pkg_postinst() {
	fdo-mime_desktop_database_update
}

pkg_postrm() {
	fdo-mime_desktop_database_update
}