[gentoo-commits] gentoo-x86 commit in sys-apps/kbd: kbd-2.0.2.ebuild ChangeLog

[Mike Frysinger (vapier)]

vapier      14/08/01 10:35:43

  Modified:             ChangeLog
  Added:                kbd-2.0.2.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key D2E96200)

Revision  Changes    Path
1.130                sys-apps/kbd/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/kbd/ChangeLog?rev=1.130&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/kbd/ChangeLog?rev=1.130&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/kbd/ChangeLog?r1=1.129&r2=1.130

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-apps/kbd/ChangeLog,v
retrieving revision 1.129
retrieving revision 1.130
diff -u -r1.129 -r1.130
--- ChangeLog	23 Apr 2014 16:53:31 -0000	1.129
+++ ChangeLog	1 Aug 2014 10:35:43 -0000	1.130
@@ -1,6 +1,11 @@
 # ChangeLog for sys-apps/kbd
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-apps/kbd/ChangeLog,v 1.129 2014/04/23 16:53:31 polynomial-c Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/kbd/ChangeLog,v 1.130 2014/08/01 10:35:43 vapier Exp $
+
+*kbd-2.0.2 (01 Aug 2014)
+
+  01 Aug 2014; Mike Frysinger <vapier@g.o> +kbd-2.0.2.ebuild:
+  Version bump.
 
   23 Apr 2014; Lars Wendler <polynomial-c@g.o>
   +files/kbd-2.0.1-big_endian.patch:



1.1                  sys-apps/kbd/kbd-2.0.2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/kbd/kbd-2.0.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/kbd/kbd-2.0.2.ebuild?rev=1.1&content-type=text/plain

Index: kbd-2.0.2.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-apps/kbd/kbd-2.0.2.ebuild,v 1.1 2014/08/01 10:35:43 vapier Exp $

EAPI=5

SCM=""
if [[ ${PV} == "9999" ]] ; then
	SCM="git-r3"
	EGIT_REPO_URI="http://git.kernel.org/cgit/linux/kernel/git/legion/${PN}.git"
	EGIT_BRANCH="master"
else
	SRC_URI="ftp://ftp.kernel.org/pub/linux/utils/kbd/${P}.tar.xz"
	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86"
fi

inherit autotools eutils ${SCM}

DESCRIPTION="Keyboard and console utilities"
HOMEPAGE="http://kbd-project.org/"

LICENSE="GPL-2"
SLOT="0"
IUSE="nls pam test"

RDEPEND="pam? ( virtual/pam )"
DEPEND="${RDEPEND}
	virtual/pkgconfig
	test? ( dev-libs/check )"

src_unpack() {
	if [[ ${PV} == "9999" ]] ; then
		git-r3_src_unpack
	else
		default
	fi

	# Rename conflicting keymaps to have unique names, bug #293228
	cd "${S}"/data/keymaps/i386 || die
	mv dvorak/no.map dvorak/no-dvorak.map || die
	mv fgGIod/trf.map fgGIod/trf-fgGIod.map || die
	mv olpc/es.map olpc/es-olpc.map || die
	mv olpc/pt.map olpc/pt-olpc.map || die
	mv qwerty/cz.map qwerty/cz-qwerty.map || die
}

src_prepare() {
	epatch "${FILESDIR}"/${PN}-2.0.0-tests.patch
	eautoreconf
}

src_configure() {
	econf \
		$(use_enable nls) \
		$(use_enable pam vlock) \
		$(use_enable test tests)
}

src_install() {
	default
	dohtml docs/doc/*.html
}