[gentoo-commits] repo/gentoo:master commit in: x11-misc/xdg-user-dirs-gtk/

[Mike Gilbert]

commit:     4fefa42e5cf3283a1eb79880cb33c9245aaefad0
Author:     David Michael <fedora.dm0 <AT> gmail <DOT> com>
AuthorDate: Sat Dec 26 03:01:31 2020 +0000
Commit:     Mike Gilbert <floppym <AT> gentoo <DOT> org>
CommitDate: Mon Dec 28 17:35:47 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=4fefa42e

x11-misc/xdg-user-dirs-gtk: EAPI 7, support cross-compiling

The build system prevented the CHOST pkg-config from being found,
so this specifies it as the cache variable to work around it.

It also wants to know the path of a runtime dependency, so that is
specified with EPREFIX so it isn't required at build time.

Package-Manager: Portage-3.0.9, Repoman-3.0.2
Signed-off-by: David Michael <fedora.dm0 <AT> gmail.com>
Signed-off-by: Mike Gilbert <floppym <AT> gentoo.org>

 .../xdg-user-dirs-gtk-0.10-r1.ebuild               | 24 +++++++++++++++-------
 1 file changed, 17 insertions(+), 7 deletions(-)

diff --git a/x11-misc/xdg-user-dirs-gtk/xdg-user-dirs-gtk-0.10-r1.ebuild b/x11-misc/xdg-user-dirs-gtk/xdg-user-dirs-gtk-0.10-r1.ebuild
index d433d5e80ce..2d9acf66e61 100644
--- a/x11-misc/xdg-user-dirs-gtk/xdg-user-dirs-gtk-0.10-r1.ebuild
+++ b/x11-misc/xdg-user-dirs-gtk/xdg-user-dirs-gtk-0.10-r1.ebuild
@@ -1,8 +1,8 @@
 # Copyright 1999-2020 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=6
-inherit gnome.org readme.gentoo-r1
+EAPI=7
+inherit gnome.org readme.gentoo-r1 toolchain-funcs
 
 DESCRIPTION="Integrates xdg-user-dirs into the Gnome desktop and Gtk+ applications"
 HOMEPAGE="https://www.freedesktop.org/wiki/Software/xdg-user-dirs"
@@ -10,14 +10,14 @@ HOMEPAGE="https://www.freedesktop.org/wiki/Software/xdg-user-dirs"
 LICENSE="GPL-2"
 SLOT="0"
 KEYWORDS="~alpha amd64 arm arm64 ~hppa ~ia64 ~mips ppc ppc64 sparc x86 ~amd64-linux ~x86-linux ~x86-solaris"
-IUSE=""
 
 RDEPEND="
 	dev-libs/glib
-	>=x11-misc/xdg-user-dirs-0.14
 	>=x11-libs/gtk+-3.5.1:3
+	>=x11-misc/xdg-user-dirs-0.14
 "
-DEPEND="${RDEPEND}
+DEPEND="${RDEPEND}"
+BDEPEND="
 	dev-util/intltool
 	virtual/pkgconfig
 "
@@ -30,15 +30,25 @@ DOC_CONTENTS="
 "
 
 src_prepare() {
-	default_src_prepare
+	default
 	sed -i \
 		-e '/Encoding/d' \
 		-e 's:OnlyShowIn=GNOME;LXDE;Unity;:NotShowIn=KDE;:' \
 		user-dirs-update-gtk.desktop.in || die
 }
 
+src_configure() {
+	local -a myeconfargs=(
+		# Skip configure.ac disabling the cross-compiling pkg-config.
+		ac_cv_path_PKG_CONFIG="$(tc-getPKG_CONFIG)"
+		# Skip searching for this program in the CBUILD root.
+		XDG_USER_DIRS_UPDATE="${EPREFIX}/usr/bin/xdg-user-dirs-update"
+	)
+	econf "${myeconfargs[@]}"
+}
+
 src_install() {
-	default_src_install
+	default
 	readme.gentoo_create_doc
 }