[gentoo-commits] repo/gentoo:master commit in: dev-python/regex/

[Michał Górny]

commit:     b0236ec7c52e3b15f1c97cdeab7844325ded1f1b
Author:     Nils Freydank <holgersson <AT> posteo <DOT> de>
AuthorDate: Sat Oct 27 17:54:10 2018 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Tue Oct 30 09:32:18 2018 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=b0236ec7

dev-python/regex: Add pypy3 support

Signed-off-by: Nils Freydank <holgersson <AT> posteo.de>
Package-Manager: Portage-2.3.51, Repoman-2.3.11
Pull-Request: https://github.com/gentoo/gentoo/pull/10166
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/regex/regex-2017.04.05-r1.ebuild | 45 +++++++++++++++++++++++++++++
 1 file changed, 45 insertions(+)

diff --git a/dev-python/regex/regex-2017.04.05-r1.ebuild b/dev-python/regex/regex-2017.04.05-r1.ebuild
new file mode 100644
index 00000000000..f67aa62e686
--- /dev/null
+++ b/dev-python/regex/regex-2017.04.05-r1.ebuild
@@ -0,0 +1,45 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python2_7 python3_{4,5,6,7} pypy pypy3 )
+
+inherit distutils-r1 flag-o-matic
+
+DESCRIPTION="Alternative regular expression module to replace re"
+HOMEPAGE="https://bitbucket.org/mrabarnett/mrab-regex"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sparc ~x86 ~amd64-fbsd"
+IUSE="doc"
+
+DOCS=( README docs/UnicodeProperties.txt )
+
+python_compile() {
+	if ! python_is_python3; then
+		local CFLAGS=${CFLAGS}
+		append-cflags -fno-strict-aliasing
+	fi
+	distutils-r1_python_compile
+}
+
+python_test() {
+	local msg="tests failed under ${EPYTHON}"
+	# https://bitbucket.org/mrabarnett/mrab-regex/issue/145/1-fail-in-testsuite-under-pypy
+	einfo "There is one trivial fail of test test_empty_array under pypy"
+
+	if python_is_python3; then
+		"${PYTHON}" Python3/test_regex.py || die "${msg}"
+	else
+		"${PYTHON}" Python2/test_regex.py || die "${msg}"
+	fi
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( docs/Features.html )
+
+	distutils-r1_python_install_all
+}