Get Gentoo!
gentoo.org sites
gentoo.org Wiki Bugs Forums Packages
Planet Archives Sources
Infra Status

Gentoo Archives: gentoo-commits

From: "Ralph Sennhauser (sera)" <sera@g.o>
To: gentoo-commits@l.g.o
Subject: [gentoo-commits] gentoo-x86 commit in dev-java/icedtea: ChangeLog icedtea-7.2.3.9.ebuild
Date: Tue, 28 May 2013 06:36:52
Message-Id: 20130528063646.02B1D2171D@flycatcher.gentoo.org
1 sera 13/05/28 06:36:45
2
3 Modified: ChangeLog
4 Added: icedtea-7.2.3.9.ebuild
5 Log:
6 Security bump #466822
7 Drop ant deps, the eclass ensures package requirements. 466558
8 Rename tarballs #439140
9 This version doesn't build with icedtea 6
10
11 (Portage version: 2.1.12.1/cvs/Linux x86_64, signed Manifest commit with key 3C5CF75A)
12
13 Revision Changes Path
14 1.96 dev-java/icedtea/ChangeLog
15
16 file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-java/icedtea/ChangeLog?rev=1.96&view=markup
17 plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-java/icedtea/ChangeLog?rev=1.96&content-type=text/plain
18 diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-java/icedtea/ChangeLog?r1=1.95&r2=1.96
19
20 Index: ChangeLog
21 ===================================================================
22 RCS file: /var/cvsroot/gentoo-x86/dev-java/icedtea/ChangeLog,v
23 retrieving revision 1.95
24 retrieving revision 1.96
25 diff -u -r1.95 -r1.96
26 --- ChangeLog 23 May 2013 05:45:35 -0000 1.95
27 +++ ChangeLog 28 May 2013 06:36:45 -0000 1.96
28 @@ -1,6 +1,14 @@
29 # ChangeLog for dev-java/icedtea
30 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
31 -# $Header: /var/cvsroot/gentoo-x86/dev-java/icedtea/ChangeLog,v 1.95 2013/05/23 05:45:35 caster Exp $
32 +# $Header: /var/cvsroot/gentoo-x86/dev-java/icedtea/ChangeLog,v 1.96 2013/05/28 06:36:45 sera Exp $
33 +
34 +*icedtea-7.2.3.9 (28 May 2013)
35 +
36 + 28 May 2013; Ralph Sennhauser <sera@g.o> +icedtea-7.2.3.9.ebuild:
37 + Security bump #466822
38 + Drop ant deps, the eclass ensures package requirements. 466558
39 + Rename tarballs #439140
40 + This version doesn't build with icedtea 6
41
42 *icedtea-6.1.12.5 (22 May 2013)
43
44
45
46
47 1.1 dev-java/icedtea/icedtea-7.2.3.9.ebuild
48
49 file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-java/icedtea/icedtea-7.2.3.9.ebuild?rev=1.1&view=markup
50 plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-java/icedtea/icedtea-7.2.3.9.ebuild?rev=1.1&content-type=text/plain
51
52 Index: icedtea-7.2.3.9.ebuild
53 ===================================================================
54 # Copyright 1999-2013 Gentoo Foundation
55 # Distributed under the terms of the GNU General Public License v2
56 # $Header: /var/cvsroot/gentoo-x86/dev-java/icedtea/icedtea-7.2.3.9.ebuild,v 1.1 2013/05/28 06:36:45 sera Exp $
57 # Build written by Andrew John Hughes (gnu_andrew@××××××××××.org)
58
59 # *********************************************************
60 # * IF YOU CHANGE THIS EBUILD, CHANGE ICEDTEA-6.* AS WELL *
61 # *********************************************************
62
63 EAPI="4"
64
65 inherit java-pkg-2 java-vm-2 pax-utils prefix versionator virtualx flag-o-matic
66
67 ICEDTEA_VER=$(get_version_component_range 2-)
68 ICEDTEA_BRANCH=$(get_version_component_range 2-3)
69 ICEDTEA_PKG=icedtea-${ICEDTEA_VER}
70 CORBA_TARBALL="47a6bf94ce11.tar.gz"
71 JAXP_TARBALL="d2142901bcb7.tar.gz"
72 JAXWS_TARBALL="b1877762d45c.tar.gz"
73 JDK_TARBALL="8e91101e36f0.tar.gz"
74 LANGTOOLS_TARBALL="fd956199cb82.tar.gz"
75 OPENJDK_TARBALL="12b96a57263c.tar.gz"
76 HOTSPOT_TARBALL="ad5a321edea2.tar.gz"
77 CACAO_TARBALL="a567bcb7f589.tar.gz"
78 JAMVM_TARBALL="jamvm-0972452d441544f7dd29c55d64f1ce3a5db90d82.tar.gz"
79 ZERO_HOTSPOT_TARBALL="2c4981784101.tar.gz"
80
81 CORBA_GENTOO_TARBALL="icedtea-${ICEDTEA_BRANCH}-corba-${CORBA_TARBALL}"
82 JAXP_GENTOO_TARBALL="icedtea-${ICEDTEA_BRANCH}-jaxp-${JAXP_TARBALL}"
83 JAXWS_GENTOO_TARBALL="icedtea-${ICEDTEA_BRANCH}-jaxws-${JAXWS_TARBALL}"
84 JDK_GENTOO_TARBALL="icedtea-${ICEDTEA_BRANCH}-jdk-${JDK_TARBALL}"
85 LANGTOOLS_GENTOO_TARBALL="icedtea-${ICEDTEA_BRANCH}-langtools-${LANGTOOLS_TARBALL}"
86 OPENJDK_GENTOO_TARBALL="icedtea-${ICEDTEA_BRANCH}-openjdk-${OPENJDK_TARBALL}"
87 HOTSPOT_GENTOO_TARBALL="icedtea-${ICEDTEA_BRANCH}-hotspot-${HOTSPOT_TARBALL}"
88 CACAO_GENTOO_TARBALL="icedtea-${ICEDTEA_BRANCH}-cacao-${CACAO_TARBALL}"
89 JAMVM_GENTOO_TARBALL="icedtea-${ICEDTEA_BRANCH}-${JAMVM_TARBALL}"
90 ZERO_GENTOO_TARBALL="icedtea-2.1-hotspot-${ZERO_HOTSPOT_TARBALL}"
91
92 DESCRIPTION="A harness to build OpenJDK using Free Software build tools and dependencies"
93 HOMEPAGE="http://icedtea.classpath.org"
94 SRC_URI="
95 http://icedtea.classpath.org/download/source/${ICEDTEA_PKG}.tar.gz
96 http://icedtea.classpath.org/hg/release/icedtea7-forest-${ICEDTEA_BRANCH}/archive/${OPENJDK_TARBALL}
97 -> ${OPENJDK_GENTOO_TARBALL}
98 http://icedtea.classpath.org/hg/release/icedtea7-forest-${ICEDTEA_BRANCH}/corba/archive/${CORBA_TARBALL}
99 -> ${CORBA_GENTOO_TARBALL}
100 http://icedtea.classpath.org/hg/release/icedtea7-forest-${ICEDTEA_BRANCH}/jaxp/archive/${JAXP_TARBALL}
101 -> ${JAXP_GENTOO_TARBALL}
102 http://icedtea.classpath.org/hg/release/icedtea7-forest-${ICEDTEA_BRANCH}/jaxws/archive/${JAXWS_TARBALL}
103 -> ${JAXWS_GENTOO_TARBALL}
104 http://icedtea.classpath.org/hg/release/icedtea7-forest-${ICEDTEA_BRANCH}/jdk/archive/${JDK_TARBALL}
105 -> ${JDK_GENTOO_TARBALL}
106 http://icedtea.classpath.org/hg/release/icedtea7-forest-${ICEDTEA_BRANCH}/hotspot/archive/${HOTSPOT_TARBALL}
107 -> ${HOTSPOT_GENTOO_TARBALL}
108 http://icedtea.classpath.org/hg/release/icedtea7-forest-${ICEDTEA_BRANCH}/langtools/archive/${LANGTOOLS_TARBALL}
109 -> ${LANGTOOLS_GENTOO_TARBALL}
110 http://icedtea.classpath.org/download/drops/cacao/${CACAO_TARBALL} -> ${CACAO_GENTOO_TARBALL}
111 http://icedtea.classpath.org/download/drops/jamvm/${JAMVM_TARBALL} -> ${JAMVM_GENTOO_TARBALL}
112 !amd64? ( !arm? ( !ppc? ( !ppc64? ( !sparc? ( !x86? (
113 http://icedtea.classpath.org/hg/release/icedtea7-forest-2.1/hotspot/archive/${ZERO_HOTSPOT_TARBALL}
114 -> ${ZERO_GENTOO_TARBALL}
115 ) ) ) ) ) )"
116
117 LICENSE="Apache-1.1 Apache-2.0 GPL-1 GPL-2 GPL-2-with-linking-exception LGPL-2 MPL-1.0 MPL-1.1 public-domain W3C"
118 SLOT="7"
119 KEYWORDS="~amd64 ~ia64 ~x86"
120
121 IUSE="+X +alsa cjk +cups debug doc examples javascript +jbootstrap +nsplugin
122 +nss pax_kernel pulseaudio +source systemtap test +webstart"
123
124 # Ideally the following were optional at build time.
125 ALSA_COMMON_DEP="
126 >=media-libs/alsa-lib-1.0"
127 CUPS_COMMON_DEP="
128 >=net-print/cups-1.2.12"
129 X_COMMON_DEP="
130 >=dev-libs/atk-1.30.0
131 >=dev-libs/glib-2.26
132 media-libs/fontconfig
133 >=media-libs/freetype-2.3.5
134 >=x11-libs/cairo-1.8.8
135 x11-libs/gdk-pixbuf:2
136 >=x11-libs/gtk+-2.8:2
137 >=x11-libs/libX11-1.1.3
138 >=x11-libs/libXext-1.1.1
139 >=x11-libs/libXi-1.1.3
140 >=x11-libs/libXrender-0.9.4
141 >=x11-libs/libXtst-1.0.3
142 >=x11-libs/pango-1.24.5"
143 X_DEPEND="
144 >=x11-libs/libXau-1.0.3
145 >=x11-libs/libXdmcp-1.0.2
146 >=x11-libs/libXinerama-1.0.2
147 x11-proto/inputproto
148 >=x11-proto/xextproto-7.1.1
149 x11-proto/xineramaproto
150 x11-proto/xproto"
151
152 COMMON_DEP="
153 >=media-libs/giflib-4.1.6
154 media-libs/lcms:2
155 >=media-libs/libpng-1.2
156 >=sys-libs/zlib-1.2.3
157 virtual/jpeg
158 javascript? ( dev-java/rhino:1.6 )
159 nss? ( >=dev-libs/nss-3.12.5-r1 )
160 pulseaudio? ( >=media-sound/pulseaudio-0.9.11 )
161 systemtap? ( >=dev-util/systemtap-1 )"
162
163 # cups is needed for X. #390945 #390975
164 RDEPEND="${COMMON_DEP}
165 !dev-java/icedtea:0
166 X? (
167 ${CUPS_COMMON_DEP}
168 ${X_COMMON_DEP}
169 media-fonts/dejavu
170 cjk? (
171 media-fonts/arphicfonts
172 media-fonts/baekmuk-fonts
173 media-fonts/lklug
174 media-fonts/lohit-fonts
175 media-fonts/sazanami
176 )
177 )
178 alsa? ( ${ALSA_COMMON_DEP} )
179 cups? ( ${CUPS_COMMON_DEP} )"
180
181 # Only ant-core-1.8.1 has fixed ant -diagnostics when xerces+xalan are not present.
182 # ca-certificates, perl and openssl are used for the cacerts keystore generation
183 # xext headers have two variants depending on version - bug #288855
184 # autoconf - as long as we use eautoreconf, version restrictions for bug #294918
185
186 # FIXME: this version can't be built with icedtea-6
187 DEPEND="${COMMON_DEP} ${ALSA_COMMON_DEP} ${CUPS_COMMON_DEP} ${X_COMMON_DEP}
188 || (
189 >=dev-java/gcj-jdk-4.3
190 dev-java/icedtea-bin:7
191 dev-java/icedtea:7
192 )
193 app-arch/cpio
194 app-arch/unzip
195 app-arch/zip
196 app-misc/ca-certificates
197 dev-lang/perl
198 >=dev-libs/libxslt-1.1.26
199 dev-libs/openssl
200 virtual/pkgconfig
201 sys-apps/attr
202 sys-apps/lsb-release
203 ${X_DEPEND}
204 pax_kernel? ( sys-apps/paxctl )"
205
206 PDEPEND="webstart? ( dev-java/icedtea-web:7 )
207 nsplugin? ( dev-java/icedtea-web:7[nsplugin] )"
208
209 S="${WORKDIR}"/${ICEDTEA_PKG}
210
211 pkg_setup() {
212 JAVA_PKG_WANT_BUILD_VM="
213 icedtea-7 icedtea-bin-7 icedtea7
214 gcj-jdk"
215 #icedtea-6 icedtea-bin-6 icedtea6 icedtea6-bin
216 JAVA_PKG_WANT_SOURCE="1.5"
217 JAVA_PKG_WANT_TARGET="1.5"
218
219 java-vm-2_pkg_setup
220 java-pkg-2_pkg_setup
221 }
222
223 src_unpack() {
224 unpack ${ICEDTEA_PKG}.tar.gz
225 }
226
227 java_prepare() {
228 # For bootstrap builds as the sandbox control file might not yet exist.
229 addpredict /proc/self/coredump_filter
230
231 # icedtea doesn't like some locales. #330433 #389717
232 export LANG="C" LC_ALL="C"
233 }
234
235 bootstrap_impossible() {
236 # Fill this according to testing what works and what not
237 has "${1}" icedtea6 icedtea-6 icedtea6-bin icedtea-bin-6
238 }
239
240 src_configure() {
241 local config bootstrap
242 local vm=$(java-pkg_get-current-vm)
243
244 # Whether to bootstrap
245 bootstrap="disable"
246 if use jbootstrap; then
247 if bootstrap_impossible "${vm}"; then
248 einfo "Bootstrap with ${vm} is currently not possible and thus disabled, ignoring USE=jbootstrap"
249 else
250 bootstrap="enable"
251 fi
252 fi
253
254 if has "${vm}" gcj-jdk; then
255 # gcj-jdk ensures ecj is present.
256 use jbootstrap || einfo "bootstrap is necessary when building with ${vm}, ignoring USE=\"-jbootstrap\""
257 bootstrap="enable"
258 local ecj_jar="$(readlink "${EPREFIX}"/usr/share/eclipse-ecj/ecj.jar)"
259 config="${config} --with-ecj-jar=${ecj_jar}"
260 fi
261
262 config="${config} --${bootstrap}-bootstrap"
263
264 # HotSpot > CACAO > JamVM > Zero, though CACAO is somewhat memory hungry
265 # CACAO is not yet available for icedtea-7
266 case "${ARCH}" in
267 amd64|sparc|x86)
268 ;;
269 arm)
270 config+=" --enable-jamvm" #IT1266
271 replace-flags -Os -O2 #BGO453612 #IT1267
272 ;;
273 ppc|ppc64)
274 config+=" --enable-jamvm"
275 ;;
276 *)
277 config+=" --enable-zero"
278 HOTSPOT_GENTOO_TARBALL=${ZERO_GENTOO_TARBALL}
279 ;;
280 esac
281
282 # OpenJDK-specific parallelism support. Bug #389791, #337827
283 # Implementation modified from waf-utils.eclass
284 # Note that "-j" is converted to "-j1" as the system doesn't support --load-average
285 local procs=$(echo -j1 ${MAKEOPTS} | sed -r "s/.*(-j\s*|--jobs=)([0-9]+).*/\2/" )
286 config="${config} --with-parallel-jobs=${procs}";
287 einfo "Configuring using --with-parallel-jobs=${procs}"
288
289 if use javascript ; then
290 config="${config} --with-rhino=$(java-pkg_getjar rhino-1.6 js.jar)"
291 else
292 config="${config} --without-rhino"
293 fi
294
295 unset JAVA_HOME JDK_HOME CLASSPATH JAVAC JAVACFLAGS
296
297 econf ${config} \
298 --with-openjdk-src-zip="${DISTDIR}/${OPENJDK_GENTOO_TARBALL}" \
299 --with-corba-src-zip="${DISTDIR}/${CORBA_GENTOO_TARBALL}" \
300 --with-jaxp-src-zip="${DISTDIR}/${JAXP_GENTOO_TARBALL}" \
301 --with-jaxws-src-zip="${DISTDIR}/${JAXWS_GENTOO_TARBALL}" \
302 --with-jdk-src-zip="${DISTDIR}/${JDK_GENTOO_TARBALL}" \
303 --with-hotspot-src-zip="${DISTDIR}/${HOTSPOT_GENTOO_TARBALL}" \
304 --with-langtools-src-zip="${DISTDIR}/${LANGTOOLS_GENTOO_TARBALL}" \
305 --with-cacao-src-zip="${DISTDIR}/${CACAO_GENTOO_TARBALL}" \
306 --with-jamvm-src-zip="${DISTDIR}/${JAMVM_GENTOO_TARBALL}" \
307 --with-jdk-home="$(java-config -O)" \
308 --with-abs-install-dir=/usr/$(get_libdir)/icedtea${SLOT} \
309 --disable-downloading --disable-Werror \
310 $(use_enable !debug optimizations) \
311 $(use_enable doc docs) \
312 $(use_enable nss) \
313 $(use_enable pulseaudio pulse-java) \
314 $(use_enable systemtap) \
315 $(use_with pax_kernel pax paxctl)
316 }
317
318 src_compile() {
319 # Would use GENTOO_VM otherwise.
320 export ANT_RESPECT_JAVA_HOME=TRUE
321 # disable all optional ant tasks
322 export ANT_TASKS="none"
323
324 emake
325 }
326
327 src_test() {
328 # Use Xvfb for tests
329 unset DISPLAY
330
331 Xemake check
332 }
333
334 src_install() {
335 local dest="/usr/$(get_libdir)/icedtea${SLOT}"
336 local ddest="${ED}/${dest}"
337 dodir "${dest}"
338
339 dodoc README NEWS AUTHORS
340 dosym /usr/share/doc/${PF} /usr/share/doc/${PN}${SLOT}
341
342 cd openjdk.build/j2sdk-image || die
343
344 # Ensures HeadlessGraphicsEnvironment is used.
345 if ! use X; then
346 rm -r jre/lib/$(get_system_arch)/xawt || die
347 fi
348
349 # Don't hide classes
350 rm lib/ct.sym || die
351
352 #402507
353 mkdir jre/.systemPrefs || die
354 touch jre/.systemPrefs/.system.lock || die
355 touch jre/.systemPrefs/.systemRootModFile || die
356
357 # doins can't handle symlinks.
358 cp -vRP bin include jre lib man "${ddest}" || die
359
360 dodoc ASSEMBLY_EXCEPTION THIRD_PARTY_README
361
362 if use doc; then
363 # java-pkg_dohtml needed for package-list #302654
364 java-pkg_dohtml -r ../docs/* || die
365 fi
366
367 if use examples; then
368 dodir "${dest}/share";
369 cp -vRP demo sample "${ddest}/share/" || die
370 fi
371
372 if use source; then
373 cp src.zip "${ddest}" || die
374 fi
375
376 # Fix the permissions.
377 find "${ddest}" \! -type l \( -perm /111 -exec chmod 755 {} \; -o -exec chmod 644 {} \; \) || die
378
379 # Needs to be done before generating cacerts
380 java-vm_set-pax-markings "${ddest}"
381
382 # We need to generate keystore - bug #273306
383 einfo "Generating cacerts file from certificates in ${EPREFIX}/usr/share/ca-certificates/"
384 mkdir "${T}/certgen" && cd "${T}/certgen" || die
385 cp "${FILESDIR}/generate-cacerts.pl" . && chmod +x generate-cacerts.pl || die
386 for c in "${EPREFIX}"/usr/share/ca-certificates/*/*.crt; do
387 openssl x509 -text -in "${c}" >> all.crt || die
388 done
389 ./generate-cacerts.pl "${ddest}/bin/keytool" all.crt || die
390 cp -vRP cacerts "${ddest}/jre/lib/security/" || die
391 chmod 644 "${ddest}/jre/lib/security/cacerts" || die
392
393 # OpenJDK7 should be able to use fontconfig instead, but wont hurt to
394 # install it anyway. Bug 390663
395 cp "${FILESDIR}"/fontconfig.Gentoo.properties.src "${T}"/fontconfig.Gentoo.properties || die
396 eprefixify "${T}"/fontconfig.Gentoo.properties
397 insinto "${dest}"/jre/lib
398 doins "${T}"/fontconfig.Gentoo.properties
399
400 set_java_env "${FILESDIR}/icedtea.env"
401 if ! use X || ! use alsa || ! use cups; then
402 java-vm_revdep-mask "${dest}"
403 fi
404 java-vm_sandbox-predict /proc/self/coredump_filter
405 }
406
407 pkg_preinst() {
408 if has_version "<=dev-java/icedtea-7.2.0:7"; then
409 # portage would preserve the symlink otherwise, related to bug #384397
410 rm -f "${EROOT}/usr/lib/jvm/icedtea7"
411 elog "To unify the layout and simplify scripts, the identifier of Icedtea-7*"
412 elog "has changed from 'icedtea7' to 'icedtea-7' starting from version 7.2.0-r1"
413 elog "If you had icedtea7 as system VM, the change should be automatic, however"
414 elog "build VM settings in /etc/java-config-2/build/jdk.conf are not changed"
415 elog "and the same holds for any user VM settings. Sorry for the inconvenience."
416 fi
417 }
Report Message
Find on MARC Find on Google Groups