[gentoo-commits] repo/gentoo:master commit in: dev-libs/angelscript/

[James Le Cuirot]

commit:     170f8a9284212b3be79d2258bd76c35bdca68fed
Author:     James Le Cuirot <chewi <AT> gentoo <DOT> org>
AuthorDate: Thu Sep 29 21:07:57 2022 +0000
Commit:     James Le Cuirot <chewi <AT> gentoo <DOT> org>
CommitDate: Thu Sep 29 21:08:33 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=170f8a92

dev-libs/angelscript: I forgot the ebuild... again

Signed-off-by: James Le Cuirot <chewi <AT> gentoo.org>

 dev-libs/angelscript/angelscript-2.36.0.ebuild | 48 ++++++++++++++++++++++++++
 1 file changed, 48 insertions(+)

diff --git a/dev-libs/angelscript/angelscript-2.36.0.ebuild b/dev-libs/angelscript/angelscript-2.36.0.ebuild
new file mode 100644
index 000000000000..96929201e78b
--- /dev/null
+++ b/dev-libs/angelscript/angelscript-2.36.0.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit toolchain-funcs multilib-minimal
+
+DESCRIPTION="A flexible, cross-platform scripting library"
+HOMEPAGE="http://www.angelcode.com/angelscript/"
+SRC_URI="http://www.angelcode.com/angelscript/sdk/files/angelscript_${PV}.zip"
+LICENSE="ZLIB"
+SLOT="0/${PV}"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~riscv ~x86"
+IUSE="doc static-libs"
+
+BDEPEND="app-arch/unzip"
+
+S="${WORKDIR}/sdk"
+
+pkg_setup() {
+	tc-export CXX AR RANLIB
+}
+
+src_prepare() {
+	default
+	multilib_copy_sources
+}
+
+multilib_src_compile() {
+	emake -C ${PN}/projects/gnuc shared \
+		  $(use static-libs && echo static)
+}
+
+multilib_src_install() {
+	emake -C ${PN}/projects/gnuc \
+		  DESTDIR="${D}" \
+		  PREFIX="${EPREFIX}"/usr \
+		  LIBDIR_DEST='$(PREFIX)'/$(get_libdir) \
+		  install_header install_shared \
+		  $(use static-libs && echo install_static)
+}
+
+multilib_src_install_all() {
+	if use doc; then
+		docinto html
+		dodoc -r docs/*
+	fi
+}