[gentoo-commits] repo/gentoo:master commit in: app-crypt/acme/

[Matthew Thode]

commit:     d69eaf34f3ac35197e3d5b96aad83fa4c7eb9f64
Author:     Matthew Thode <prometheanfire <AT> gentoo <DOT> org>
AuthorDate: Thu Sep 10 04:30:43 2020 +0000
Commit:     Matthew Thode <prometheanfire <AT> gentoo <DOT> org>
CommitDate: Thu Sep 10 04:34:05 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=d69eaf34

app-crypt/acme: 1.8.0 bump

Package-Manager: Portage-3.0.4, Repoman-3.0.1
Signed-off-by: Matthew Thode <prometheanfire <AT> gentoo.org>

 app-crypt/acme/Manifest          |  1 +
 app-crypt/acme/acme-1.8.0.ebuild | 69 ++++++++++++++++++++++++++++++++++++++++
 2 files changed, 70 insertions(+)

diff --git a/app-crypt/acme/Manifest b/app-crypt/acme/Manifest
index 052b267e889..840e9863bf6 100644
--- a/app-crypt/acme/Manifest
+++ b/app-crypt/acme/Manifest
@@ -1 +1,2 @@
 DIST certbot-1.7.0.tar.gz 1416764 BLAKE2B de678a222e8c8e3e7834470f87763763671bfae37a5c8320a4c1a2552ec979b5391094713e7e13526f73fdf8cd32f70f8c4350f422505892c4fdd0ae77742c80 SHA512 f81242e68b7e261bbb6294ffe92e47bc1687128344816d71a495a94a2646e209e46c147bc76eedce0c477cc140dc6ae0fba76d2d5d01b828fce78875f5a2886a
+DIST certbot-1.8.0.tar.gz 1425620 BLAKE2B 9cc0443fd067bf594f02a79c99defa250e656dbee00cd2717a4a747abfe80511ffcb800b6ac63e484a918192dad9465dc45335f358267fa998af16e966b8e2a6 SHA512 c6559fe1e5db6269942bda3738c00b1b550ec448288eaf911ba9c3967c7e949b34bdd8b77742398f0a512ce07929fa2f227c1202e40900151762f1db6ff9de56

diff --git a/app-crypt/acme/acme-1.8.0.ebuild b/app-crypt/acme/acme-1.8.0.ebuild
new file mode 100644
index 00000000000..a3d394a31a6
--- /dev/null
+++ b/app-crypt/acme/acme-1.8.0.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=(python{3_6,3_7,3_8})
+
+if [[ ${PV} == 9999* ]]; then
+	EGIT_REPO_URI="https://github.com/certbot/certbot.git"
+	inherit git-r3
+	S=${WORKDIR}/${P}/${PN}
+else
+	SRC_URI="https://github.com/certbot/certbot/archive/v${PV}.tar.gz -> certbot-${PV}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+	S=${WORKDIR}/certbot-${PV}/acme
+fi
+
+inherit distutils-r1
+
+DESCRIPTION="An implementation of the ACME protocol"
+HOMEPAGE="https://github.com/certbot/certbot https://letsencrypt.org/"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+IUSE="doc test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-python/cryptography-1.3.4[${PYTHON_USEDEP}]
+	>=dev-python/idna-2.0.0[${PYTHON_USEDEP}]
+	>=dev-python/josepy-1.1.0[${PYTHON_USEDEP}]
+	>=dev-python/pyopenssl-0.15.1[${PYTHON_USEDEP}]
+	dev-python/pyrfc3339[${PYTHON_USEDEP}]
+	dev-python/pytz[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.10[${PYTHON_USEDEP}]
+	>=dev-python/requests-toolbelt-0.3.0[${PYTHON_USEDEP}]
+	>=dev-python/six-1.9.0[${PYTHON_USEDEP}]
+"
+DEPEND="
+	doc? (
+		dev-python/sphinx[${PYTHON_USEDEP}]
+		dev-python/sphinx_rtd_theme[${PYTHON_USEDEP}]
+	)
+	test? (
+		${RDEPEND}
+		dev-python/nose[${PYTHON_USEDEP}]
+		dev-python/pytest[${PYTHON_USEDEP}]
+		dev-python/pytest-xdist[${PYTHON_USEDEP}]
+	)
+	>=dev-python/setuptools-1.0[${PYTHON_USEDEP}]
+"
+
+src_compile() {
+	python_foreach_impl run_in_build_dir default
+	distutils-r1_src_compile
+	if use doc ; then
+		cd docs || die
+		sphinx-build -b html -d _build/doctrees   . _build/html
+	fi
+}
+
+python_test() {
+	nosetests -w ${PN} || die
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( docs/_build/html/. )
+
+	distutils-r1_python_install_all
+}